Colisionscode streikt?!

AND51 · Beitrag von **AND51** » 01.06.2006 00:04

Kaeru Gaman hat geschrieben:der befehl braucht die Spritenummer, um höhe und breite zu ermitteln.
zusammen mit der x/y-pos hat sie dann ein rechteck.
nun überprüft sie lediglich, ob sich die beiden rechtecke überlappen.

Genau so hätte ich es auch sagen können, aber der Geistesblitz war wohl so heiß dass er seine Spuren hinterlassen hat.

Boah, geil, mal etwas verstanden zu haben...

Wie funkt denn SpritePixelCollision() eigentlich? Die normale Version könnte ich ja noch nachproggen, aber mit Transparenz?

Kaeru Gaman · Beitrag von **Kaeru Gaman** » 01.06.2006 00:06

die nimmt eben die jeweilige texture als maske.
checkt erst die rechteck-koordinaten, und checkt dann für den überlappenden bereich jedes pixel einzeln, ob es von beiden sprites dorthin gezeichnet wird.

[edit]
eine viel einfachere methode ist BoundingCircle:

du ermittelst die mittelpunkte beider sprites, dann deren abstand, dann schaust du, ob der kleiner ist als die summe der beiden kollisionsradien.

für viele bilderchen ist ein kreis ein schönerer kollisionsbereich als ein rechteck.
für ballergames ist das ideal.

[edit2]
> Eine andere Möglochkeit zum Kollisionsabfrgen gibt es doch gar nicht.

doch, eben dementsprechend aufwendige koordinaten-prüfungen.
ok, bei 2D hast du schnell die performance so weit unten wie bei pixel-kollision,
aber im 3D-bereich sind alle möglichen Boundings (Sphere, Box, etc),
irgendwelche formeln für regelmäßige geometrische formen weit effektiver, als tausende von polygonen auf überschneidungen zu checken.

AND51 · Beitrag von **AND51** » 01.06.2006 00:08

Achso. Abe ist das denn wirklich so ein Performanceverlust? Eine andere Möglochkeit zum Kollisionsabfrgen gibt es doch gar nicht.

Ghost · Beitrag von **Ghost** » 01.06.2006 21:09

sorry aber der Code Streikt wieder

also ich habe den Code jetzt so

Code: Alles auswählen

      ResetList(LGJaeger()) 
While NextElement(LGJaeger()) 
  ResetList(GatlingshootI()) 
While NextElement(GatlingshootI()) 
 If SpriteCollision(1,GatlingshootI()\x,GatlingshootI()\y,2, LGJaeger()\x, LGJaeger()\y) And LGJaeger()\Shield > 0
    DeleteElement(GatlingshootI())
   LGJaeger()\Shield - GatlingshootI()\Schildschaden
    EndIf 
 Wend
 Wend

So eigentlich klappt alles eine Zeit lang aber mitten im Spiel bricht er ab und der Debugger springt ein. Er makiert mir die Zeile" LGJaeger()\Shield - GatlingshootI()\Schildschaden" und schreibt drunter "Pointer is null"
Ich hatte sonst nur einige Variabeln verändert.

Kaeru Gaman · Beitrag von **Kaeru Gaman** » 01.06.2006 21:18

muha... muss ich erstmal lesbar machen...

Code: Alles auswählen

ResetList(LGJaeger()) 
While NextElement(LGJaeger()) 
  ResetList(GatlingshootI()) 
  While NextElement(GatlingshootI()) 
    If SpriteCollision(1,GatlingshootI()\x,GatlingshootI()\y,2, LGJaeger()\x, LGJaeger()\y) And LGJaeger()\Shield > 0
      DeleteElement(GatlingshootI())
      LGJaeger()\Shield - GatlingshootI()\Schildschaden
    EndIf 
  Wend
Wend

aalso...

ich hatte gesagt, du sollst den Schaden VOR dem löschen des schusses abziehen.
ist doch logisch, wenn du erst den schuss löscht, nimmst du für die rechnung den schaden von irgendeinem nächsten schuss, weil der, den du meinst, garnicht mehr existiert.

eventuell hängt auch daran der fehler, denn wenn du den letzten schuss gelöscht hast, hat die liste natürlich keine schüsse mehr, auf deren ()\Schildschaden du zugreifen kannst...

solche details sind ganz wichtig!

du musst dir immer bewusst sein, was du da grade im code anweist.
wenn du daten von einem listenelement verwenden willst, darfst du es nicht vorher löschen.

Ghost · Beitrag von **Ghost** » 01.06.2006 21:29

Ups sorry hab ich übersehen (dachte wäre andersrum also erst dividieren dann löschen)

sorum scheint es jedenfalls zu klappen
Danke nochmals

Kaeru Gaman · Beitrag von **Kaeru Gaman** » 01.06.2006 21:32

