Listicon in Zwischenablage kopieren

[andi256]

Hallo,

gibt es eine (einfache) Möglichkeit den Inhalt eines Listicon in die Zwischenablage zu bekommen, so das man den Inhalt zb. in excel weiterverarbeiten kann?

(am schönsten wären wenn [Strg c] funktionieren würde) ...

Code: Alles auswählen

OpenWindow(0, 100, 300, 400, 200, "Listicon", #PB_Window_SystemMenu)
 ListIconGadget(1, 1, 1, 300, 160, "Spalte0", 100, #PB_ListIcon_GridLines | #PB_ListIcon_FullRowSelect | #PB_ListIcon_HeaderDragDrop |#PB_ListIcon_MultiSelect )

 AddGadgetColumn(1, 1, "Spalte1", 100)
 AddGadgetColumn(1, 2, "Spalte2", 100)
 AddGadgetColumn(1, 3, "Spalte3", 100)
 
 AddGadgetItem(1, -1, "0:0" + Chr(10) + "0:1" + Chr(10) + "0:2")
 AddGadgetItem(1, -1, "1:0" + Chr(10) + "1:1" + Chr(10) + "1:2")
 AddGadgetItem(1, -1, "2:0" + Chr(10) + "2:1" + Chr(10) + "2:2")
 AddGadgetItem(1, -1, "3:0" + Chr(10) + "3:1" + Chr(10) + "3:2")

Repeat
Until WindowEvent() = #PB_Event_CloseWindow 

Danke im Vorab
Andi

[Kiffi]

Code: Alles auswählen

EnableExplicit

OpenWindow(0, 100, 300, 400, 200, "Listicon", #PB_Window_SystemMenu)
ListIconGadget(1, 1, 1, 300, 160, "Spalte0", 100, #PB_ListIcon_GridLines | #PB_ListIcon_FullRowSelect | #PB_ListIcon_HeaderDragDrop |#PB_ListIcon_MultiSelect )

AddGadgetColumn(1, 1, "Spalte1", 100)
AddGadgetColumn(1, 2, "Spalte2", 100)
AddGadgetColumn(1, 3, "Spalte3", 100)

AddGadgetItem(1, -1, "0:0" + Chr(10) + "0:1" + Chr(10) + "0:2")
AddGadgetItem(1, -1, "1:0" + Chr(10) + "1:1" + Chr(10) + "1:2")
AddGadgetItem(1, -1, "2:0" + Chr(10) + "2:1" + Chr(10) + "2:2")
AddGadgetItem(1, -1, "3:0" + Chr(10) + "3:1" + Chr(10) + "3:2")

Enumeration 
  #Shortcut_CtrlC
EndEnumeration

AddKeyboardShortcut(0, #PB_Shortcut_Control | #PB_Shortcut_C, #Shortcut_CtrlC)

Define WWE
Define Csv.s
Define CountRows, RowCounter, CountCols, ColCounter

Repeat
  
  WWE = WaitWindowEvent()
  
  Select WWE
      
    Case #PB_Event_CloseWindow 
      Break 
      
    Case #PB_Event_Menu
      
      Select EventMenu()
          
        Case #Shortcut_CtrlC
          
          Csv = ""
          
          CountRows = CountGadgetItems(1)
          CountCols = 3
          
          For RowCounter = 0 To CountRows - 1
            For ColCounter = 0 To CountCols - 1
              Csv + GetGadgetItemText(1, RowCounter, ColCounter)
              If ColCounter < CountCols - 1
                Csv + ";"
              EndIf
            Next
            If RowCounter < CountRows - 1
              Csv + #CRLF$
            EndIf
          Next
          
          SetClipboardText(Csv)
          MessageRequester("Csv ist jetzt im ClipBoard", Csv)
          
      EndSelect
      
  EndSelect
  
ForEver

Grüße ... Kiffi

[mk-soft]

Nehme anstatt ";" das #TAB$. Dann funk´s auch mit Excel...

[rolaf]

Nehme anstatt ";" das #TAB$. Dann funk´s auch mit Excel...

Excel kann auch CSV und TABS nehme ich für die Dritten.