Popup Window like Mssage Requester?

[matalog]

Is there a way to have a popup window the same as Messagerequester() which does not halt the operation of the program until the user clicks on it?

[BarryG]

See #3 example by AZJIO here -> https://www.purebasic.fr/english/viewto ... 04#p621304

[RASHAD]

Code: Select all

Procedure timerCB()
  Static i
  i+1
  SetGadgetText(3, Str(i))
EndProcedure

If OpenWindow(0, 0, 0, 520, 300, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ButtonGadget(0, 10, 10, 120, 30, "Window")
  TextGadget(3, 10, 50, 210, 20, "0")
  If OpenWindow(1, 0, 0, 220, 100, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_Invisible,WindowID(0))
    TextGadget(2, 10, 10, 210, 20, "Hello")
    ButtonGadget(1, 10, 40, 120, 30, "Close")
    StickyWindow(1, #True) 
  EndIf
  
  AddWindowTimer(0, 0, 100)
  BindEvent(#PB_Event_Timer,@timerCB())
  
  Repeat
    Select WaitWindowEvent(1)
      Case #PB_Event_CloseWindow
        Quit = 1
        
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 0
            HideWindow(1, #False)
          Case 1
            HideWindow(1, #True)
        EndSelect
    EndSelect
  Until Quit = 1
EndIf