The IIF function

[bds107]

Hi everyone!
Back when animals still spoke, there was something called IIF. Unfortunately, it wasn't built into PureBASIC, or I'd have to cross my eyes.

Code: Select all

GLOBAL result.s, userInput.a
result.s = IIF(userInput MOD 2 = 0, "Even", "Odd")
DEBUG "The number is " + result

Hopefully...

[Quin]

This has been requested many times. I've concluded that it'll never happen.
PB isn't a bad language for pounding out a native executable that works across operating systems. But if you want anything even close to modern syntax, it's not it. I personally recommend Crystal for that.

[AZJIO]

PureAutoIt

Code: Select all

Macro IIf(expr, truepart, falsepart=__expr_null__.b)
	If expr
		truepart
	Else
		falsepart
	EndIf
EndMacro

Code: Select all

result.s = IIF(userInput MOD 2 = 0, "Even", "Odd")

Code: Select all

result.s = n & 1

[Quin]

PureAutoIt

Code: Select all

Macro IIf(expr, truepart, falsepart=__expr_null__.b)
	If expr
		truepart
	Else
		falsepart
	EndIf
EndMacro

Only works in super basic cases. I can't do this for example:

Code: Select all

MessageRequester("Current score is", Str(Points) + " " + Iif(Points = 1, "point", "points"))

That's why I'd like it to be a language feature, not a new function. But we know how Fred feels about those.

[AZJIO]

Code: Select all

Procedure.s IIF(expr, truepart.s, falsepart.s)
	If expr
		ProcedureReturn truepart
	Else
		ProcedureReturn falsepart
	EndIf
EndProcedure

Global result.s, userInput.a = 1
result.s = IIF(userInput & 1, "Odd", "Even")
Debug "The number is " + result

Global Points = 1
MessageRequester("Current score is", Str(Points) + " " + Iif(Bool(Points = 1), "point", "points"))

[ebs]

Only because I'm extremely lazy (apologies to AZJIO):

Code: Select all

Macro IIF(_expr, _truepart, _falsepart)
  IIFX(Bool(_expr), _truepart, _falsepart)
EndMacro

Procedure.s IIFX(expr, truepart.s, falsepart.s)
	If expr
		ProcedureReturn truepart
  Else
		ProcedureReturn falsepart
  EndIf
EndProcedure

Global result.s, userInput.a = 1
result.s = IIF(userInput & 1, "Odd", "Even")
Debug "The number is " + result

Global Points = 1
MessageRequester("Current score is", Str(Points) + " " + IIF(Points = 1, "point", "points"))

[Piero]

Macro IIF(_expr,

That's great, I didn't know/remember!

PS: IIFs$

Code: Select all

Points = 10
Debug "Score: " + Str(Points) + " Point" +
   Mid("s",Bool(Points=1)+1) +" ("+ StringField("Even|Odd",Points&1+1,"|") +")"

[Piero]

Summarizing:

Code: Select all

Macro IIF(e,s)
   StringField(s,Bool(Not(e))+1,"|")
EndMacro

x=10
Debug ""+x+" Point"+ IIF(x=1, "|s")
Debug ""+x+" is "+ IIF(x&1, "Odd|Even")
Debug IIF(1=0 or 0=0, "True|Not True")