Probleme de fermeture de fenetre

[ThoT]

Bonjour à tous!
Mon souci du soir est que je n'arrive pas à fermer une fenetre.
Je vous donne le code :

Code : Tout sélectionner

Enumeration
#fenetre_menu
#fenetre_nouvelle_entree
#fenetre_infos
#font_arial24
#texte_titre_menu
#texte_nom
#texte_infos
#texte_prenom
#champ_nom
#champ_prenom
#bouton_nouvelle_entree
#bouton_2
#bouton_menu_quitter
#bouton_nouvelle_valider
#bouton_nouvelle_quitter
#bouton_infos_ok
EndEnumeration

Procedure ouvrir_menu()
If OpenWindow(#fenetre_menu,0,0,120,130,"Repertoire | Menu",#PB_Window_ScreenCentered) And CreateGadgetList(WindowID(#fenetre_menu))
LoadFont(#font_arial24,"Arial", 24)
TextGadget(#texte_titre_menu,10,5,100,40,"Menu",#PB_Text_Center)
SetGadgetFont(#texte_titre_menu,FontID(#font_arial24))
ButtonGadget(#bouton_nouvelle_entree,10,50,100,20,"Nouvelle entrée")
ButtonGadget(#bouton_2,10,75,100,20,"Recherche")
ButtonGadget(#bouton_menu_quitter,10,100,100,20,"Quitter")
EndIf
EndProcedure

Procedure ouvrir_nouvelle_entree()
If OpenWindow(#fenetre_nouvelle_entree,0,0,640,480,"Repertoire | Nouvelle entrée",#PB_Window_ScreenCentered) And CreateGadgetList(WindowID(#fenetre_nouvelle_entree))
TextGadget(#texte_nom,20,20,50,20,"Nom :")
TextGadget(#texte_prenom,20,50,50,20,"Prenom :")
StringGadget(#champ_nom,100,20,200,20,"")
StringGadget(#champ_prenom,100,50,200,20,"")
ButtonGadget(#bouton_nouvelle_valider,100,120,100,50,"Enregistrer")
ButtonGadget(#bouton_nouvelle_quitter,240,120,100,50,"Quitter")
EndIf
EndProcedure

Procedure infos(nom.s,prenom.s)
If OpenWindow(#fenetre_nouvelle_entree,0,0,320,240,"Repertoire | Infos",#PB_Window_ScreenCentered) And CreateGadgetList(WindowID(#fenetre_nouvelle_entree))
TextGadget(#texte_infos,20,20,180,20,"Vous vous appelez "+prenom+" "+nom+"!")
ButtonGadget(#bouton_infos_ok,110,180,100,50,"OK")
EndIf
EndProcedure
ouvrir_menu()

Repeat

evenement = WaitWindowEvent()

;Dans quelle fenetre se produit l'evenement?
Select EventWindow()
;Si c'est dans la fenetre menu
  Case #fenetre_menu
;On recherche le type d'evenement
    Select evenement
;Si c'est un evenement gadget
      Case #PB_Event_Gadget
;On recherche quel gadget est concerné
        Select EventGadget()
;Si c'est le bouton "nouvelle_entrée"
          Case #bouton_nouvelle_entree
;On ouvre la fenetre appropriée
            ouvrir_nouvelle_entree()
;Si c'est le bouton_2
          Case #bouton_2
;On joue un son (en attendant mieux)
            Beep_(3000,100)
;Si c'est le bouton quitter
          Case #bouton_menu_quitter
;On quitte le programme
          End
        EndSelect
    EndSelect

  Case #fenetre_nouvelle_entree
    Select evenement
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #bouton_nouvelle_valider
          infos(GetGadgetText(#champ_nom),GetGadgetText(#champ_prenom))
          Case #bouton_nouvelle_quitter
          CloseWindow(#fenetre_nouvelle_entree)
        EndSelect
    EndSelect

;----------C'est là que je n'arrive pas à fermer la fenetre---------
  Case #fenetre_infos
    Select evenement
      Case #PB_Event_Gadget
        Select EventGadget()
          Case #bouton_infos_ok
          CloseWindow(#fenetre_infos)
        EndSelect
    EndSelect
EndSelect

ForEver

End

Ca doit etre quelque chose de tout bete voir de trés con, mais je ne vois pas...
Merci à qui m'aidera!

Et si jamais vous avez des critiques sur mon code autres que concernant mon probleme, je suis aussi preneur!

[Octavius]

C'est tout bête, ta fenêtre d'info, tu ne l'ouvres pas avec la bonne constante. Regardes bien ta procédure infos(nom.s,prenom.s)

Tu as :

Code : Tout sélectionner

OpenWindow(#fenetre_nouvelle_entree,0,0,320,240,"Repertoire | Infos",#PB_Window_ScreenCentered)

Qui devrait être normalement :

Code : Tout sélectionner

OpenWindow(#fenetre_infos,0,0,320,240,"Repertoire | Infos",#PB_Window_ScreenCentered)

[ThoT]

Je savais que c'etait tout bete...
Merci beaucoup Octavius!