Webobjekt mit Dateiamen speichern - wie?

[Fanpost]

Ich speicher mein HTML-Formular wie folgt ab:

Code: Alles auswählen

Procedure FormularSpeichern()
   Protected WebObject.IWebBrowser2
   WebObject = GetWindowLong_(GadgetID(#Adresse), #GWL_USERDATA)
   WebObject\ExecWB(#OLECMDID_SAVEAS, #OLECMDEXECOPT_DontPROMPTUSER, 0, 0)
 EndProcedure  
 

Mit dieser Prozedur wird mit dem Dateinamen "blank" gespeichert.
Wie kann ich einen Dateinamen hinzufügen?

[Kiffi]

Code: Alles auswählen

#VT_BSTR = 8

Procedure FormularSpeichern(Filename.s)
  
  Protected WebObject.IWebBrowser2
  
  WebObject = GetWindowLong_(GadgetID(#Adresse), #GWL_USERDATA)
  
  Protected filename_Unicode
  
  ; convert to unicode
  filename_Unicode = AllocateMemory(Len(Filename) * 2 + 2)
  MultiByteToWideChar_(#CP_ACP, 0, @Filename, -1, filename_Unicode, Len(Filename) * 2 + 2)                
  
  Protected filename_BSTR
  
  ; create bstr
  filename_BSTR = SysAllocString_(filename_Unicode)
  
  ; fill variant
  Protected VariantIn.VARIANT
  VariantIn\vt = #VT_BSTR
  VariantIn\bstrVal = filename_BSTR
  
  If WebObject\ExecWB(#OLECMDID_SAVEAS, #OLECMDEXECOPT_DONTPROMPTUSER, @VariantIn, 0) = #S_OK
    MessageRequester("","Saved sucessfully")
  Else
    MessageRequester("","could not save file")
  EndIf
  
  FreeMemory(filename_Unicode)
  SysFreeString_(filename_BSTR)   
  
EndProcedure

(habe ich Dir am 23. Juni per Mail gesendet)

Grüße ... Peter

[ts-soft]

Code: Alles auswählen

  WebObject = GetWindowLong_(GadgetID(#Adresse), #GWL_USERDATA)

Besser mit GetWindowLongPtr_

Code: Alles auswählen

WebObject = GetWindowLongPtr_(GadgetID(#Adresse), #GWL_USERDATA)

[NicTheQuick]

Diese zwei Zeilen würde ich aber ändern von

Code: Alles auswählen

filename_Unicode = AllocateMemory(Len(Filename) * 2 + 2)
  MultiByteToWideChar_(#CP_ACP, 0, @Filename, -1, filename_Unicode, Len(Filename) * 2 + 2)       

in

Code: Alles auswählen

CompilerIf #PB_Compiler_Unicode
	filename_Unicode = @Filename
CompilerElse
	filename_Unicode = AllocateMemory((Len(Filename) + 1) * SizeOf(Unicode))
	PokeS(filename_Unicode, Filename, -1, #PB_Unicode)
CompilerEndIf

Dafür muss am Ende aber auch noch das hier hin:

Code: Alles auswählen

CompilerIf Not #PB_Compiler_Unicode
	FreeMemory(filename_Unicode)
CompilerEndIf

@ts-soft:

[RSBasic]

@NicTheQuick
64 Bit-Kompatibilität.

[NicTheQuick]

64 Bit-Kompatibilität.

Was möchtest du damit sagen?

[RSBasic]

@ts-soft:

Gegenfrage: Was wolltest du damit sagen? Ich dachte, du wüsstest nicht, warum ts-soft gesagt hat, dass GetWindowLongPtr_() besser sei, als GetWindowLong_().
Oder was hast du damit gemeint?

[NicTheQuick]

Sein Post war vorher noch kaputt formatiert und unvollständig, da hab ich nicht kapiert, was er sagen wollte. Jetzt hat er es ja wieder editiert.

[ts-soft]

Noch etwas kürzer

Code: Alles auswählen

filename_Unicode = AllocateMemory(StringByteLength(Filename.s, #PB_Unicode) + 2)
PokeS(filename_Unicode, Filename, -1, #PB_Unicode)

;
;
FreeMemory(filename_Unicode)

PS: Beim ersten Posting von mir fehlte noch ein [ /code ]. Das sah einfach nur schrecklich aus

[NicTheQuick]

Ich vermeide das Kopieren lieber, wenn es nicht notwendig ist.