Listicon Item Checkbox de/aktivieren

[X360 Andy]

Schönen Abend,

ich suche gerade nach einer Möglichkeit alle Checkboxen zu aktivieren bzw sie deaktivieren zu lassen.

Beispiel was ich meine, was natürlich nicht funktioniert, weil nichts dementsprechendes vorhanden ist.

Code: Alles auswählen

Enumeration
  #Button_0
  #Button_1
  #ListIcon_0
EndEnumeration


Procedure Open_Window_0()
  If OpenWindow(0, 339, 238, 372, 247, "Listicon Item Checked",  #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar )
    ButtonGadget(#Button_0, 20, 200, 60, 30, "ALLE")
      ButtonGadget(#Button_1, 290, 200, 60, 30, "KEINE")
      
      ListIconGadget(#ListIcon_0, 20, 20, 330, 170, "Column0", 100, #PB_ListIcon_CheckBoxes | #PB_ListIcon_MultiSelect | #PB_ListIcon_GridLines)
      AddGadgetColumn(#ListIcon_0, 1, "Column1", 100)
      AddGadgetItem(#ListIcon_0,-1,"Eintrag 1"+Chr(10)+"Haus")
      AddGadgetItem(#ListIcon_0,-1,"Eintrag 2"+Chr(10)+"Baum")
      
  EndIf
EndProcedure
Open_Window_0()

Repeat
  event = WaitWindowEvent(50)
  
  Select event
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Button_0
          ; Alle auswählen
         
        Case #Button_1
          ; Auswahl zurückziehen
      EndSelect
    Case #PB_Event_CloseWindow
      Select EventWindow()
        Case 0
          exit = 1
      EndSelect
      
  EndSelect
  
Until exit = 1

Kennt einer eine Möglichkeit das irgendwie zu verwirklichen ?

Das ich die zu aktivierten mit "& #PB_Tree_Checked" abfragen kann ist mir klar, dies hab ich so auch in der Hilfe gefunden.

Viele Grüße Andreas

[STARGÅTE]

Für ListIcon gibts doch auch was:
SetGadgetItemState mit #PB_ListIcon_Checked

Code: Alles auswählen

Enumeration
  #Button_0
  #Button_1
  #ListIcon_0
EndEnumeration


Procedure Open_Window_0()
  If OpenWindow(0, 339, 238, 372, 247, "Listicon Item Checked",  #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_TitleBar )
    ButtonGadget(#Button_0, 20, 200, 60, 30, "ALLE")
      ButtonGadget(#Button_1, 290, 200, 60, 30, "KEINE")
      
      ListIconGadget(#ListIcon_0, 20, 20, 330, 170, "Column0", 100, #PB_ListIcon_CheckBoxes | #PB_ListIcon_MultiSelect | #PB_ListIcon_GridLines)
      AddGadgetColumn(#ListIcon_0, 1, "Column1", 100)
      AddGadgetItem(#ListIcon_0,-1,"Eintrag 1"+Chr(10)+"Haus")
      AddGadgetItem(#ListIcon_0,-1,"Eintrag 2"+Chr(10)+"Baum")
      
  EndIf
EndProcedure
Open_Window_0()

Repeat
  event = WaitWindowEvent(50)
  
  Select event
    Case #PB_Event_Gadget
      Select EventGadget()
        Case #Button_0
          ; Alle auswählen
          For Item = 0 To CountGadgetItems(#ListIcon_0)-1
            SetGadgetItemState(#ListIcon_0, Item, GetGadgetItemState(#ListIcon_0, Item)|#PB_ListIcon_Checked)
          Next
        Case #Button_1
          ; Auswahl zurückziehen
          For Item = 0 To CountGadgetItems(#ListIcon_0)-1
            SetGadgetItemState(#ListIcon_0, Item, GetGadgetItemState(#ListIcon_0, Item)&(~#PB_ListIcon_Checked))
          Next
      EndSelect
    Case #PB_Event_CloseWindow
      Select EventWindow()
        Case 0
          exit = 1
      EndSelect
      
  EndSelect
  
Until exit = 1

[X360 Andy]

Ach verdammt, habs nur mit Attributen versucht.... Danke