Screenproblem

[Janno]

Ich habe ein Problem mit dem Screen-befehl.
Ich will, dass, wenn man eine Taste drückt, der Bildschirm einfach schwarz wird.

Code: Alles auswählen

InitSprite()
InitKeyboard()

OpenScreen(800,600,16,"")

Repeat
ExamineKeyboard()
FlipBuffers()

If KeyboardPushed(#PB_Key_Space)
  ClearScreen(RGB(255,255,255))
EndIf

Until KeyboardPushed(#PB_Key_Escape)

Das Problem ist dabei, dass sobald ein Sprite mit dabei ist, der Bildschirm wieder normal wird, wenn man die Taste loslässt

Code: Alles auswählen

InitSprite()
InitKeyboard()

OpenScreen(800,600,16,"")
LoadSprite(1,"Bilder\Back.bmp",0)

Repeat
ExamineKeyboard()
FlipBuffers()

DisplaySprite(1,0,0)

If KeyboardPushed(#PB_Key_Space)
  ClearScreen(RGB(255,255,255))
EndIf

Until KeyboardPushed(#PB_Key_Escape)

[#NULL]

würd ich wahrscheinlich so machen (übrigens is RGB(255,255,255) weiß )

Code: Alles auswählen

InitSprite()
InitKeyboard()

OpenScreen(800,600,16,"")
LoadSprite(1,"c:\test\a.bmp",0)

show=1

Repeat
  ClearScreen(0)
  ExamineKeyboard()
  
  If KeyboardReleased( #PB_Key_Space)
    show!1
  EndIf
  
  If show
    DisplaySprite(1,Random(50),Random(50))
  EndIf
  FlipBuffers()
  
Until KeyboardPushed(#PB_Key_Escape)

[Kaeru Gaman]

bei einem screen hast du 2 buffer die permanent wechseln,
und du baust in jedem schleifendurchlauf den bildschirm komplett auf,
von clear bis er fertig ist, und dann per flipbuffers angezeigt wird.

ich hab mal was mit reingebaut, damit man auch was auf dem bild sieht.
wenn man Return drückt, wird die Farbkombination Blau/Gelb,
wenn man Space drückt, wird sie Schwarz/Weiß.

Code: Alles auswählen

InitSprite() 
InitKeyboard() 

OpenScreen(800,600,16,"") 

Repeat 
  ExamineKeyboard() 

  If KeyboardPushed(#PB_Key_Space) 
    Color = $000000 
  EndIf 
  If KeyboardPushed(#PB_Key_Return) 
    Color = $FF0000 
  EndIf 

  ClearScreen(Color)
  Color2 = Color ! $FFFFFF
  StartDrawing(ScreenOutput())
    DrawingMode(4)
    For n= go To 280 Step 8
      Circle(400,300,n, Color2)
    Next
  StopDrawing()

  go +1 : If go > 8 : go = 1 : EndIf

  FlipBuffers() 

Until KeyboardPushed(#PB_Key_Escape)

[Janno]

danke für die schnelle hilfe
(ich weiß das rgb(255,255,255) weiß ist, aber wenn ich schwarz genommen hätte, hätte sich nichts verändert )

[#NULL]

@KG

[Alves]

@ Kaeru

Ich rkieg mich nich mehr ein^^