Check whether a computer uses BIOS or UEFI

[Little John]

Hi all,

the following code returns #False on my PC with BIOS, as expected.

I would appreciate it, if some of you would test the code on your systems.
Especially interesting for me is to know, whether the function actually returns #True on computers with UEFI.
I'd also be grateful for suggestions for improvement, if necessary.
Thanks in advance!

Code: Select all

EnableExplicit

Import "kernel32.lib"
   GetFirmwareEnvironmentVariableA (name.p-ascii, guid.p-ascii, *buffer, nSize.l)
EndImport


Procedure.i UsesUEFI()
   ; out: #True  if the used system firmware is UEFI,
   ;      #False if the used system firmware is BIOS.
   ;
   ; <https://docs.microsoft.com/en-us/windows/win32/api/winbase/nf-winbase-getfirmwareenvironmentvariablea>, 2019-09-24
   ; tested with PB 5.71 (x86 and x64) under Windows 10 Pro Version 1903 with BIOS
   Protected *buffer, error.i, nSize.l=1000
   
   *buffer = AllocateMemory(nSize)
   GetFirmwareEnvironmentVariableA("", "{00000000-0000-0000-0000-000000000000}", *buffer, nSize)
   error = GetLastError_()
   FreeMemory(*buffer)
   
   ProcedureReturn Bool(error <> #ERROR_INVALID_FUNCTION)
EndProcedure


;-- Demo
Debug UsesUEFI()

[W4GNS]

Yes, returns true for me

[BarryG]

Mine returns 1 (UEFI), as confirmed with the Windows "System Information" app.

Your code matches the CPP source posted by Martin Karer here:

https://social.technet.microsoft.com/Fo ... de-windows

So I'd say it's correct.

[idle]

I get a zero on the ASRock 970 3 with win 10 x64
edit: apparently it's running in Legacy mode.

[Denis]

Returns #true for me

Win 10 - 64 bit (1809)

it matches with information given by msinfo32.exe

[juror]

correct for me - UEFI

[Little John]

Many thanks for all your replies! They are much appreciated.

I get a zero on the ASRock 970 3 with win 10 x64
edit: apparently it's running in Legacy mode.

Yes, even a modern PC with an UEFI can run in Legacy mode.
The old function name was misleading. I changed it to UsesUEFI(), and also changed the thread title accordingly.

Many thanks again, and especially to BarryG for the link!

[hoangdiemtinh]

Not working.

my PC: Win10 Pro 64-bit, run on a MBR System Disk (this is Legacy Windows Environment).

(my MainBoard have support EFI Booting in BIOS Setup).

But, this code return #True.

Please fix code.

[Zero Ray]

Not working.

my PC: Win10 Pro 64-bit, run on a MBR System Disk (this is Legacy Windows Environment).

(my MainBoard have support EFI Booting in BIOS Setup).

But, this code return #True.

Please fix code.

Try it

Code: Select all

#SystemBootEnvironmentInformation = $5A

Structure _SYSTEM_BOOT_ENVIRONMENT_INFORMATION Align #PB_Structure_AlignC
  BootIdentifier.guid
  FirmwareType.l
  BootFlags.d
EndStructure

Procedure GetSystemBootEnvironmentInformation()
  Protected SBEI._SYSTEM_BOOT_ENVIRONMENT_INFORMATION
  
  If NtQuerySystemInformation_(#SystemBootEnvironmentInformation, @SBEI, SizeOf(SBEI), #Null) = 0
    ProcedureReturn SBEI\FirmwareType
  Else
    ProcedureReturn -1
  EndIf
EndProcedure

Select GetSystemBootEnvironmentInformation()
  Case 0
    Debug "Unknown"
  Case 1
    Debug "Bios"
  Case 2
    Debug "Uefi"
  Case 3
    Debug "Not implemented"
  Case -1
    Debug "Error"
EndSelect

[Little John]

See also this forum contribution.

[Zero Ray]

See also this forum contribution.

The GetFirmwareType function is only available in version NT6.2 and higher