F10 abfragen

[netzcoder]

Hallo,
ich möchte gerne abfragen ob F10 gedrückt wurde. Hab ein Fenster welches "Invisible" gesetzt ist. Nun möchte ich wenn F10 gedückt wird eine Aktion ausführen.
If GetAsyncKeyState_(#VK_F10) liefert leider beim drücken und beim loslassen ein Event. Das möchte ich aber nicht.
Euer netzcoder

[c4s]

Was für einen Wert liefert es denn? Denk mal ganz scharf nach.

[STARGÅTE]

Jo es gibt mehrere Werte, das sieht etwa so aus:

Code: Alles auswählen

Repeat
 Delay(10)
 Event = GetAsyncKeyState_(#VK_F10)
 If Event
  Debug Event
 EndIf
ForEver

-32767
-32768
-32768
-32767
-32767
1

1 : steht für losgelassen, wird aber nicht immer registriert!
-32767 : steht für den ersten Anschlag oder später für "dauer-Feuer"
-32768 : steht für taste wird gedrückt, soll aber noch kein "dauer-Feuer" sein.

[netzcoder]

Das hört sich ja alles irgendwie sehr wage an. Also gibt es nichts wirklich gutes?

[Kaeru Gaman]

das ist nicht vage, das ist sehr eindeutig.
lies dir bitte Stargates Posting noch mal durch.

eine Korrektur:
der Rückgabewert von GetAsyncKeystate ist kein Event.

Code: Alles auswählen

Repeat
  Delay(10)
  State_F10 = GetAsyncKeyState_(#VK_F10)
  If State_F10
    Debug State_F10
  EndIf
ForEver

nur kosmetisch, aber wichtig damit keine Verwechslungen aufkommen.

-----------------------------------

If GetAsyncKeyState_(#VK_F10) liefert leider beim drücken und beim loslassen ein Event.

ist grundsätzlich Falsch!
wie gesagt es ist kein Event und es liefert auch kein Event.
bei jeder Abfrage wird es einen Wert liefern, gemäß der Meßreihe wie Stargate sie gezeigt hat.

wenn du jetzt natürlich durch den Aufbau deiner Eventschleife bedingt diesen Wert bei WM_KEYDOWN und WM_KEYUP ausführst, erhältst du die Zustandswerte zu diesen beiden Zeitpunkten.

[netzcoder]

Vielen Dank für die Hilfe. Hab es jetzt!

[Pelagio]

Hallo Leute,

warum so umständlich, da man ja weiß das F10 abgefragt wird kann man da nicht 'AddKeyboardShortcut ' benutzen?

Code: Alles auswählen

If OpenWindow(0, 0, 0, 400, 100, "Example", #PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_Invisible)
   AddKeyboardShortcut(0, #PB_Shortcut_F10, 10)     
   SetActiveWindow(0)
   Repeat
      Event = WaitWindowEvent()
      If Event=#PB_Event_Menu And EventMenu()=10
        HideWindow(0, #False)
      EndIf    
   Until Event = #PB_Event_CloseWindow
EndIf

[ts-soft]

Hallo Leute,

warum so umständlich, da man ja weiß das F10 abgefragt wird kann man da nicht 'AddKeyboardShortcut ' benutzen?

Weil Dein Code, sobald ein anderes Fenster aktiviert wurde, nicht mehr funktioniert.

Mit folgendem Code könnte man das lösen:

Code: Alles auswählen

Macro LoWord(long)
  long & $FFFF
EndMacro

Macro HiWord(long)
  (long >> 16) & $FFFF
EndMacro

OpenWindow(0, #PB_Ignore, #PB_Ignore, 640, 480, "", #PB_Window_SystemMenu | #PB_Window_Invisible)
RegisterHotKey_(WindowID(0), 1, 0, #VK_F10)

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow : Break
    Case #WM_HOTKEY
      If HiWord(EventlParam()) = #VK_F10
        Debug "Hallo, F10 gedrückt!"
      EndIf
  EndSelect
ForEver

UnregisterHotKey_(WindowID(0), 1)

Aber nochmal in der MSDN nachschauen, im Beispiel ist keine Fehlerbehandlung usw.
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Gruß
Thomas

[netzcoder]

An ts-soft: Dein Code ist wirklich Gold wert. Genau so etwas habe ich gesucht. Vielen vielen Dank.

netzcoder

[ts-soft]

An ts-soft: Dein Code ist wirklich Gold wert. Genau so etwas habe ich gesucht. Vielen vielen Dank.

netzcoder

Kein Problem, aber mit F10 sollteste es nicht verwenden, das könnte schief gehen. Lieber etwas ungewöhnlicher,
z.B. Alt + F10

Code: Alles auswählen

 Macro LoWord(long)
  long & $FFFF
EndMacro

Macro HiWord(long)
  (long >> 16) & $FFFF
EndMacro

OpenWindow(0, #PB_Ignore, #PB_Ignore, 640, 480, "", #PB_Window_SystemMenu | #PB_Window_Invisible)
RegisterHotKey_(WindowID(0), 1, #MOD_ALT, #VK_F10)

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_CloseWindow : Break
    Case #WM_HOTKEY
      If HiWord(EventlParam()) = #VK_F10 And LoWord(EventlParam()) = #MOD_ALT
        Debug "Hallo, F10 gedrückt!"
      EndIf
  EndSelect
ForEver

UnregisterHotKey_(WindowID(0), 1)