TELNET Verbindung herstellen und in den Speicher lesen

[dl5ndh]

Hallo,
ich kann als Funkamateur mich in ein TELNET DX Cluster einwählen, indem
man einfach sagt : telnet://gb7mbc.spoo.org:8000/, das letztere also in die
Adresszeile des Browsers eingibt und dann öffnet sich ein kleines Fenster und
man ist fast im TELNET Rechner drin. Dann nur noch das Rufzeichen eingeben,
zum Beispiel DL5ZZZ, ENTER. Jetzt kommen laufend die DX-Meldungen Zeile
für Zeile...
Frage bitte: Wie kann ich mich mit PureBASIC (Welche Befehle) in dieses o.g.
DX Cluster einloggen, also Aufruf der TELNET Adresse, das Rufzeichen DL5ZZZ
eingeben und wie kann ich dann Zeile für Zeile dieser laufenden DXMeldungen
auslesen?
Vielleicht kann mir da jemand mit einem Beispiel helfen.

Gruß Gerhard

[tobe]

hallo Gerhard,

ich würde es so machen:

Code: Alles auswählen

InitNetwork()
OpenConsole()
Define Verbindung, *Buffer
;
Procedure CheckString(String$)
  Shared Verbindung
  Print(String$)
  If FindString(String$, "login:", 1)
    SendNetworkString(Verbindung, "DL5ZZZ" + #LF$)
  EndIf
EndProcedure
;
Verbindung = OpenNetworkConnection("gb7mbc.spoo.org", 8000)
If Verbindung
  Repeat
    Select NetworkClientEvent(Verbindung)
      Case 0
        Delay(1)
      Case #PB_NetworkEvent_Data
        *Buffer = AllocateMemory(1024)
        If *Buffer
          CheckString(PeekS(*Buffer, ReceiveNetworkData(Verbindung, *Buffer, 1024)))
          FreeMemory(*Buffer)
        Else
          MessageRequester("Error", "Konnte den angeforderten Speicher nicht reservieren!")
        EndIf
    EndSelect
  ForEver
Else
  MessageRequester("Error", "Verbindung konnte nicht hergestellt werden!", 0)
EndIf

[dl5ndh]

Hallo Tobe,
recht herzlichen Dank für Deine außerordentliche Mühe wegen meinem
TELNET Problem. Ich kam einfach nicht mit den Networkbefehlen weiter.
Du hast es geschafft, congrats!
Ich habe es ausprobiert und es läuft ganz super. Ich kann alles so prima
verwenden.
DANKE

Gruß Gerhard