PokeS() vs *String\s

[Justin]

Is it legal to do this or are both options wrong?

Code: Select all

EnableExplicit

Procedure test(st.i)
	Protected.String *s
	
	*s = @st
	*s\s = "foo" ;OK?
	
	;PokeS(st, "foo") ;Wrong?
EndProcedure

Define.s st

st = ""

test(@st)

Debug st

[infratec]

Enable Purifier and set granularity to 1, 1, 1, 1

Then you should see that both is wrong.
You don't have the place to store the string.

You can do

Code: Select all

st = space(512)

[STARGÅTE]

Both codes are wrong.

With PokeS(), you did not allocate the additional needed memory, which causes an IMA.
With *s\s you write a new string and the memory address could change, so the main string is not affacted:

Code: Select all

EnableExplicit

Procedure test(st.i)
	Protected.String *s
	
	*s = @st
	*s\s = "Hello World"
	Debug "Local: " + @*s\s

	;PokeS(st, "foo") ;Wrong?
EndProcedure


Define.s st

st = "123"
Debug "Main: " + @st
test(@st)
Debug "Main: " + @st

Debug st

You should use the String-Structure in the Main-Code and Procedure:

Code: Select all

Procedure test(*s.String)
	*s\s = "Hello World"
EndProcedure

Define MyString.String

MyString\s = "123"
test(@MyString)
Debug MyString\s

[SMaag]

@justin
Why you want to to this?

If you want to speed up String-Parameters in Procedures - if you don't want PB to copy the String!

The solution is Prototype your Procedure. Then PureBasic pass the StringPointer directly and do not make a copy
of the String.

here is an example for

Code: Select all

EnableExplicit

Prototype.i ReplaceChar(String$, cSearch.c, cReplace.c) ; ProtoType-Function for ReplaceChar
Global ReplaceChar.ReplaceChar                          ; define Prototype-Handler for CountChar

Procedure.i _ReplaceChar(*String, cSearch.c, cReplace.c)
           
  Protected *char.Character   ; Pointer to a virutal Char-Struct
  Protected N
  
  *char = *String         
  If *char    
    While *char\c               ; until end of String
      If *char\c =  cSearch
        *char\c = cReplace    ; replace the Char
        N + 1
      EndIf
      *char + SizeOf(Character)   ; Index to next Char
    Wend
  EndIf
  ProcedureReturn N     
EndProcedure
ReplaceChar = @_ReplaceChar()     ; Bind ProcedureAdress to the PrototypeHandler

Define Txt$="1234561.123456111"

Debug Txt$
ReplaceChar(Txt$, '1', 'A')   ; Txt$ is passed as @Txt$
Debug Txt$

[Justin]

So both are wrong, thanks!

[AZJIO]

Code: Select all

test(@st)

If you pass the pointer, then you must accept it as a pointer

Code: Select all

Procedure test(*st)

Or pointer to the structure

Code: Select all

Procedure test(*st.Integer)

Code: Select all

*s = @st

Here, "st" is a pointer, and you again take the pointer from it. You don't have a string in the pointer, but a number pointer.

[STARGÅTE]

Code: Select all

*s = @st

Here, "st" is a pointer, and you again take the pointer from it. You don't have a string in the pointer, but a number pointer.

This part of Justin's code is right.
"st" is a pointer (integer) and you have to receive its pointer as well to take it over to the String-Structure .String, because here you have a Pointer to a Structure its first field is a pointer to a string.

Code: Select all

Define String.s  = "Hello World"  ; The string
Define *Pointer  = @String        ; Pointer to the String content itself
Define *StringStructure.String = @*Pointer  ; Pointer to the String-Pointer

Debug *StringStructure\s

However, this way is read-only. During write, you would change the string location in memory, which is not reflected back to String.s

[AZJIO]

STARGÅTE
Yes, you're right, I forgot that lately I've been using *c.Character pointers, where you need to take a pointer 1 time.

[AZJIO]

I've experimented with such a feature before. If you are passing a pointer instead of a structure, then you cannot increase the length of the string, since it is declared in the outer scope. If the author of the topic has passed an empty string and then writes data to it, then he will simply break the memory.

Code: Select all

Procedure.s TrimLeft(*a, n)
	Protected *p.string = @*a
	*p\s = Right(*p\s, Len(*p\s) - n)
EndProcedure
tmp$ = "Hello world"
TrimLeft(@tmp$, 3)
Debug tmp$

Instead of test(@st), you should use:

Code: Select all

Define st.String
test(@st)

[STARGÅTE]

If you are passing a pointer instead of a structure, then you cannot increase the length of the string, since it is declared in the outer scope.

Exactly.