Wie Gadgetnummer per WindowCallback ermitteln?

[Rudi]

Folgender Code gibt mir alle Infos von wParam zurück.
Möchte aber nur die Gadgetnummern der dynamisch erstellten Textgadgets beim Anklicken haben.

Code: Alles auswählen

Procedure WinCallback(hWnd, uMsg, wParam, lParam)
Debug wParam

  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure

Procedure OpenWindow_Window_0()
  If OpenWindow(0, 300, 300, 400, 100, "Window_0")
  SetWindowCallback(@WinCallback())
  EndIf
EndProcedure

OpenWindow_Window_0()
For i=1 To 10
TextGadget(i,20*i,20,20,20,Str(i),#SS_NOTIFY)
Next

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_Gadget
    Case #PB_Event_CloseWindow
      Select EventWindow()
        Case 0
          CloseWindow(0)
          Break
      EndSelect
  EndSelect
ForEver

[ts-soft]

Code: Alles auswählen

GetProp_(hwnd, "PB_ID")

oder

Code: Alles auswählen

GetDlgCtrlID_(hWnd)

[Rudi]

Danke! Scheint aber nicht die richtige Lösung zu sein. Die Gadget-ID kommt nur beim Klick auf eines der Textgadgets und dann nur über wParam. Ich denke da muß über entsprechende Konstanten gefiltert werden, wie hier, aus der BP-Hilfe:

Code: Alles auswählen

  Procedure WinCallback(hWnd, uMsg, wParam, lParam) 
    ; Windows füllt die Parameter automatisch, welche wir im Callback verwenden...
    
    If uMsg = #WM_SIZE 
      Select wParam 
        Case #SIZE_MINIMIZED 
          Debug "Fenster wurde minimiert"
        Case #SIZE_RESTORED 
          Debug "Fenster wurde wiederhergestellt"
        Case #SIZE_MAXIMIZED 
          Debug "Fenster wurde maximiert"
      EndSelect 
    EndIf 
  
    ProcedureReturn #PB_ProcessPureBasicEvents 
  EndProcedure 

[ts-soft]

Wenn das Händel in wParam ist, dann sollstest Du hWnd auch durch wParam ersetzen!
Bei #PB_Any ist die ID ein Pointer, also eine sehr hohe Nummer

[Rudi]

Mit Debug GetDlgCtrlID_(wParam) kommt die Gadgetnummer jetzt schon beim Überfahren mit der Maus. Also gut!
Wollte aber, dass erst bei Mausklick was passiert.
Der hier geht nicht:

Code: Alles auswählen

If uMsg = #WM_LBUTTONDOWN
  Debug GetDlgCtrlID_(wParam)
EndIf 

[Kiffi]

Wollte aber, dass erst bei Mausklick was passiert.

probier mal das hier:

Code: Alles auswählen

  If uMsg = #WM_COMMAND
    Select (wParam >> 16) & $FFFF ; Message
      Case #BN_CLICKED            ;  -> Button Clicked
        Debug "Click" 
    EndSelect 
  EndIf 

(grade eben aus anderen Postings zusammengestöpselt)

Grüße ... Kiffi

[edel]

Wenn du Informationen zu einer Windowsmessage brauchst, suchst du sie am besten hier :
http://social.msdn.microsoft.com/Search/en-US?query=

Dort steht dann was genau wParam und lParam ist und was nicht.

Zu deinem Problem :

Code: Alles auswählen

Macro _LOWORD(a) 		: (a & $FFFF)       : EndMacro
Macro _HIWORD(a) 		: (a >> 16 & $FFFF) : EndMacro 

Procedure WinCallback(hWnd, uMsg, wParam, lParam)
  
  If uMsg = #WM_COMMAND
    
    If _HIWORD(wParam) = #STN_CLICKED
      
      Debug _LOWORD(wParam) 
      
    EndIf

  EndIf
  
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure

[Rudi]

Besten Dank an ts-soft, Kiffi und edel!
Der Code von edel funktioniert ganz edel. Muss mich da aber erst noch rein denken, um ihn zu verstehen. Der Abend ist nun gerettet...
Hier noch einmal der Code insgesamt:

Code: Alles auswählen

Macro _LOWORD(a) : (a & $FFFF)       : EndMacro
Macro _HIWORD(a) : (a >> 16 & $FFFF) : EndMacro

Procedure WinCallback(hWnd, uMsg, wParam, lParam)
 
  If uMsg = #WM_COMMAND
    If _HIWORD(wParam) = #STN_CLICKED
      Debug _LOWORD(wParam)
    EndIf
  EndIf
 
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure

Procedure OpenWindow_Window_0()
  If OpenWindow(0, 300, 300, 400, 100, "Window_0")
  SetWindowCallback(@WinCallback())
  EndIf
EndProcedure

OpenWindow_Window_0()
For i=1 To 10
TextGadget(i,20*i,20,20,20,Str(i),#SS_NOTIFY)
Next

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_Gadget
    Case #PB_Event_CloseWindow
      Select EventWindow()
        Case 0
          CloseWindow(0)
          Break
      EndSelect
  EndSelect
ForEver