[gelöst] Problem mit #PB_Event_Gadget / EventGadget()

[scholly]

moin, moin...

Mein Problemcode:

Code: Alles auswählen

;In real lese ich mehr aus einer Ini ein
Dim top.s(8)
top(1) = "Speicherort"
top(2) = "Kategorien"
top(3) = "Titel"
top(4) = "Genre"
top(5) = "Artist"
top(6) = "Owner"
top(7) = "Todo"

If OpenWindow(0, 216, 0, 300, 300, "TreeGadget with Functions", #PB_Window_TitleBar | #PB_Window_SystemMenu ) 
  If CreateGadgetList(WindowID(0)) 

    TreeGadget(20, 10, 10, 270, 190) 
    For counter = 1 To 7
      AddGadgetItem(20, -1, top(counter))
    Next
    
  EndIf 
EndIf 
  
Repeat

  Select WaitWindowEvent()

    Case #PB_Event_CloseWindow; Close-Button gedrückt
      Quit = #True

    Case #PB_Event_Gadget                     ; Gadget-Events abarbeiten
    
      Select EventGadget()
        Case 20                               
          Debug "Eintrag (GetGadgetItemText)  : " + GetGadgetItemText(20, GetGadgetState(20), 0) 
      EndSelect; Select EventGadget()
      
  EndSelect; WaitWindowEvent()

Until Quit = #True

End

Wenn ich einen Eintrag selektiere, erhalte ich 2 Debug-Zeilen zu dem Eintrag.
Wenn ich blind ins Gadget klicke, eine Debug-Zeile zu dem selektierten Eintrag.

Eigentlich wollte ich nur dann eine erhalten, wenn ich einen Eintrag neu selektiere.
Was mache ich falsch ?

tia... scholly

[edel]

Du musst EventType() einbauen.

[mk-soft]

EventType abfgragen

Code: Alles auswählen

;In real lese ich mehr aus einer Ini ein
Dim top.s(8)
top(1) = "Speicherort"
top(2) = "Kategorien"
top(3) = "Titel"
top(4) = "Genre"
top(5) = "Artist"
top(6) = "Owner"
top(7) = "Todo"

If OpenWindow(0, 216, 0, 300, 300, "TreeGadget with Functions", #PB_Window_TitleBar | #PB_Window_SystemMenu )
  If CreateGadgetList(WindowID(0))

    TreeGadget(20, 10, 10, 270, 190)
    For counter = 1 To 7
      AddGadgetItem(20, -1, top(counter))
    Next
   
  EndIf
EndIf
 
Repeat

  Select WaitWindowEvent()

    Case #PB_Event_CloseWindow; Close-Button gedrückt
      Quit = #True

    Case #PB_Event_Gadget                     ; Gadget-Events abarbeiten
      type = EventType()
      Select EventGadget()
        Case 20
          Select type                               
            Case #PB_EventType_LeftClick : Debug "LeftClick: Eintrag (GetGadgetItemText)  : " + GetGadgetItemText(20, GetGadgetState(20), 0)
            Case #PB_EventType_Focus     : Debug "Focus: Eintrag (GetGadgetItemText)  : " + GetGadgetItemText(20, GetGadgetState(20), 0)
            Case #PB_EventType_Change    : Debug "Change: Eintrag (GetGadgetItemText)  : " + GetGadgetItemText(20, GetGadgetState(20), 0)
          EndSelect  
      EndSelect; Select EventGadget()
     
  EndSelect; WaitWindowEvent()

Until Quit = #True

End

FF

[scholly]

Merci vielmals,

besonders, da ich mit dem neuen Code quasi schon eine Antwort auf eine Frage bekommen habe, die eigentlich erst später aufgetaucht wäre

bis denne... scholly