Trim() enhancement

[paulr]

How about allowing strings greater than 1 in length in the 'character to trim' argument, then trimming any of the characters from the target?

So that: Trim("<hello>", "<>")
Would return "hello"?

This would be more powerful and keep the original functionality perfectly intact.

[IdeasVacuum]

Well, PB has the Regular Expression lib for that. http://www.purebasic.com/documentation/ ... index.html

[Little John]

How about allowing strings greater than 1 in length in the 'character to trim' argument, then trimming any of the characters from the target?

Yes, that would be very useful. E.g. PowerBasic has this feature for ages.

( Until this will be implemented in PureBasic, you can use self-written functions for this. )

[PB]

> This would be more powerful

But what would it do to this?

Code: Select all

a$=Trim("<>hello<>","<>")

[DK_PETER]

> This would be more powerful

But what would it do to this?

Code: Select all

a$=Trim("<>hello<>","<>")

@PB

You could do this:

Macro myTrim(st, remst)
Trim(ReplaceString(st, remst,""),"")
EndMacro

a$ = "<>hello<>"
Debug myTrim(a$, "<>")

[Shield]

What if the string is "<>he<>llo<>"?

[Little John]

> This would be more powerful

But what would it do to this?

Code: Select all

a$=Trim("<>hello<>","<>")

See the link in the post directly above your post ...

[Little John]

@PB

You could do this:

Macro myTrim(st, remst)
Trim(ReplaceString(st, remst,""),"")
EndMacro

a$ = "<>hello<>"
Debug myTrim(a$, "<>")

No. As Shield already indicated, that's not a Trim() function.

General remark: I can't see the sense in ignoring existing solutions, that have been posted previously in a thread.

[DK_PETER]

@PB

You could do this:

Macro myTrim(st, remst)
Trim(ReplaceString(st, remst,"")," ")
EndMacro

a$ = "<>hello<>"
Debug myTrim(a$, "<>")

No. As Shield already indicated, that's not a Trim() function.

General remark: I can't see the sense in ignoring existing solutions, that have been posted previously in a thread.

Easy Little John. ;-D
I completely agree, but in the spirit of a New Year - I provided a non-serious option.
It does however provide the desired result for Shield's "<>he<>llo<>".

Happy New Year!

[paulr]

Thank you for your input IdeasVacuum and Little John.

> This would be more powerful

But what would it do to this?

Code: Select all

a$=Trim("<>hello<>","<>")

PB, I'm proposing the function work exactly like Trim, but removing characters from the start and end of a string until it hits one not in the 'characters to remove' string. So:

Trim("<>hello<>","<>") would return "hello"
Trim("<>he<>llo<>","<>") would return "he<>llo"
Trim("<<>><<>he<>>>>llo<>>>>>>","<>") would return "he<>>>>llo"
Trim(">hello","<>") would return "hello"

Hope it's clear now.

[Danilo]

PB, I'm proposing the function work exactly like Trim, but removing characters from the start and end of a string until it hits one not in the 'characters to remove' string. So:

Trim("<>hello<>","<>") would return "hello"
Trim("<>he<>llo<>","<>") would return "he<>llo"
Trim("<<>><<>he<>>>>llo<>>>>>>","<>") would return "he<>>>>llo"
Trim(">hello","<>") would return "hello"

Hope it's clear now.

Yes, it is clear now.

Code: Select all

Procedure.s TrimAll(inputString.s, characters.s)
    Protected i, *p.Character
    Protected len = Len(inputString)
    If len > 0
        len - 1
        For i = 0 To len
            *p = @characters
            While *p\c <> 0
                inputString = Trim(inputString,Chr(*p\c))
                *p + SizeOf(Character)
            Wend
        Next
    EndIf
    ;Debug "TrimAll Iterations: "+Str(i+1)
    ProcedureReturn inputString
EndProcedure

Macro Trim(string,chars=" ") : TrimAll(string,chars) : EndMacro


Debug Trim("<>hello<>","<>")                ; would return "hello"
Debug Trim("<>he<>llo<>","<>")              ; would return "he<>llo"
Debug Trim("<<>><<>he<>>>>llo<>>>>>>","<>") ; would return "he<>>>>llo"
Debug Trim(">hello","<>")                   ; would return "hello"
Debug Trim("<hello>","<>o")                 ; would return "hell"
Debug Trim("<hello>","<o>")                 ; would return "hell"
Debug Trim("   hello   ")                   ; would return "hello"

The following version trims only until no more changes are found (better for large strings):

Code: Select all

Procedure.s TrimAll(inputString.s, characters.s)
    Protected i, *p.Character, newString.s, foundChange
    Protected len = Len(inputString)
    If len > 0
        len - 1
        For i = 0 To len
            *p = @characters
            foundChange = #False
            While *p\c <> 0
                newString = Trim(inputString,Chr(*p\c))
                If newString <> inputString
                    foundChange = #True
                EndIf
                inputString = newString
                *p + SizeOf(Character)
            Wend
            If foundChange = #False
                Break
            EndIf
        Next
    EndIf
    ;Debug "TrimAll Iterations: "+Str(i+1)
    ProcedureReturn inputString
EndProcedure

Macro Trim(string,chars=" ") : TrimAll(string,chars) : EndMacro


Debug Trim("<>hello<>","<>")                ; would return "hello"
Debug Trim("<>he<>llo<>","<>")              ; would return "he<>llo"
Debug Trim("<<>><<>he<>>>>llo<>>>>>>","<>") ; would return "he<>>>>llo"
Debug Trim(">hello","<>")                   ; would return "hello"
Debug Trim("<hello>","<>o")                 ; would return "hell"
Debug Trim("<hello>","<o>")                 ; would return "hell"
Debug Trim("   hello   ")                   ; would return "hello"

[paulr]

Thanks, that's a very neat implementation. I'd like to see that in the next version of PB!

[Andre]

Thanks, that's a very neat implementation. I'd like to see that in the next version of PB!

+1

[Thade]

Code: Select all

Procedure.s TrimAll(in.s, what.s)
	While FindString(what, Left(in, 1)) Or FindString(what, Right(in, 1))
		For i=1 To Len(what)
			in=Trim(in,	Mid(what, i, 1))
		Next
	Wend
	ProcedureReturn in
EndProcedure

Debug TrimAll("<>Hello<>", "<>")
Debug TrimAll("<>Hel<>lo<>", "<>")
Debug TrimAll("<>Hello<>", "<o>")
Debug TrimAll("<>Hello<>", "o><")
Debug TrimAll("<>Hello<>", "o<>")
Debug TrimAll("<>Hello<>", "<>o")
Debug TrimAll("<><.>><<>Hel<>lo<>:<>>::<><<>>", "<:>.")

or this does the same

Code: Select all

Procedure.s TrimAll(in.s, what.s)
	While FindString(what, Left(in, 1))
		in=Trim(in, Left(in,1))
	Wend
	While FindString(what, Right(in, 1))
		in=RTrim(in,	Right(in, 1))
	Wend
	ProcedureReturn in
EndProcedure

Debug TrimAll("<>Hello<>", "<>")
Debug TrimAll("<>Hel<>lo<>", "<>")
Debug TrimAll("<>Hello<>", "<o>")
Debug TrimAll("<>Hello<>", "o><")
Debug TrimAll("<>Hello<>", "o<>")
Debug TrimAll("<>Hello<>", "<>o")
Debug TrimAll("<><.>><<>Hel<>lo<>:<>>::<><<>>", "<:>.")