PB_Window_BorderLess in Version 4.41 nicht OK?

[mama]

Hallo,

ist es in Ordnung, daß mit der neuen Version 4.41 unter Windows z.B. bei
OpenWindow(2, Breite0, 0, Breite1, Hoehe1, "TV",#PB_Window_BorderLess|#PB_Window_Tool)
die Fensterkopzeile trotzdem angezeigt wird?
Bisher (v4.40) hatte ich hier ein anderes Verhalten.

Bitte entschuldigt, falls ich hier falsch bin.
Grüße,
Martin

[ts-soft]

Die Kombination ist unlogisch, deshalb ist auch kein bestimmtes Aussehen richtig.

[STARGÅTE]

richtig!

#PB_Window_Tool bedeutet ja nur das es ein "mini"-X oben rechts gibt. das steht aber im widerspruch "BorderLess".

Um ein Rahmenloses Fester "unterzuordner" gibs die ParentID bei OpenWindow

[mama]

Welche Möglichkeit habe ich sonst, um Taskleisteneintrag und Rahmen loszuwerden?

Grüße,
Martin

[STARGÅTE]

habe ich das nicht eben geschrieben ?
Dafür gibs ParentID

Code: Alles auswählen

OpenWindow(0, 100, 100, 200, 200, "Fenster", #PB_Window_MinimizeGadget)
 OpenWindow(1, WindowX(0)+300, WindowY(0), 200, 200, "", #PB_Window_BorderLess, WindowID(0))

Repeat

 Event = WaitWindowEvent()
 
 Select Event
  Case #PB_Event_CloseWindow
   End
 EndSelect

ForEver

[mama]

Ah ja. ParentID.
Kannte ich bisher noch nicht. Vielen Dank, das werde ich gerne benutzen.
Danke auch für das Beispiel!!

Grüße,
Martin

[hörmi]

hier mal ein kleiner vorschlag von mir (hat den vorteil das man kein zweites fenster braucht:

mit grundlage von DarkDragon

Code: Alles auswählen

#CLSCTX_INPROC_SERVER = 1
#CLSCTX_LOCAL_SERVER  = 4
#CLSCTX_SERVER        = #CLSCTX_INPROC_SERVER | #CLSCTX_LOCAL_SERVER

If OpenWindow(0, 10, 0, 300, 50, "Test",#PB_Window_BorderLess)
  ButtonGadget(0,0,0,50,20,"Hide")
  ButtonGadget(1,50,0,50,20,"Show")
  CoInitialize_(0)
  
  *tb.ITaskbarList2
  res = CoCreateInstance_(?CLSID_TaskbarList, 0, #CLSCTX_SERVER, ?IID_ITaskbarList, @*tb)
  
  Repeat
    Event = WindowEvent()
    Select Event
      Case #PB_Event_CloseWindow
        Break
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 0
            *tb\DeleteTab(WindowID(0))
          Case 1
            *tb\addTab(WindowID(0))
        EndSelect
    EndSelect
  ForEver
  
  CoUninitialize_()
  
  End
  
EndIf

DataSection
  CLSID_TaskbarList:
  ; 56FDF344-FD6D-11D0-958A-006097C9A090
  Data.l $56FDF344
  Data.w $FD6D, $11D0, $8A95
  Data.b $00, $60, $97, $C9, $A0, $90
  IID_ITaskbarList:
  ; {56FDF342-FD6D-11D0-958A-006097C9A090}
  Data.l $56FDF342
  Data.w $FD6D, $11D0, $8A95
  Data.b $00, $60, $97, $C9, $A0, $90
EndDataSection

Edit: hab Borderless vergessen

[ts-soft]

da wird nirgends released und gefällt mir so garnicht, besser:

Code: Alles auswählen

DataSection
  CLSID_TaskBarList:
  Data.l $56FDF344
  Data.w $FD6D, $11D0
  Data.b $95, $8A, $00, $60, $97, $C9, $A0, $90
  IID_ITaskBarList:
  Data.l $56FDF342
  Data.w $FD6D, $11D0
  Data.b $95, $8A, $00, $60, $97, $C9, $A0, $90
EndDataSection

Procedure HideFromTaskBar(hWnd, Flag)
  Protected TBL.ITaskbarList

  CoInitialize_(0)
  If CoCreateInstance_(?CLSID_TaskBarList, 0, 1, ?IID_ITaskBarList, @TBL) = #S_OK
    TBL\HrInit()
    If Flag
      TBL\DeleteTab(hWnd)
    Else
      TBL\AddTab(hWnd)
    EndIf
    TBL\Release()
  EndIf
  CoUninitialize_()
EndProcedure

If OpenWindow(0, 100, 100, 300, 50, "Test")
  ButtonGadget(0,0,0,50,20,"Hide")
  ButtonGadget(1,50,0,50,20,"Show")

  Repeat
    Event = WindowEvent()
    Select Event
      Case #PB_Event_CloseWindow
        Break
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 0
            HideFromTaskBar(WindowID(0), #True)
          Case 1
            HideFromTaskBar(WindowID(0), #False)
        EndSelect
    EndSelect
  ForEver
 
EndIf

Gruß
Thomas

[hörmi]

Ok deins ist besser, aber ich wollte einfach nur einen weiteren Vorschlag bringen

[ts-soft]

Ok deins ist besser, aber ich wollte einfach nur einen weiteren Vorschlag bringen

Hab ich doch keiner was gegen gesagt , habs nur verschlimmbessert.