ExplorerListGadget

[rndrei]

How to remove the size,type,modefied columns?

Code: Select all

If OpenWindow(0, 0, 0, 500, 300, "ExplorerListGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ExplorerListGadget(1, 10, 10, 500, 300, "/home/user/examples/;*.txt" , #PB_Explorer_MultiSelect)
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

[TI-994A]

How to remove the size,type,modefied columns?

Try this:

Code: Select all

If OpenWindow(0, 0, 0, 500, 300, "ExplorerListGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ExplorerListGadget(1, 10, 10, 500, 300, GetHomeDirectory() , #PB_Explorer_MultiSelect)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)
  Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf 

[rndrei]

Just what you need, thank you!

[rndrei]

How to remove the size,type,modefied columns?

Try this:

Code: Select all

If OpenWindow(0, 0, 0, 500, 300, "ExplorerListGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ExplorerListGadget(1, 10, 10, 500, 300, GetHomeDirectory() , #PB_Explorer_MultiSelect)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)
  Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf 

Tell me how to remove the title (NAME)?

[TI-994A]

Tell me how to remove the title (NAME)?

Code: Select all

RemoveGadgetColumn(1, 0)

[rndrei]

Then it does not show folders and files!?

[Shardik]

Then it does not show folders and files!?

I have modified TI-994A's example to remove the title row of the ExplorerListGadget (cross-platform; successfully tested in MacOS 'Ventura', Linux Mint 21.3 x64 'Virginia' and Windows 10 23H2 with PB 6.20 x86 and x64):

Code: Select all

If OpenWindow(0, 0, 0, 500, 300, "ExplorerListGadget",
  #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ExplorerListGadget(1, 10, 10, 500, 300, GetHomeDirectory(),
    #PB_Explorer_MultiSelect)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)
  RemoveGadgetColumn(1, 1)

  ; ----- Remove title row

  CompilerSelect #PB_Compiler_OS
    CompilerCase #PB_OS_Linux
      gtk_tree_view_set_headers_visible_(GadgetID(1), 0)
    CompilerCase #PB_OS_MacOS
      CocoaMessage(0, GadgetID(1), "setHeaderView:", 0)
    CompilerCase #PB_OS_Windows
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1),
        #GWL_STYLE) | #LVS_NOCOLUMNHEADER)
  CompilerEndSelect

  Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf

[rndrei]

Works! And where can I see the list of functions GTK_?

[mk-soft]

Google ?!

https://docs.gtk.org/gtk3/class.Widget.html
https://docs.gtk.org/gtk3/class.TreeView.html
...
...
...
https://docs.gtk.org/gtk3/class.Window.html#description

Or do you not know the search engine