> Danke nochmals

kein problem, jederzeit wieder.

freundlichen, lernbereiten anfängern zu helfen macht mehr spass, als von blöden scriptkiddies angebagger zu werden "gib ma code, ey"

PS:
kleiner tip am rande: überarbeite mal deine formatierungen. ich finds schlecht lesbar. eigentlich macht man einrückungen eher so wie in meinem beispiel....

DarkDragon · Beitrag von **DarkDragon** » 04.06.2006 19:00

Ich habe vor einiger Zeit einen Code für Anfänger, die mich im ICQ kontaktierten geschrieben:

Code: Alles auswählen

; Sprite- und Keyboardfunktionen voreinstellen
If InitSprite() = 0 : MessageRequester("Error", "Can't init. screens and sprites") : End : EndIf
If InitKeyboard() = 0 : MessageRequester("Error", "Can't init. keyboard") : End : EndIf

; Geschwindigkeitskonstante
#SPEED = 2

; Diese Funktion prüft ob eine Kollision vorliegt
Procedure Collision(x.f, y.f)
  Result = 0
;   Gehe alle Tiles durch
  Restore Map
  
  For my=0 To 17
    For mx=0 To 24
      
      a.b
      Read a
;       Wenn der Tile-Typ 1(Mauer) ist, so prüfe auf eine Kollision mit diesem Tile...
      If a = 1
;         ... mit den entsprechenden Tile-koordinaten(IndexX*TileBreite, IndexY*TileBreite)...
;         ... und den entsprechenden Spieler-koordinaten(SpielerX, SpielerY)...
;         ... so, wie man es Zeichnen würde.
        If SpriteCollision(0, Int(x), Int(y), 1, mx*32, my*32)
;           Wenn ja: gib 1(True) zurück
          Result = 1
;           und springe aus beiden Schleifen(Anzahl: 2) raus
          Break 2
        EndIf
      EndIf
      
    Next
  Next
  
  ProcedureReturn Result
EndProcedure

; Öffne einen Screen
If OpenScreen(800, 600, 32, "Test") = 0 : MessageRequester("Error", "Can't open a screen") : End : EndIf

; Erstelle 2 Sprites
; Rotes viereck = Mauer
CreateSprite(0, 32, 32)
StartDrawing(SpriteOutput(0))
Box(0, 0, 32, 32, RGB(255, 0, 0))
StopDrawing()

; Blaues viereck = Spieler
CreateSprite(1, 32, 32)
StartDrawing(SpriteOutput(1))
Box(0, 0, 32, 32, RGB(0, 0, 255))
StopDrawing()

; Spielerposition genau in der Mitte des Bildschirms
X.f = 800/2
Y.f = 600/2

; Framerate auf 30 setzen(reich völlig)
SetFrameRate(30)

;- Hauptschleife
Repeat
;  Keyboardstatus erneuern und abfragen
  ExamineKeyboard()
  
  If KeyboardPushed(#PB_Key_Up)     ; laufe hoch
    If Collision(X, Y-#SPEED) = 0
      Y - #SPEED
    EndIf
  EndIf
  If KeyboardPushed(#PB_Key_Down)   ; laufe runter
    If Collision(X, Y+#SPEED) = 0
      Y + #SPEED
    EndIf
  EndIf
  If KeyboardPushed(#PB_Key_Left)   ; laufe links
    If Collision(X-#SPEED, Y) = 0
      X - #SPEED
    EndIf
  EndIf
  If KeyboardPushed(#PB_Key_Right)  ; laufe rechts
    If Collision(X+#SPEED, Y) = 0
      X + #SPEED
    EndIf
  EndIf
  
;   Beenden?
  If KeyboardPushed(#PB_Key_Escape)
    Quit = 1
  EndIf
  
;  Screeninhalt löschen und mit Schwarz überdecken
  ClearScreen(0, 0, 0)
;  Spieler anzeigen
  DisplaySprite(1, X, Y)
  
;  Mapdaten durchgehen
  Restore Map
  For my=0 To 17
    For mx=0 To 24
      
      a.b
      Read a
      If a = 1
;        Mauer = 1, also anzeigen
        DisplaySprite(0, mx*32, my*32)
      EndIf
      
    Next
  Next
;  Gefüllten Backbuffer zum Frontbuffer bringen
  FlipBuffers()
  
;  Eine kleine Verzögerung um den Prozessor nicht vollständig auszulasten
  Delay(5)
Until Quit = 1
End

; Mapdaten
DataSection
  Map:
  Data.b 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1
  Data.b 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
EndDataSection

Das erklärt auch, warum ich X/Y getrennt voneinander auf Kollision überprüfe. Nämlich damit man beim schräg gegen eine Wand laufen immernoch an der Wand entlangläuft und nicht steckenbleibt.