6.10b7 CustomFilterCallback() error

[hoerbie]

Hi,

using the following example from the docs

Code: Select all

Procedure FilterCallback(x, y, SourceColor, TargetColor)
    ; Take only the Red component from the Source, do not modify the others
    ProcedureReturn RGBA(Red(SourceColor), Green(TargetColor), Blue(TargetColor), Alpha(TargetColor))
  EndProcedure
  
  UseJPEGImageDecoder()

  If OpenWindow(0, 0, 0, 400, 200, "2DDrawing Example", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    LoadImage(1, #PB_Compiler_Home + "examples/3d/Data/Textures/clouds.jpg")
  
    If CreateImage(0, 400, 200) And StartDrawing(ImageOutput(0))
      DrawImage(ImageID(1), 0, 0, 400, 200)
      
      DrawingMode(#PB_2DDrawing_CustomFilter)      
      CustomFilterCallback(@FilterCallback())
      Circle(100, 100, 100, $0000FF)   
      Circle(300, 100, 100, $000000)
      
      StopDrawing() 
      ImageGadget(0, 0, 0, 400, 200, ImageID(0))
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

I get an error message

Code: Select all

CustomFilterCallback(): The Procedure specified in '@Callback()' does not have the required argument or returntype.

I don't know if this is a general problem of the C compiler or only on mac, or maybe a problem of the docs?

Because in the docs it is written:

The SourceColor ... and the TargetColor .... Both colors are always 32-bit with alpha channel independent of the color depth of the output. The callback has to calculate the color that the target pixel should have after the drawing and return that.

But normally for PB it is told, that if NO type is given, the .i integer type will be used, that on 64-bit systems will be 64-bit and not the 32-bit for colors from the help.

Thanks, hoerbie

[mk-soft]

New since Beta 7 to avoid invalid value range

Code: Select all

Procedure FilterCallback(x, y, SourceColor.l, TargetColor.l) ; <- Colors must be define as long
  ; Take only the Red component from the Source, do not modify the others
  ProcedureReturn RGBA(Red(SourceColor), Green(TargetColor), Blue(TargetColor), Alpha(TargetColor))
EndProcedure

UseJPEGImageDecoder()

If OpenWindow(0, 0, 0, 400, 200, "2DDrawing Example", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  LoadImage(1, #PB_Compiler_Home + "examples/3d/Data/Textures/clouds.jpg")
  
  If CreateImage(0, 400, 200) And StartDrawing(ImageOutput(0))
    DrawImage(ImageID(1), 0, 0, 400, 200)
    
    DrawingMode(#PB_2DDrawing_CustomFilter)      
    CustomFilterCallback(@FilterCallback())
    Circle(100, 100, 100, $0000FF)   
    Circle(300, 100, 100, $000000)
    
    StopDrawing() 
    ImageGadget(0, 0, 0, 400, 200, ImageID(0))
  EndIf
  
  Repeat
    Event = WaitWindowEvent()
  Until Event = #PB_Event_CloseWindow
EndIf

Link: https://www.purebasic.fr/english/viewto ... 45#p616845

[hoerbie]

Hi,

thanks, then the (english) doc of the 6.10b7 is not up to date on Mac.

And in the case of making it stricter, I would then additionally expect an

Code: Select all

Procedure.l FilterCallback(x, y, SourceColor.l, TargetColor.l) ; <- Colors must be define as long
          ^

declaration for the return parameter, because it just as well gives back a color.

Greets, hoerbie