Text blinken ?

[Fanpost]

Moin, ich habe wieder mal eine Frage:

Kann man z.B. "SetGadgetText(#Hinweis," Falsche Eingabe!")" blinken lassen?
Oder generell Text unter PB?

[RSBasic]

Sowas?

Code: Alles auswählen

EnableExplicit

Define Blink

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  StringGadget(1, 10, 10, 100, 20, "", 0)
  ButtonGadget(2, 120, 10, 100, 20, "Bestätigen", 0)
  
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_Timer
        Select EventTimer()
          Case 1
            Blink + 1
            If GetGadgetColor(1, #PB_Gadget_BackColor) = RGB(255, 0, 0)
              SetGadgetColor(1, #PB_Gadget_BackColor, -1)
            Else
              SetGadgetColor(1, #PB_Gadget_BackColor, RGB(255, 0, 0))
            EndIf
            If Blink = 6
              SetGadgetColor(1, #PB_Gadget_BackColor, -1)
              RemoveWindowTimer(0, 1)
            EndIf
        EndSelect
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 2
            If GetGadgetText(1) = ""
              Blink = 0
              AddWindowTimer(0, 1, 100)
            EndIf
        EndSelect
      Case #PB_Event_CloseWindow
        End
    EndSelect
  ForEver
EndIf

Oder:

Code: Alles auswählen

EnableExplicit

Define Blink

If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  StringGadget(1, 10, 10, 100, 20, "", 0)
  ButtonGadget(2, 120, 10, 100, 20, "Bestätigen", 0)
  TextGadget(3, 10, 30, 100, 20, "", 0)
  SetGadgetColor(3, #PB_Gadget_FrontColor, RGB(255, 0, 0))
  
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_Timer
        Select EventTimer()
          Case 1
            Blink + 1
            If GetGadgetText(3) = ""
              SetGadgetText(3, "Falsche Eingabe!")
            Else
              SetGadgetText(3, "")
            EndIf
            If Blink = 6
              SetGadgetText(3, "")
              RemoveWindowTimer(0, 1)
            EndIf
        EndSelect
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 2
            If GetGadgetText(1) = ""
              Blink = 0
              AddWindowTimer(0, 1, 250)
            EndIf
        EndSelect
      Case #PB_Event_CloseWindow
        End
    EndSelect
  ForEver
EndIf

[Fanpost]

Boohhhh Ey,

mit so einer schnellen Antwort habe ich nicht gerechnet!

Danke, genau das, was ich brauche.

[udg]

nice