Button Abfrage

[The_Dark_Zim-.-]

HEY HO
Ich hab da ein Problem mit der Abfrage meiner Buttons.
Und zwar gehen die nich immer.
Hier der Code:

Code: Alles auswählen

InitMovie()
MovieName$ = OpenFileRequester("Choose the movie to play", "", "Movie files|*.*", 0)
If MovieName$
  If LoadMovie(0, MovieName$)
  
    OpenWindow(1,100,170,MovieWidth(0),MovieHeight(0), "PureBasic - Movie", #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget | #PB_Window_SizeGadget)
    
    CreateGadgetList(WindowID(1))
    ButtonGadget(4,0,0,20,20,"Ô")
    ButtonGadget(5,25,0,20,20,"Ô")
    ButtonGadget(7,50,0,20,20,"Ô")
    ButtonGadget(6,75,0,20,20,"Ô")
    
    PlayMovie(0, WindowID(1))
    ResizeMovie(0,0,21,MovieWidth(0),MovieHeight(0))
    Repeat
    
  Event = WaitWindowEvent()
  GadgetID = EventGadget()
      
 Delay(0)

   Select WaitWindowEvent()
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 4
         ResizeMovie(0,0,21,WindowWidth(1),WindowHeight(1))
        Case 5
         ResizeMovie(0,0,21,MovieWidth(0),MovieHeight(0))
        Case 6
         PauseMovie(0)
        Case 7
         ResumeMovie(0)
      EndSelect
    EndSelect
   Until WaitWindowEvent() = #PB_Event_CloseWindow
  Else
    MessageRequester("Error", "Can't load the movie...", 0)
  EndIf
 EndIf

Hoffe ihr könnt helfen.

Gruß Zim

[ts-soft]

Code: Alles auswählen

InitMovie()
MovieName$ = OpenFileRequester("Choose the movie to play", "", "Movie files|*.*", 0)
If MovieName$
  If LoadMovie(0, MovieName$)

    OpenWindow(1,100,170,MovieWidth(0),MovieHeight(0), "PureBasic - Movie", #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget | #PB_Window_SizeGadget)

    CreateGadgetList(WindowID(1))
    ButtonGadget(4,0,0,20,20,"Ô")
    ButtonGadget(5,25,0,20,20,"Ô")
    ButtonGadget(7,50,0,20,20,"Ô")
    ButtonGadget(6,75,0,20,20,"Ô")

    PlayMovie(0, WindowID(1))
    ResizeMovie(0,0,21,MovieWidth(0),MovieHeight(0))

    Repeat

      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Break
        Case #PB_Event_Gadget
          Select EventGadget()
            Case 4
              ResizeMovie(0,0,21,WindowWidth(1),WindowHeight(1))
            Case 5
              ResizeMovie(0,0,21,MovieWidth(0),MovieHeight(0))
            Case 6
              PauseMovie(0)
            Case 7
              ResumeMovie(0)
          EndSelect
      EndSelect
    ForEver
  Else
    MessageRequester("Error", "Can't load the movie...", 0)
  EndIf
EndIf

Jedesmal, wenn Du WaitWindowEvent() nutzt, wird dort das Event aus
dem Pool genommen. Du hattest 3x WaitWindowEvent() in Deinem Code,
da ist es kein Wunder, wenn events geklaut sind


Teste mal mit obigem Code weiter

Gruß
Thomas

[The_Dark_Zim-.-]

ich wieder, das kommt davon wenn man vieles einfach kopiert XD
THX scheint nun zu gehen