Savoir combien de fois est exécuté un programme [résolu]

Dr. Dri · Message par **Dr. Dri** » lun. 24/oct./2005 11:40

J'ai essayé de faire un truc simple qui fonctionne peut-être. J'ai pas d'XP sous la main pour tester mais si ca ne fonctionne pas y restera toujours la méthode OSVersion()... Avec 98 c'est nickel. Pour tester il faut créer un exécutable et le lancer plusieurs fois...

Code : Tout sélectionner

#TH32CS_SNAPHEAPLIST = %0001
#TH32CS_SNAPPROCESS  = %0010
#TH32CS_SNAPTHREAD   = %0100
#TH32CS_SNAPMODULE   = %1000
#TH32CS_SNAPALL      = %1111

Structure PROCESSENTRY32
  dwSize.l
  cntUsage.l
  th32ProcessID.l
  *th32DefaultHeapID.l
  th32ModuleID.l
  cntThreads.l
  th32ParentProcessID.l
  pcPriClassBase.l
  dwFlags.l
  szExeFile.b[#MAX_PATH]
  th32MemoryBase.l
  th32AccessKey.l
EndStructure

DataSection
 
  Instance_Buffer:
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  End_Instance_Buffer:
 
EndDataSection

Global MainInstance.l

Procedure.l CountProcesses(ExeFile.s)
  Protected Count.l, Proc32.PROCESSENTRY32, Temp.s
  Protected Kernel32ID.l, PSapiID.l, SnapshotID.l
 
  ExeFile       = LCase(ExeFile)
  Proc32\dwSize = SizeOf(PROCESSENTRY32)
  Kernel32ID    = OpenLibrary(#PB_Default, "kernel32.dll")
 
  If Kernel32ID
    PSapiID    = OpenLibrary(#PB_Default, "psapi.dll")
    SnapshotID = CallFunction(Kernel32ID, "CreateToolhelp32Snapshot", #TH32CS_SNAPPROCESS, #Null)
   
    If SnapshotID
     
      If CallFunction(Kernel32ID, "Process32First", SnapshotID, Proc32)
        Repeat
         
          If PSapiID
            ProcessID = OpenProcess_(#PROCESS_QUERY_INFORMATION|#PROCESS_VM_READ, #False, Proc32\th32ProcessID)
            Temp = Space(#MAX_PATH)
            CallFunction(PSapiID, "GetModuleFileNameExA", ProcessID, #Null, Temp, #MAX_PATH)
            Temp = Trim(Temp)
            CloseHandle_(ProcessID)
          Else
            Temp = PeekS(@Proc32\szExeFile, #MAX_PATH)
          EndIf
         
          If LCase(Temp) = ExeFile
            If Count = 0
              MainInstance = Proc32\th32ProcessID
            EndIf
            Count + 1
          EndIf
         
        Until CallFunction(Kernel32ID, "Process32Next", SnapshotID, Proc32) = #False
      EndIf
     
      CloseHandle_(SnapshotID)
    EndIf
   
    CloseLibrary(PSapiID)
    CloseLibrary(Kernel32ID)
  EndIf
 
  ProcedureReturn Count
EndProcedure

Procedure.s GetExeFile()
  Protected Location.s
 
  Location = Space(#MAX_PATH)
  GetModuleFileName_(#Null, Location, #MAX_PATH)
 
  ProcedureReturn location
EndProcedure

Procedure.l WriteMainInstanceBuffer(Length.l)
  Protected Write.l, ProcessID.l
 
  If Length > 0 And Length <= (?End_Instance_Buffer - ?Instance_Buffer)
    ProcessID = OpenProcess_(#PROCESS_ALL_ACCESS, #False, MainInstance)
   
    If ProcessID
      Write = WriteProcessMemory_(ProcessID, ?Instance_Buffer, ?Instance_Buffer, Length, #Null)
      CloseHandle_(ProcessID)
    EndIf
  EndIf
 
  ProcedureReturn Write
EndProcedure

;-example

;create or get a custom message
Global WM_MYAPPCUSTOMMESSAGE
WM_MYAPPCUSTOMMESSAGE = RegisterWindowMessage_("my_app_custom_message")

;check for existing process
If CountProcesses( GetExeFile() ) > 1
 
  DefType.s param, params
 
  ;get all params in a new line
  Repeat
    param = ProgramParameter()
    If params
      params + #CRLF$
    EndIf
    params + param
  Until param = #NULL$
 
  If params
    ;send the string to the buffer
    PokeS(?Instance_Buffer, params)
    WriteMainInstanceBuffer(Len(params))
   
    ;send the custom message
    SendMessage_(#HWND_BROADCAST, WM_MYAPPCUSTOMMESSAGE, "GET_PARAMS", Len(params))
  Else
    ;send a 'no param' message
    SendMessage_(#HWND_BROADCAST, WM_MYAPPCUSTOMMESSAGE, "NO_PARAMS", 0)
  EndIf
 
  ;only one instance so just end
  End
EndIf

;here starts the "MainInstance" program

;this var is used for small stats ^^
Global nMessages

;procedure where you receive the custom message
Procedure WindowCallback(WindowID.l, Message.l, wParam.l, lParam.l)
 
  If Message = WM_MYAPPCUSTOMMESSAGE
   
    nMessages + 1
   
    CustomMessage.s = PeekS(wParam)
   
    ;get the program parameter if any
    If CustomMessage = "GET_PARAMS"
      Text.s = "Here is a new custom message :" + #CRLF$ + PeekS(?Instance_Buffer, lParam)
    ElseIf CustomMessage = "NO_PARAMS"
      Text.s = "Here is a 'no param' message !" + #CRLF$
    EndIf
   
    ;update gadgets' text
    Text = GetGadgetText(1) + Text
    SetGadgetText(1, Text)
    SetGadgetText(0, "Custom messages : " + Str(nMessages))
   
    SetForegroundWindow_( WindowID() )
   
  EndIf
 
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure

;the only once running program
If OpenWindow(0,0,0,320,280,#PB_Window_SystemMenu|#PB_Window_ScreenCentered,"Instance") And CreateGadgetList(WindowID())
 
  ;gadgets to get the result of the custom message
  TextGadget  (0,10,10,300, 20,"No custom message received")
  StringGadget(1,10,40,300,230,"",#PB_String_MultiLine|#PB_String_ReadOnly)
 
  ;without this line, nothing is possible
  SetWindowCallback( @WindowCallback() )
 
  Repeat
    ;enjoy
  Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

Dri

Chris · Message par **Chris** » lun. 24/oct./2005 11:42

Sous XP Home, ça plante!

Chris · Message par **Chris** » lun. 24/oct./2005 11:45

Rectification, il y avait un "AddGadgetItem(0, -1, LCase(Temp)) " qui trainait dans le code. C'est lui qui faisait planter.

Sur XP, ça marche.

Dr. Dri · Message par **Dr. Dri** » lun. 24/oct./2005 11:46

dans ce cas lance le avec PB et le debugger pour voir où stp

Dri

Backup · Message par **Backup** » lun. 24/oct./2005 11:58

avec la modif de Chris , ça marche sous xp pro !

par contre ça sert a quoi ?

Dr. Dri · Message par **Dr. Dri** » lun. 24/oct./2005 12:29

@Chris
Oublié de virer tout le code des tests

je met à jour le code ^^

@Dobro
C'est censé dire combien de fois est exécuté l'exécutable transmit en paramètres... Ca rejoint la surveillance de process de Heis. Crée un exe et lance le plusieurs fois et dis moi ce que t'obtiens stp

Dri

Chris · Message par **Chris** » lun. 24/oct./2005 12:43

Ca marche sous HP Home, pas de problème

Dr. Dri · Message par **Dr. Dri** » lun. 24/oct./2005 13:16

il te donne bien le nombre de fois que l'exe a été lancé ???

Dri

Chris · Message par **Chris** » lun. 24/oct./2005 13:21

Il donne le nombre de fois que le programme EST lancé.

Si je l'ouvre plusieurs fois sans le refermer, il m'affiche le nombre d'occurences ouvertes.
Si je l'ouvre et que je le referme avant de l'ouvrir une nouvelle fois, il m'affiche toujours 1

Dr. Dri · Message par **Dr. Dri** » lun. 24/oct./2005 13:24

Chris a écrit :Il donne le nombre de fois que le programme EST lancé.

Si je l'ouvre plusieurs fois sans le refermer, il m'affiche le nombre d'occurences ouvertes.
Si je l'ouvre et que je le referme avant de l'ouvrir une nouvelle fois, il m'affiche toujours 1

Tu as tout a fait raison je me suis mal exprimé ^^
C'est bien le nombre de fois qu'il est lancé simltanément

Puisque ca semble fonctionne je crois qu'on a une solution fiable pour ne lancer l'exe qu'une fois. Avec un mutex ou un fichier si le programme plante le mutex ou le fichier n'est pas détruit et là on se base sur le nombre de fois que l'exe a été lancé ^^

Dri

Backup · Message par **Backup** » lun. 24/oct./2005 13:35

C'est censé dire combien de fois est exécuté l'exécutable transmit en paramètres... Ca rejoint la surveillance de process de Heis. Crée un exe et lance le plusieurs fois et dis moi ce que t'obtiens stp

pareil que Chris ! le dialog donne le nombre de fois que le prg est lancé !

Dr. Dri · Message par **Dr. Dri** » dim. 15/oct./2006 16:07

le même code en V4 ^^

Code : Tout sélectionner

#PB_String_MultiLine = #ES_MULTILINE

DataSection
 
  Instance_Buffer:
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  Data.l 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
  End_Instance_Buffer:
 
EndDataSection

Global MainInstance.l

Procedure.l CountProcesses(ExeFile.s)
  Protected Count.l, Proc32.PROCESSENTRY32, Temp.s
  Protected Kernel32ID.l, PSapiID.l, SnapshotID.l
 
  ExeFile       = LCase(ExeFile)
  Proc32\dwSize = SizeOf(PROCESSENTRY32)
  Kernel32ID    = OpenLibrary(#PB_Any, "kernel32.dll")
 
  If Kernel32ID
    PSapiID    = OpenLibrary(#PB_Any, "psapi.dll")
    SnapshotID = CallFunction(Kernel32ID, "CreateToolhelp32Snapshot", #TH32CS_SNAPPROCESS, #Null)
   
    If SnapshotID
     
      If CallFunction(Kernel32ID, "Process32First", SnapshotID, Proc32)
        Repeat
         
          If PSapiID
            ProcessID = OpenProcess_(#PROCESS_QUERY_INFORMATION|#PROCESS_VM_READ, #False, Proc32\th32ProcessID)
            Temp = Space(#MAX_PATH)
            CallFunction(PSapiID, "GetModuleFileNameExA", ProcessID, #Null, Temp, #MAX_PATH)
            Temp = Trim(Temp)
            CloseHandle_(ProcessID)
          Else
            Temp = PeekS(@Proc32\szExeFile, #MAX_PATH)
          EndIf
         
          If LCase(Temp) = ExeFile
            If Count = 0
              MainInstance = Proc32\th32ProcessID
            EndIf
            Count + 1
          EndIf
         
        Until CallFunction(Kernel32ID, "Process32Next", SnapshotID, Proc32) = #False
      EndIf
     
      CloseHandle_(SnapshotID)
    EndIf
   
    If PSapiID
      CloseLibrary(PSapiID)
    EndIf
    CloseLibrary(Kernel32ID)
  EndIf
 
  ProcedureReturn Count
EndProcedure

Procedure.l WriteMainInstanceBuffer(Length.l)
  Protected Write.l, ProcessID.l
 
  If Length > 0 And Length <= (?End_Instance_Buffer - ?Instance_Buffer)
    ProcessID = OpenProcess_(#PROCESS_ALL_ACCESS, #False, MainInstance)
   
    If ProcessID
      Write = WriteProcessMemory_(ProcessID, ?Instance_Buffer, ?Instance_Buffer, Length, #Null)
      CloseHandle_(ProcessID)
    EndIf
  EndIf
 
  ProcedureReturn Write
EndProcedure

;-example

;create or get a custom message
Global WM_MYAPPCUSTOMMESSAGE
WM_MYAPPCUSTOMMESSAGE = RegisterWindowMessage_("my_app_custom_message")

;check for existing process
If CountProcesses( ProgramFilename() ) > 1
 
  Define.s param, params
 
  ;get all params in a new line
  Repeat
    param = ProgramParameter()
    If params
      params + #CRLF$
    EndIf
    params + param
  Until param = #NULL$
 
  If params
    ;send the string to the buffer
    PokeS(?Instance_Buffer, params)
    WriteMainInstanceBuffer(Len(params))
   
    ;send the custom message
    SendMessage_(#HWND_BROADCAST, WM_MYAPPCUSTOMMESSAGE, "GET_PARAMS", Len(params))
  Else
    ;send a 'no param' message
    SendMessage_(#HWND_BROADCAST, WM_MYAPPCUSTOMMESSAGE, "NO_PARAMS", 0)
  EndIf
 
  ;only one instance so just end
  End
EndIf

;here starts the "MainInstance" program

;this var is used for small stats ^^
Global nMessages

;procedure where you receive the custom message
Procedure WindowCallback(WindowID.l, Message.l, wParam.l, lParam.l)
 
  If Message = WM_MYAPPCUSTOMMESSAGE
   
    nMessages + 1
   
    CustomMessage.s = PeekS(wParam)
   
    ;get the program parameter if any
    If CustomMessage = "GET_PARAMS"
      Text.s = "Here is a new custom message :" + #CRLF$ + PeekS(?Instance_Buffer, lParam)
    ElseIf CustomMessage = "NO_PARAMS"
      Text.s = "Here is a 'no param' message !" + #CRLF$
    EndIf
   
    ;update gadgets' text
    Text = GetGadgetText(1) + Text
    SetGadgetText(1, Text)
    SetGadgetText(0, "Custom messages : " + Str(nMessages))
   
    SetForegroundWindow_(WindowID)
   
  EndIf
 
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure

;the only once running program
If OpenWindow(0,0,0,320,280,"Instance",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  CreateGadgetList(WindowID(0))
 
  ;gadgets to get the result of the custom message
  TextGadget  (0,10,10,300, 20,"No custom message received")
  StringGadget(1,10,40,300,230,"",#PB_String_MultiLine|#PB_String_ReadOnly)
 
  ;without this line, nothing is possible
  SetWindowCallback( @WindowCallback() )
 
  Repeat
    ;enjoy
  Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

Dri