Create Full Path Procedure

[Randy Walker]

You'll have to uncomment the CreateDirectory line for it to actually work, but run as is in Debugger to see how it would work in action. Of course, IF the drive exists it will fail to create the root directory. To be expected:

Code: Select all

Procedure Makepath(Sample$)
Sample$ = Trim(Sample$, "\")
Path$ = ""
For D = 1 To CountString(Sample$, "\") + 1
  Path$ + StringField(Sample$, D, "\") + "\"
  If FileSize(Path$) = -1
    Debug Path$
;   CreateDirectory(Path$)
  Else
    Debug Path$+" already exists"
  EndIf
Next D
EndProcedure

;Examples with and without trailing \
Makepath("D:\Eat\At\Joes\Bar\And\Grill\")
Delay(3000)
Makepath("D:\Eat\At\Joes\Bar\And\Grill")

[BarryG]

For Windows only, it's just one API command:

Code: Select all

SHCreateDirectory_(0,"D:\Eat\At\Joes\Bar\And\Grill\")

[Randy Walker]

For Windows only, it's just one API command:

Code: Select all

SHCreateDirectory_(0,"D:\Eat\At\Joes\Bar\And\Grill\")

Good to know. THANKS again BarryG !!!

[BarryG]

I've been using that forever.

[Randy Walker]

I'm, guessing change backslash to forward slash for Linux or MAC in my procedure to get it to work there. Cannot test here.

[Piero]

I'm, guessing change backslash to forward slash for Linux or MAC in my procedure to get it to work there. Cannot test here.

Code: Select all

Procedure Makepath(Sample$)
   Sample$ = Trim(Sample$, #PS$)
   If #PS$ = "/" : PS$ = #PS$ : EndIf
   For D = 1 To CountString(Sample$, #PS$) + 1
      Path2$ + StringField(Sample$, D, #PS$) + #PS$
      Path$ = PS$ + Path2$
      If FileSize(Path$) = -1
         Debug Path$
         ;   CreateDirectory(Path$)
      Else
         Debug Path$+" already exists"
      EndIf
   Next D
   Debug""
EndProcedure

;Examples with and without trailing #PS$
Makepath("D:\Eat\At\Joes\Bar\And\Grill\")
Makepath("D:\Eat\At\Joes\Bar\And\Grill")
Makepath("/Eat/At/Joes/Bar/And/Grill/")
Makepath("/Eat/At/Joes/Bar/And/Grill")

[Axolotl]

For Windows only, it's just one API command:

Code: Select all

SHCreateDirectory_(0,"D:\Eat\At\Joes\Bar\And\Grill\")

Fun Fact: It's on the Deprecated APi Section since more than 10 years now.

SHCreateDirectory is available for use in the operating systems specified in the Requirements section. It may be altered or unavailable in subsequent versions.

[HeX0R]

better use

Code: Select all

If FileSize(Path$) <> -2

you might have files looking like directories

[Piero]

better use

Code: Select all

If FileSize(Path$) <> -2

you might have files looking like directories

Not on Mac: you cannot create a dir if there's a file with the same name (at least not on Finder… don't wanna risk to try with PB and nuke my filesystem )

[Piero]

Code: Select all

Procedure Makepath(Sample$)
   Protected PS$, Path$, Path2$, cs, D, fs
   Sample$ = Trim(Sample$, #PS$)
   If #PS$ = "/" : PS$ = #PS$ : EndIf
   cs = CountString(Sample$, #PS$) + 1
   For D = 1 To cs
      Path2$ + StringField(Sample$, D, #PS$) + #PS$
      Path$ = PS$ + Path2$
      fs = FileSize(Path$)
      If fs = -1
         ; If Not CreateDirectory(Path$) : Debug Path$+" - Error!" : Break : EndIf
         Debug Path$
      ElseIf fs = -2
         Debug Path$+" - already exists"
      Else
         Debug Path$+" - Error!" : Break
      EndIf
   Next D
   Debug""
EndProcedure

Edit: slightly modified to work better on windows

[ebs]

I use MakeSureDirectoryPathExists for the same purpose:

Code: Select all

MakeSureDirectoryPathExists_("D:\Eat\At\Joes\Bar\And\Grill\")

For Windows only, it's just one API command:

Code: Select all

SHCreateDirectory_(0,"D:\Eat\At\Joes\Bar\And\Grill\")

Fun Fact: It's on the Deprecated APi Section since more than 10 years now.

SHCreateDirectory is available for use in the operating systems specified in the Requirements section. It may be altered or unavailable in subsequent versions.

[Axolotl]

Yes, thats a good one, too.
And reading the comments section is even more fun.

Remarks
Each directory specified is created, if it does not already exist. If only some of the directories are created, the function will return FALSE.

This function does not support Unicode strings. To specify a Unicode path, use the SHCreateDirectoryEx function.

All DbgHelp functions, such as this one, are single threaded. Therefore, calls from more than one thread to this function will likely result in unexpected behavior or memory corruption. To avoid this, you must synchronize all concurrent calls from more than one thread to this function.

[Piero]

Fun fact: for PB Mac FileSize, "/a/path/" <> "/a/path" if there is a "path" file, but not on windows (so I edited my previous post a bit)

[Randy Walker]

Yes, thats a good one, too.
And reading the comments section is even more fun.

Remarks
Each directory specified is created, if it does not already exist. If only some of the directories are created, the function will return FALSE.

This function does not support Unicode strings. To specify a Unicode path, use the SHCreateDirectoryEx function.

All DbgHelp functions, such as this one, are single threaded. Therefore, calls from more than one thread to this function will likely result in unexpected behavior or memory corruption. To avoid this, you must synchronize all concurrent calls from more than one thread to this function.

I don't know or understand Unicode Well enough to write code that supports it and as far as I'm concerned, don't have any use for it. Feel free to provide what you would consider to be a superior Procedure. I wont be offended. If you're comfortable using the SHCreate thing, that's fine too. Seems if the end user of your code doesn't have the Dbghelp.lib then your code will fail, Also from the official MS website: "This function is available through Windows XP Service Pack 2 (SP2) and Windows Server 2003. It might be altered or unavailable in subsequent versions of Windows."
So bottom line seems to be: Your SHCreate thing may not be the best possible path. No pun intended.

[Bisonte]

in a crossplatform way from TS-Soft (German Forum) modified by me a little... :

Code: Select all

Procedure.i CreateDirectoryEx(DirectoryName.s, FileAttribute = #PB_Default) ; Erstellt Verzeichnis, inklusive Übergeordnete
  
  Protected i, c, tmp.s
  
  If Right(DirectoryName, 1) = #PS$
    DirectoryName = Left(DirectoryName, Len(DirectoryName) -1)
  EndIf
  c = CountString(DirectoryName, #PS$) + 1
  For i = 1 To c
    tmp + StringField(DirectoryName, i, #PS$)
    If FileSize(tmp) <> -2
      CreateDirectory(tmp)
    EndIf
    tmp + #PS$
  Next
  
  If FileAttribute <> #PB_Default
    CompilerIf #PB_Compiler_OS = #PB_OS_Windows
      SetFileAttributes_(DirectoryName, FileAttribute)
    CompilerElse
      SetFileAttributes(DirectoryName, FileAttribute)
    CompilerEndIf
  EndIf
  
  If FileSize(DirectoryName) = -2
    ProcedureReturn #True
  EndIf
  
EndProcedure