How use Window3D

[matty47]

Coming back to PB after a long hiatus. Tried the following code to see how a WIndow3D would work but could not get the 3d window to open. Obviously I have missed something. Any help greatly appreciated.

Code: Select all

If Not InitEngine3D()
  MessageRequester("Error","Unable to initialise 3d Engine",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf

  If Not InitSprite()
  MessageRequester("Error","Unable to initialise sprite",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
  End
EndIf

InitKeyboard()
InitMouse()

win = OpenWindow(#PB_Any,0,0,1080,720,"My 3D Window",#PB_Window_SystemMenu | #PB_Window_ScreenCentered|#PB_Window_SizeGadget)
If Not win
  MessageRequester("Error","Could not open window",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf
ButtonGadget(0,0,135,45,20,"Quit")


If Not OpenWindowedScreen(WindowID(win),0,0,1080,720,#True,0,0)
 MessageRequester("Error","Could not open windowed screen",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf

win3d=OpenWindow3D(#PB_Any,50,50,640,480,"[color='ffffff00']A 3D Window",#PB_Window3D_SizeGadget)
If Not win3d
  MessageRequester("Error","Could not open window3d",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf


Repeat
  
  Repeat
    event=WindowEvent()
    
    Select event
      Case #PB_Event_Gadget
        If EventGadget()=0
          End
        EndIf
        
      Case #PB_Event_CloseWindow
        End
    EndSelect
  Until event=0
  
  FlipBuffers()
  
  Delay(1)
ForEver

[mk-soft]

Take a look at the gadget3d example.

The template for the GUI must also be loaded and something else.

[wombats]

You need to add a path to the GUI skin, a camera, and call RenderWorld().

Code: Select all

If Not InitEngine3D()
  MessageRequester("Error","Unable to initialise 3d Engine",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf

If Not InitSprite()
  MessageRequester("Error","Unable to initialise sprite",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
  End
EndIf

InitKeyboard()
InitMouse()

win = OpenWindow(#PB_Any,0,0,1080,720,"My 3D Window",#PB_Window_SystemMenu | #PB_Window_ScreenCentered|#PB_Window_SizeGadget)
If Not win
  MessageRequester("Error","Could not open window",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf
;ButtonGadget(0,0,135,45,20,"Quit")


If Not OpenWindowedScreen(WindowID(win),0,0,1080,720,#True,0,0)
  MessageRequester("Error","Could not open windowed screen",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf

Add3DArchive(#PB_Compiler_Home + "examples/3d/Data/GUI", #PB_3DArchive_FileSystem)

CreateCamera(0, 0, 0, 100, 100)

win3d=OpenWindow3D(#PB_Any,50,50,640,480,"[color='ffffff00']A 3D Window",#PB_Window3D_SizeGadget)
If Not win3d
  MessageRequester("Error","Could not open window3d",#PB_MessageRequester_Ok|#PB_MessageRequester_Error)
EndIf

ButtonGadget3D(0, 150, 40, 200, 50, "Quit")

Repeat
  
  Repeat
    event=WindowEvent()
    
    Select event        
      Case #PB_Event_CloseWindow
        quit = #True
    EndSelect
  Until event=0
  
  Repeat
    Event = WindowEvent3D()
    
    Select Event
      Case #PB_Event3D_CloseWindow
        If EventWindow3D() = win3d
          quit = #True
        EndIf
        
      Case #PB_Event3D_Gadget
        If EventGadget3D() = 0
          quit = #True
        EndIf
        
    EndSelect
  Until Event = 0
  
  If ExamineKeyboard() And ExamineMouse()
    Input$ = KeyboardInkey()
    
    InputEvent3D(MouseX(), MouseY(), MouseButton(#PB_MouseButton_Left), Input$, 0)
  EndIf
  
  If KeyboardPushed(#PB_Key_Escape)
    quit = #True
  EndIf
  
  RenderWorld()
  
  FlipBuffers()
  
  Delay(1)
Until quit