progressbar with "#PBM_SETMARQUEE" (winXP)

[bingo]

any way tu use pb progressbar with #PBM_SETMARQUEE (xp only!) ?

#PBM_SETMARQUEE = #WM_USER + 10

http://msdn.microsoft.com/library/en-us ... arquee.asp 8O

[Sparkie]

Note - *** Requires WinXP with XP skins enabled ***

Tested and working on WinXPhome with PB 3.91.

Code: Select all

; --> *** Requires WinXP with XP skins enabled ***

#PBS_MARQUEE = 8
#PBM_SETMARQUEE = #WM_USER + 10

If OpenWindow(0, 0, 0, 320, 160, #PB_Window_SystemMenu | #PB_Window_ScreenCentered, "ProgressBarGadget Marquee") And CreateGadgetList(WindowID(0)) 
  ProgressBarGadget(0, 10, 30, 300, 20, 0, 100, #PBS_MARQUEE) 
  ButtonGadget(1, 110, 70, 75, 20, "On")
  HideGadget(0, 1)
  
  Repeat
    Event = WaitWindowEvent()
    
    Select Event

      Case #PB_EventGadget
        
        Select EventGadgetID()
          
          Case 1
            If GetGadgetText(1) = "On"
              SetGadgetText(1, "Off")
              HideGadget(0, 0)
              SendMessage_(GadgetID(0), #PBM_SETMARQUEE, 1, 100) ; on
            Else 
              SetGadgetText(1, "On")
              SendMessage_(GadgetID(0), #PBM_SETMARQUEE, 0, 0) ; off
              HideGadget(0, 1)
            EndIf
             
        EndSelect
    EndSelect
    
  Until Event = #PB_Event_CloseWindow 
EndIf