Why is the directory not created ?

[hoangdiemtinh]

I am new to PB.
My primary language is not US/UK. I am using Google Translate.

Code: Select all

Global.S myFOLDER = "D:\abc\def\gh"
CreateDirectory(myFOLDER)

Why is the directory not created ?

[AZJIO]

D:\abc\def Does this path exist?

[hoangdiemtinh]

D:\abc\def Does this path exist?

If the path doesn't exist, is there any way to force the directory to be created ?

[idle]

you need to test the whole path "D:\abc" and "D:\abc\def" ...

Code: Select all

Procedure CreateDirectoryEX(path.s) 
  
  Protected ct,tpath.s 
  ct = CountString(path,#PS$) +1
  For a = 1 To ct 
    tpath + StringField(path,a,#PS$)  + #PS$
    If FileSize(tpath)<> -2
      CreateDirectory(tpath)
    EndIf 
  Next 
  
EndProcedure   

[AZJIO]

https://azjio.narod.ru/PureBasic/pb_use ... tories.htm
https://www.purebasic.fr/english/viewto ... 30#p317830

[hoangdiemtinh]

you need to test the whole path "D:\abc" and "D:\abc\def" ...

Code: Select all

Procedure CreateDirectoryEX(path.s) 
  
  Protected ct,tpath.s 
  ct = CountString(path,#PS$) +1
  For a = 1 To ct 
    tpath + StringField(path,a,#PS$)  + #PS$
    If FileSize(tpath)<> -2
      CreateDirectory(tpath)
    EndIf 
  Next 
  
EndProcedure   

The folder has been created.
By the way, I use IsDirectory(tpath) to evaluate the folder that has been successfully created, but I encountered an error message.
---------------------------------
Edit:
I found this.
https://www.purebasic.fr/english/viewtopic.php?t=68073

[BarryG]

Why is the directory not created ?

Because nested folders aren't supported. This is mentioned in the manual.

For Windows, you can do it like this:

Code: Select all

SHCreateDirectory_(0,"D:\abc\def\gh")

[idle]

Add a final test to verify the directory and replace path separators in place if needed

Code: Select all

Procedure CreateDirectoryEX(path.s) 
  
  Protected ct,tpath.s 
  
  CompilerIf #PB_OS_Windows 
    ReplaceString(path,"/","\",#PB_String_InPlace) 
  CompilerElse 
    ReplaceString(path,"\","/",#PB_String_InPlace) 
  CompilerEndIf   
  
  ct = CountString(path,#PS$) +1
  For a = 1 To ct 
    tpath + StringField(path,a,#PS$) + #PS$
    If FileSize(tpath)<> -2
      If CreateDirectory(tpath) = 0 
        ProcedureReturn 0 
      EndIf   
    EndIf 
  Next 
  
  If FileSize(path) = -2  
    ProcedureReturn #True 
  EndIf 
  
EndProcedure   

Global dir.s = "D:/test/abc\def\" 
Debug CreateDirectoryEX(dir) 

[tua]

Or even more succinctly (without having to check the OS):

Code: Select all

Procedure CreateDirectoryEX(path.s) 
  Protected i, tpath.s, ct

  ReplaceString(path, #NPS$, #PS$, #PB_String_InPlace) 
  ct = CountString(path, #PS$) + 1
  For i = 1 To ct 
    tpath + StringField(path, i, #PS$) + #PS$
    If FileSize(tpath) <> -2 And CreateDirectory(tpath) = 0 
      ProcedureReturn #False
    EndIf 
  Next 
  ProcedureReturn Bool(FileSize(path) = -2)
EndProcedure   

Global dir.s = "D:/test/abc\def\l00" 
Debug CreateDirectoryEX(dir)

[idle]

Or even more succinctly (without having to check the OS):

Code: Select all

Procedure CreateDirectoryEX(path.s) 
  Protected i, tpath.s, ct

  ReplaceString(path, #NPS$, #PS$, #PB_String_InPlace) 
  ct = CountString(path, #PS$) + 1
  For i = 1 To ct 
    tpath + StringField(path, i, #PS$) + #PS$
    If FileSize(tpath) <> -2 And CreateDirectory(tpath) = 0 
      ProcedureReturn #False
    EndIf 
  Next 
  ProcedureReturn Bool(FileSize(path) = -2)
EndProcedure   

Global dir.s = "D:/test/abc\def\l00" 
Debug CreateDirectoryEX(dir)

I had no idea we had #NPS$

[AZJIO]

On Linux, the #NPS$ character is a valid file/folder name character and should not be corrupted

[tua]

Hehe, that's correct. However, putting a backslash in a unix filename should be punishable by 5 strokes with a keyboard ...

[Piero]

On Mac (BSD) if you drag something on Terminal you get backslashes for spaces etc., but that's not the best way:

Code: Select all

Procedure.s QuotePath(str$)
   ProcedureReturn "'" + ReplaceString(str$, "'", "'\''") + "'"
EndProcedure

[eJan]

Code: Select all

; Bisonte: http://www.purebasic.fr/english/viewtopic.php?p=496867#p496867

Prototype proto_msdpe(Path.p-Ascii)

Procedure _MSDPE(Path.s)
  ProcedureReturn MakeSureDirectoryPathExists_(Path)  
EndProcedure

Global MakeSureDirectoryPathExists.proto_msdpe = @_MSDPE()

Debug MakeSureDirectoryPathExists("C:\a\b\c\d\")