Speicherort des Programms ermitteln

[benpicco]

Wie kann ich rausbekommen, wo die exe Datei, die mein Programm ist und ausgeführt wird, gespeichert ist, dass ich dateien aus diesem Ordner kopieren kann?
Gibt´s da sowas wie %homedir% ?
Wenn ja, soll ich dann einfach copyfile("%...%ordner",zzielordner$) schreiben?

[Kiffi]

Wie kann ich rausbekommen, wo die exe Datei, die mein Programm ist
und ausgeführt wird, gespeichert ist

Code: Alles auswählen

Procedure.s GetAppPath()
  ProgrammPfad.s = Space(255)
  GetCurrentDirectory_(255, @ProgrammPfad)
  If Right(ProgrammPfad,1) <> ""
    ProgrammPfad + ""
  EndIf
  ProcedureReturn ProgrammPfad 
EndProcedure

Debug GetAppPath()

Grüße ... Kiffi

[benpicco]

Danke, aber gibt´s das auch in ner demofreundlichen Version?

[Leo]

Das hier sollte auch mit der Demo funzen

Code: Alles auswählen

Procedure.s GetAppPath() 
    If OpenLibrary(0,"kernel32.dll")
        *ptrGetDir = IsFunction(0,"GetCurrentDirectoryA")
        If *ptrGetDir
            ProgrammPfad.s = Space(255) 
            CallFunctionFast(*ptrGetDir,255, @ProgrammPfad)
            If Right(ProgrammPfad,1) <> "\" 
                ProgrammPfad + "\" 
            EndIf 
        EndIf 
        CloseLibrary(0)
    EndIf 
    ProcedureReturn ProgrammPfad 
EndProcedure 

Debug GetAppPath()

[ts-soft]

am besten noch das space(255) durch space(360) bzw. #MAX_PATH ersetzen !
Gruß
Thomas

[benpicco]

Danke, perfekt!

[ts-soft]

Gerade erst gesehen, das aktuelle Verzeichnis und das Programm Verzeichnis müssen nicht übereinstimmen. Deshalb hier nochmal der Code für die Demo:

Code: Alles auswählen

Procedure.s GetAppDir()
  FullPath.s = Space(360)
  DLL = OpenLibrary(#PB_Any, "Kernel32")
  CallFunction(DLL, "GetModuleFileNameA", CallFunction(DLL, "GetModuleHandleA", 0), @FullPath, 360)
  CloseLibrary(DLL)
  FullPath = GetPathPart(FullPath)
  If Right(FullPath, 1) <> "\" : FullPath + "\" : EndIf
  ProcedureReturn FullPath
EndProcedure

Debug GetAppDir()

und der Code für die Vollversion:

Code: Alles auswählen

Procedure.s GetAppDir()
  FullPath.s = Space(#MAX_PATH)
  GetModuleFileName_(GetModuleHandle_(0), @FullPath, #MAX_PATH)
  FullPath = GetPathPart(FullPath)
  If Right(FullPath, 1) <> "\" : FullPath + "\" : EndIf
  ProcedureReturn FullPath
EndProcedure

Debug GetAppDir()

Achtung: in der Entwicklungsumgebung wird der Pfad des PBCompilers zurückgegeben!

Gruß
Thomas