Lecteur Multimédia Bouton pause ?

[Vlad]

Je me fabrique un lecteur de musique minimaliste.
Pour programmer le bouton Play : Playsound
Pour programmer le bouton Stop : StopSound
Mais pour programmer le bouton Pause ?
Si quelqu'un peut m'aider, je ne vois pas comment y parvenir ?
Est-ce possible en PureBasic ?

MERCI infiniment

[venom]

Salut Vlad,

je te conseille plus de partir via la librairie movie() et non sound() ça correspond plus a ce que tu souhaite faire
voici un petit code via la librairie movie() mais il y en a des tas sur le forum

Code : Tout sélectionner

;- Window Constants
Enumeration
  #Window_0
EndEnumeration

;- Gadget Constants
Enumeration
  #Button_Open
  #String_0
  #Button_Play
  #Button_Stop
  #Button_Pause
  #Film
EndEnumeration
InitMovie()

  If OpenWindow(#Window_0, 220, 0, 490, 70, "Fenetre",  #PB_Window_SystemMenu | #PB_Window_TitleBar | #PB_Window_ScreenCentered )
      ButtonGadget(#Button_Open, 10, 10, 150, 20, "Ouvrir un media")
      StringGadget(#String_0, 170, 10, 310, 20, "", #PB_String_ReadOnly)
      ButtonGadget(#Button_Play, 10, 40, 150, 20, "Lecture")
      ButtonGadget(#Button_Stop, 170, 40, 150, 20, "Stop")
      ButtonGadget(#Button_Pause, 330, 40, 150, 20, "Pause", #PB_Button_Default | #PB_Button_Toggle)

  EndIf
  
  Repeat
   EventID = WaitWindowEvent()
    If EventID = #PB_Event_Gadget
      Select EventGadget()
        
       Case #Button_Open
        NomFichier$ = OpenFileRequester("Ouvrir un media", "",  "Audio|*.mp3;*.wav", 0)
         SetGadgetText(#String_0, GetFilePart(NomFichier$))
          LoadMovie(#Film, NomFichier$)

       Case #Button_Play
        PlayMovie(#Film, WindowID(#Window_0))

       Case #Button_Stop
        StopMovie(#Film)

       Case #Button_Pause
        If GetGadgetState(#Button_Pause) = 1 ; <--- si le bouton est enfoncer, le resultat est de 1
         PauseMovie(#Film); <--- met le media en pause
        ElseIf GetGadgetState(#Button_Pause)  = 0; <--- si le bouton n'est pas enfoncer, le resultat est de 0
         ResumeMovie(#Film); <--- reprend le media en cours
        EndIf 

      EndSelect
    EndIf
  Until EventID = #PB_Event_CloseWindow

@++