For Editor & String , single Click causes DoubleClick ?

[millie78526]

TIA ,
For Editor & String , single Click causes DoubleClick ?
I think what's happening is PB catches TWO Clicks , StringDownClick and StringUpClick .
Same for EditorDownClick and EditorUpClick .
How can I discover #PB_UpClick vs #PB_DownClick ?

Code: Select all

  If OpenWindow(0, 0, 0, 200, 500, "SetGadgetColor", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ButtonGadget(1, 10, 10, 180, 36, "Button..." , #PB_Button_Toggle )
    EditorGadget(2, 10, 50, 180, 36)
    StringGadget(3, 10, 100, 180, 36, "Working...." , #PB_String_ReadOnly )
    ListViewGadget(4, 10, 150, 180, 60)
    For i = 0 To 4
      AddGadgetItem(4, -1, "Text")
    Next i
    ContainerGadget(5, 10, 230, 180, 50, #PB_Container_Raised)

    SetGadgetColor(2, #PB_Gadget_BackColor, #Red) ; Editor
    SetGadgetColor(2, #PB_Gadget_FrontColor,$FFFFFF) 
    
    SetGadgetColor(3, #PB_Gadget_BackColor, $000000) ; String
    SetGadgetColor(3, #PB_Gadget_FrontColor,$FFFFFF) 
    
    SetGadgetColor(4, #PB_Gadget_FrontColor,$FFFFFF) 
    SetGadgetColor(4, #PB_Gadget_BackColor, $000000) ; ListView
    
    SetGadgetColor(5, #PB_Gadget_BackColor, $0000FF) ; Container

Repeat
  Select WaitWindowEvent()
    Case #PB_Event_Gadget
      Select EventGadget()
        Case 1
           Debug "Case 1 Button"  
        Case 2
           Debug "Case 2 Editor"  
        Case 3
           Debug "Case 3 String"  
        Case 4
           Debug "Case 4 ListView"  
        Case 5
           Debug "Case 5 Container"  
        EndSelect
        
      Case #PB_Event_CloseWindow
        Quit = 1

    EndSelect

  Until Quit = 1

EndIf

End

[ChrisR]

Uses EventType() to select only event types supported by Editor and StringGadget (see help):
- #PB_EventType_Focus
- #PB_EventType_Change
- #PB_EventType_LostFocus

Code: Select all

         Case 2
           Select EventType()
             Case #PB_EventType_Focus
               Debug "Case 2 Editor Focus"
             Case #PB_EventType_Change
               Debug "Case 2 Editor Change"
             Case #PB_EventType_LostFocus
               Debug "Case 2 Editor Lost Focus"
             ;Default
             ;  Debug "Case 2 Editor EventType not used: " + EventType()
           EndSelect
         Case 3
           Select EventType()
             Case #PB_EventType_Focus
               Debug "Case 3 String Focus"
             Case #PB_EventType_Change
               Debug "Case 3 String Change"
             Case #PB_EventType_LostFocus
               Debug "Case 3 String Lost Focus"
             ;Default
             ;  Debug "Case 3 String EventType not used: " + EventType()
           EndSelect

[boddhi]

For Editor & String , single Click causes DoubleClick ?

Each action on a gadget triggers a certain number of events managed by PB. This number differs according to the type of gadget.

Hence, as Chris says:
 1) You need to filter events with EventType() to find out the nature of the event,
 2) Don't hesitate to consult the help for each gadget to know exactly which events PB intercepts for it. Some events for a gadget are not available for others.

[millie78526]

Ahh.. Thank you very much ChrisR...

- #PB_EventType_Focus
- #PB_EventType_Change
- #PB_EventType_LostFocus
I'm starting to get the hang of things...