Bestimmten Teil einer String auschneiden

[R3booz]

Hallo,

habt ihr auf die schnelle eine Idee wie ich es am einfachsten umsetzten kann wenn ich das hier habe:

Code: Alles auswählen

string.s = "Hallo [weg damit] wie gehts"

und nur das

Code: Alles auswählen

[weg damit]

entfernen will, sprich alles was in eckigen klammern ist.

wie mach ich das am besten?

mfg R3booz

[RSBasic]

RegEx wäre genau das, was du suchst.

[R3booz]

Aber wie stell ich das mit Klammern an?

[ts-soft]

Code: Alles auswählen

Define string.s = "Hallo [weg damit] wie gehts"

Debug Left(string, FindString(string, "[") - 1) + Mid(string, FindString(string, "]") + 1)

[RSBasic]

Code: Alles auswählen

EnableExplicit

Define string.s = "Hallo [weg damit] wie gehts"
Define Result$

If CreateRegularExpression(0, "\[.*\]")
  Result$ = ReplaceRegularExpression(0, string, "")
  Debug Result$
Else
  Debug RegularExpressionError()
EndIf

[Kiffi]

ich will auch mal!

Code: Alles auswählen

Define string.s = "Hallo [weg damit] wie gehts"

Debug StringField(string, 1, "[") + StringField(string, 2, "]")

[ts-soft]

Kiffi is the Winner

[R3booz]

Vielen dank das reicht

mfg R3booz

[NicTheQuick]

Die Pointer-Variante fehlt aber noch!!

Code: Alles auswählen

Procedure.s removeBrackets(input.s)
	Protected *c.Character = @input
	Protected *o.Character = *c
	Protected remove.i = #False
	While *c\c
		If (*c\c = '[')
			remove = #True
		EndIf
		If (Not remove)
			*o\c = *c\c
			*o + SizeOf(Character)
		EndIf
		If (*c\c = ']')
			remove = #False
		EndIf
		*c + SizeOf(Character)
	Wend
	*o\c = 0
	ProcedureReturn input
EndProcedure

string.s = "Hallo [weg damit] wie gehts? - [Scheiße] Gut!"

Debug removeBrackets(string)

[STARGÅTE]

Ein .*? im Regex stellt sicher, dass auch mehere [ ] richtig geparst werden.

Code: Alles auswählen

EnableExplicit

Define string.s = "Hallo [weg damit] wie [das auch weg] gehts"
Define Result$

If CreateRegularExpression(0, "\[.*?\]")
  Result$ = ReplaceRegularExpression(0, string, "")
  Debug Result$
Else
  Debug RegularExpressionError()
EndIf