[Finish]Mouse pointer not moving

[SPH]

Why Mouse pointer not moving ??

Code: Select all

InitSprite()
InitKeyboard()
InitMouse()

OpenWindow(0,0,0,500,100,"SPH_Entertainment",#PB_Window_ScreenCentered);|#PB_Window_SystemMenu)
OpenWindowedScreen(WindowID(0),0,0,500,100,1,0,0)

CreateSprite(0,40,40)
StartDrawing(SpriteOutput(0))
LineXY(0,0,30,20,RGB(255,255,0))
LineXY(20,30,30,20,RGB(255,255,0))
LineXY(20,30,0,0,RGB(255,255,0))
StopDrawing()


Repeat
  Repeat         ;- Gestion de la fenêtre
    Event  = WindowEvent() 
  Until Event = 0
  
  ;;;;;
  
  ExamineMouse()
  x=MouseX()
  y=MouseY()
  Debug Str(x)+" : "+Str(y)
  Delay(5)
  
  DisplayTransparentSprite(0,x,y)
  
  ;;;;;
  
  ExamineKeyboard()
  
Until KeyboardPushed(#PB_Key_Escape)

[STARGÅTE]

ExamineMouse()

In fullscreen mode the command FlipBuffers() need to be called inside your event loop to handle all events properly.

[SPH]

... Flipbuffer() !!!

sorry

[miso]

For 6.21 sprites:

Code: Select all

InitSprite()
InitKeyboard()
InitMouse()

OpenWindow(0,0,0,500,100,"SPH_Entertainment",#PB_Window_ScreenCentered);|#PB_Window_SystemMenu)
OpenWindowedScreen(WindowID(0),0,0,500,100,1,0,0)

CreateSprite(0,40,40,#PB_Sprite_AlphaBlending)
StartDrawing(SpriteOutput(0))
  DrawingMode(#PB_2DDrawing_AllChannels)
  Box(0,0,OutputWidth(),OutputHeight(),RGBA(0,0,0,0))
  LineXY(0,0,30,20,RGBA(255,255,0,255))
  LineXY(20,30,30,20,RGBA(255,255,0,255))
  LineXY(20,30,0,0,RGBA(255,255,0,255))
StopDrawing()


Repeat
  Repeat         ;- Gestion de la fenêtre
    Event  = WindowEvent() 
  Until Event = 0
  ExamineKeyboard()
  ExamineMouse()
  ClearScreen(RGB(60,20,20))
 
  x=MouseX()
  y=MouseY()
 
  DisplayTransparentSprite(0,x,y)
  FlipBuffers()
  Delay(1)
Until KeyboardPushed(#PB_Key_Escape)