[PB6.11] assembler backend (x86+x64) _DateUTC() bug

[benubi]

Hello, I don't know where to post it in the bug section so I post it here.

The program Atomic Webserver 3 uses _DateUTC() and on Windows (x86 and x64 - assembler backend) PB6.11 the imported procedure fails and returns a pointer or some other unusable value when called.

Would be nice if it could be used again in the next PB version as I started to play around with UTC dates and I'd like to write something that needs precise UTC date/time & course it would be even better if we had a DateUTC() one day in PB's date library instead of using internals/API.

It still works fine on the Linux versions I tested and on the C backend (but it makes it more complicated to select/unselect the compiler in the options manually for every compilation when transferring/opening the source on the other OS'es IDE's - the Linux IDE's can't find the selected compiler).

CompilerSelect #PB_Compiler_OS ;for compatiblity with 6.04lts
CompilerCase #PB_OS_Windows
CompilerIf #PB_Compiler_32Bit
ImportC ""
_DateUTC.q(t = #Null) As "_time"
EndImport
CompilerElse
ImportC ""
_DateUTC.q(t = #Null) As "time"
EndImport
CompilerEndIf
CompilerCase #PB_OS_Linux
Procedure.q _DateUTC()
ProcedureReturn time_(#Null)
EndProcedure
CompilerCase #PB_OS_MacOS
ImportC ""
CFAbsoluteTimeGetCurrent.d()
EndImport
Procedure.q _DateUTC()
ProcedureReturn CFAbsoluteTimeGetCurrent() + Date(2001, 1, 1, 0, 0, 0)
EndProcedure
CompilerEndSelect

[freak]

There is a native function now: https://www.purebasic.com/documentation ... teutc.html

[idle]

The function is only supposed to be imported for compatibility for pb6.04 and earlier
I will post the fix later today thanks.

Code: Select all

CompilerIf #PB_Compiler_Version <= 604 
  CompilerSelect #PB_Compiler_OS ;for compatiblity with 6.04lts mk-soft
    CompilerCase #PB_OS_Windows
      CompilerIf #PB_Compiler_32Bit
        ImportC "" 
          DateUTC.q(t=0) As "_time"  
        EndImport 
      CompilerElse   
        ImportC "" 
          DateUTC.q(t=0) As "time"  
        EndImport 
      CompilerEndIf
    CompilerCase #PB_OS_Linux
      Procedure.q DateUTC()
        ProcedureReturn time_(#Null)
      EndProcedure
    CompilerCase #PB_OS_MacOS
      ImportC ""
        CFAbsoluteTimeGetCurrent.d()
      EndImport
      Procedure.q DateUTC()
        ProcedureReturn CFAbsoluteTimeGetCurrent() + Date(2001, 1, 1, 0, 0, 0)
      EndProcedure
  CompilerEndSelect
CompilerEndIf 

[benubi]

OMG it already exists

Well, that's much better than I imagined.
I had it all backwards here.

Sorry & thanks to everybody

[idle]

OMG it already exists

Well, that's much better than I imagined.
I had it all backwards here.

Sorry & thanks to everybody

Thank you, I didn't spot it as I'm mostly testing on Linux.

[Mikes]

The ConvertDate function for 6.04 and below

Code: Select all

CompilerIf #PB_Compiler_Version <= 604 
  #PB_Date_LocalTime = 0
  #PB_Date_UTC = 1
  Procedure.q ConvertDate(ParmDate.q, ParmFormat.b) 
    If ParmFormat
      ProcedureReturn ParmDate - (Date() - DateUTC())
    Else
      ProcedureReturn ParmDate + (Date() - DateUTC())
    EndIf
  EndProcedure
CompilerEndIf

Test code

Code: Select all

EnableExplicit
Define UTCDateTime.q, LocalDateTime.q

UTCDateTime = DateUTC()
LocalDateTime = ConvertDate(UTCDateTime, #PB_Date_LocalTime)

Debug FormatDate("UTC time: %mm/%dd/%yyyy %hh:%ii:%ss", UTCDateTime)
Debug FormatDate("Local time: %mm/%dd/%yyyy %hh:%ii:%ss", LocalDateTime)
Debug FormatDate("Test Local back to UTC time: %mm/%dd/%yyyy %hh:%ii:%ss", ConvertDate(LocalDateTime, #PB_Date_UTC))