PureBoard

Code: Alles auswählen

;- Konstanten
Enumeration ; Window ID
  #Window
EndEnumeration

Enumeration ; Menu ID
  #Menu
EndEnumeration

Enumeration ; MenuItem ID
  #Menu_Exit
EndEnumeration

Enumeration ; Statusbar ID
  #Statusbar
EndEnumeration

Enumeration ; Gadget ID
  #List
EndEnumeration

; ***************************************************************************************

; Es müssen immer alle Variablen declariert werden

EnableExplicit

; ***************************************************************************************

Procedure UpdateWindow()

  Protected x,y,dx,dy
  Protected mn,st,tb
  
  x = 0
  y = 0
  mn = MenuHeight()
  st = StatusBarHeight(#StatusBar)
  ;tb = ToolBarHeight(#ToolBar)
  dx = WindowWidth(#Window)
  dy = WindowHeight(#Window) - mn - st - tb
  ResizeGadget(#List, x, y, dx, dy)
  
EndProcedure

Procedure WriteLog(Info.s)
  Protected temp.s
  temp = FormatDate("%YYYY.%MM.%DD %HH:%II:%SS - ", Date()) + Info
  AddGadgetItem(#List, -1, temp)
  If CountGadgetItems(#List) > 500
    RemoveGadgetItem(#List, 0)
  EndIf
EndProcedure

;- Globale Variablen
Global exit = 0

; Main in eine Procedure gekapselt

Procedure Main()

  Protected style, event, window, menu, gadget, type
 
  ;- Fenster
  style = #PB_Window_MinimizeGadget | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget
  If OpenWindow(#Window, #PB_Ignore, #PB_Ignore, 400, 300, "Fenster", style)
    ; Menu
    If CreateMenu(#Menu, WindowID(#Window))
      MenuTitle("&Datei")
        MenuItem(#Menu_Exit, "Be&enden")
    EndIf
    ; Statusbar
    CreateStatusBar(#Statusbar, WindowID(#Window))
    ; Gadgets
    ListViewGadget(#List, 0,0,0,0)
    
    ; Init
    WriteLog("Programm gestartet")
    
    ;-- Hauptschleife
    Repeat
      event = WaitWindowEvent()
      Select event
        Case #PB_Event_Menu                       ; ein Menü wurde ausgewählt
          menu = EventMenu()
          Select menu
            Case #Menu_Exit
              Exit = 1
          EndSelect
        Case #PB_Event_Gadget                     ; ein Gadget wurde gedrückt
          gadget = EventGadget()
          type = EventType()
        
        Case #PB_Event_CloseWindow                ; das Schließgadget vom Fenster wurde gedrückt
          window = EventWindow()
          If window = #Window
            Exit = 1
          EndIf
         
        Case #PB_Event_Repaint                    ; der Fensterinhalt wurde zerstört und muss neu gezeichnet werden (nützlich für 2D Grafik-Operationen)
        Case #PB_Event_SizeWindow                 ; das Fenster wurde in der Größe verändert
          window = EventWindow()
          If window = #Window
            UpdateWindow()
          EndIf

        Case #PB_Event_MoveWindow                 ; das Fenster wurde verschoben
        Case #PB_Event_ActivateWindow             ; das Fenster wurde aktiviert (hat den Fokus erhalten)
        Case #PB_Event_SysTray                    ; das SysTray wurde aktiviert
     
      EndSelect
     
    Until Exit
  EndIf
EndProcedure : Main() 

Code: Alles auswählen

; IDE - Source drucken
;~~~~~~~~~~~~~~~~~~~~~~

EnableExplicit

Procedure FileLoad(vFile.s, List vValue.s())
   If ReadFile(0, vFile)
      While Not Eof(0)
         AddElement(vValue())
         vValue() =  ReadString(0)
      Wend
      CloseFile(0)    
   EndIf
EndProcedure

Procedure PrintKopf(vFile.s)
   DrawingFont(FontID(0))
   DrawText(100, 100, vFile, #Black)
   DrawingFont(FontID(1))
EndProcedure

Procedure FilePrint(vFile.s, List vValue.s())
   Protected pValue.s, pX.i, pY.i = 400
   
   If PrintRequester()
      If StartPrinting("PureBasic Sourcedruck")
         LoadFont(0, "Arial", 75)
         LoadFont(1, "Arial", 50)
         If StartDrawing(PrinterOutput())
            DrawingMode(#PB_2DDrawing_Transparent)
            PrintKopf(vFile)
            ForEach vValue()
               pX = 100
               pValue =  RSet(Str(ListIndex(vValue())),4, "0") + ":  " + vValue()
               Repeat
                  DrawText(pX, pY, Left(pValue, 140), #Black)
                  If (pY=6600)
                     NewPrinterPage()
                     PrintKopf(vFile)   
                     pY = 400
                  Else
                     pY + 100
                  EndIf
                  pValue = Mid(pValue, 140)
                  pX = 300
               Until Not Len(pValue)
            Next
            StopDrawing()
         EndIf
         StopPrinting()
      EndIf
   EndIf
EndProcedure

Procedure Main(vFile.s)
   Protected NewList pValue.s()
   
   If vFile
      FileLoad (vFile, pValue())
      FilePrint(vFile, pValue())
   EndIf 
EndProcedure

Main (ProgramParameter())

End