How to send an email as html?

Johanson · Post by **Johanson** » Tue Mar 09, 2021 10:50 am

How to send an email as html (v.5.73 !!! )

it is impossible that there is a programming language that cannot send an email in html format.

infratec · Post by **infratec** » Tue Mar 09, 2021 11:05 am

Hm ...

if I look at C, it can do nearly nothing.
It all depends on libraries.

If you can nothing find here in the forum, simply choose a library of your choice and write a wrapper.

infratec · Post by **infratec** » Tue Mar 09, 2021 11:11 am

Or you can use the 'inbuild' libcurl

viewtopic.php?p=591235

An example:
https://curl.se/libcurl/c/smtp-mime.html

Or more simple:
https://curl.se/mail/lib-2012-01/0121.html

Johanson · Post by **Johanson** » Tue Mar 09, 2021 6:43 pm

infratec wrote:Hm ...

if I look at C, it can do nearly nothing.
It all depends on libraries.

If you can nothing find here in the forum, simply choose a library of your choice and write a wrapper.

what does it mean?:

Code: Select all

#PB_Mail_Custom : Add customs fields (can be multi-line).

Keya · Post by **Keya** » Tue Mar 09, 2021 6:48 pm

Send yourself a plaintext email saying Hello, then send yourself a HTML version of the same. Compare the differences and it becomes obvious

Johanson · Post by **Johanson** » Tue Mar 09, 2021 7:07 pm

Keya wrote:Send yourself a plaintext email saying Hello, then send yourself a HTML version of the same. Compare the differences and it becomes obvious

such suggestions are ...
...
I know exactly how the structure should look like, but how do I send it in PB ???

Question:
Will the following notation work in PB 5.73:

Code: Select all

SetMailBody (0, "MIME-Version: 1.0" + # CRLF $ +
                       "Content-Type: multipart / alternative; boundary = '-------'" + # CRLF $ +
                       "Content-Language: en" + # CRLF $ +
                       "This is a multi-part message in MIME format." + # CRLF $ +
                       "---------" + # CRLF $ +
                       "Content-Type: text / plain; charset = utf-8; format = flowed" + # CRLF $ +
                       "Content-Transfer-Encoding: 7bit" + # CRLF $ +
                       "non html" + # CRLF $ +
                       "---------" + # CRLF $ +
                       "Content-Type: text / html; charset = utf-8" + # CRLF $ +
                       "Content-Transfer-Encoding: 8bit" + # CRLF $ +
                       "<html>" + # CRLF $ +
                       "<head>" + # CRLF $ +
                       "<meta http-equiv = 'content-type' content = 'text / html; charset = UTF-8'>" + # CRLF $ +
                       "<title> topic </title>" + # CRLF $ +
                       "</head>" + # CRLF $ +
                       "<body>" + # CRLF $ +
                       "<p> As <font size = '+ 2'> sss </font> <br>" + # CRLF $ +
                       "</p>" + # CRLF $ +
                       "</body>" + # CRLF $ +
                       "</html>" + # CRLF $ +
                       "-----------")

No !
Or maybe this:

Code: Select all

SetMailAttribute (#Mail, #PB_Mail_Custom, 
                       "MIME-Version: 1.0" + # CRLF $ +
                       "Content-Type: multipart / alternative; boundary = '-------'" + # CRLF $ +
                       "Content-Language: en" + # CRLF $ +
                       "This is a multi-part message in MIME format." + # CRLF $ +
                       "---------" + # CRLF $ +
                       "Content-Type: text / plain; charset = utf-8; format = flowed" + # CRLF $ +
                       "Content-Transfer-Encoding: 7bit" + # CRLF $ +
                       "non html" + # CRLF $ +
                       "---------" + # CRLF $ +
                       "Content-Type: text / html; charset = utf-8" + # CRLF $ +
                       "Content-Transfer-Encoding: 8bit")

Hmmm????
If it used to work (in previous versions), why did it suddenly stop?

infratec · Post by **infratec** » Tue Mar 09, 2021 9:12 pm

As written ...
it will not work with te e-mail functions of PB, since the original Content-Type is still present.
At the moment you can not replace it, you can only add an additional one.
I already added a feature request about this:
viewtopic.php?f=3&t=72187

You have to use the way I showed you with libcurl.

Johanson · Post by **Johanson** » Wed Mar 10, 2021 12:05 am

infratec wrote:As written ...
You have to use the way I showed you with libcurl.

POLINK: error: Unresollved external symbol
'_curl_easy_strerror'.
POLINK: fatal error: 1 unresolved external(s).

Johanson · Post by **Johanson** » Wed Mar 10, 2021 12:37 am

By the way:

Code: Select all

SendMail(#Mail, Smtp$ [, Port [, Flags [, User$, Password$]]])

... returns NONZERO if the mail was sent correctly and zero otherwise
but

Code: Select all

If CreateMail(0, "senderMail", "Subject: Hello !")
  SetMailBody(0, "Hello !")
  AddMailRecipient(0, "mailTO", #PB_Mail_To)
  Result = SendMail(0, "smtpserver", 465, #PB_Mail_Asynchronous, "user", "password")
  Debug "Result="+Str(Result)
  Repeat
    Progress = MailProgress(0):  Delay(300)
  Until Progress = #PB_Mail_Finished Or Progress = #PB_Mail_Error
  
  If Progress = #PB_Mail_Finished
    MessageRequester("Information", "Mail correctly sent !")
  Else
    MessageRequester("Error", "Can't sent the mail !")
  EndIf
EndIf

Result=1 ==> NONZERO, but "Can't sent the mail !"

Why ???

dige · Post by **dige** » Wed Mar 10, 2021 7:47 am

http://www.purebasic.fr/english/viewtop ... 12&t=50538

infratec · Post by **infratec** » Wed Mar 10, 2021 7:51 am

Johanson wrote:
infratec wrote:As written ...
You have to use the way I showed you with libcurl.
POLINK: error: Unresollved external symbol
'_curl_easy_strerror'.
POLINK: fatal error: 1 unresolved external(s).

From where is your used libcurl.pbi?
Which OS are you using?

Johanson · Post by **Johanson** » Wed Mar 10, 2021 8:08 am

infratec wrote:
Johanson wrote:
infratec wrote:As written ...
You have to use the way I showed you with libcurl.
POLINK: error: Unresollved external symbol
'_curl_easy_strerror'.
POLINK: fatal error: 1 unresolved external(s).
From where is your used libcurl.pbi?
Which OS are you using?

Win10 x64

Johanson · Post by **Johanson** » Wed Mar 10, 2021 8:35 am

dige wrote:http://www.purebasic.fr/english/viewtop ... 12&t=50538

I tried
I remind you: I have version 5.73

infratec · Post by **infratec** » Wed Mar 10, 2021 10:55 am

I added the mime stuff in my libcurl.pbi

viewtopic.php?p=591235

This code works:

Code: Select all

;
; LibCurl e-mail with html body
;

EnableExplicit

IncludeFile "libcurl.pbi"

#MailServer = "smtp://mail.example.com"

#FROM = "<sender@example.org>"
#To = "<addressee@example.net>"

#SMTP_User = ""
#SMTP_Password = ""

;#SKIP_PEER_VERIFICATION = #True
;#SKIP_HOSTNAME_VERIFICATION = #True

Define.i curl, i, res
Define.curl_slist *recipients, *headers, *slist
Define.curl_mime *mime, *alt
Define *part
Define inline_text$, inline_html$

Dim HeaderArray$(5)

HeaderArray$(0) = "Date: Wed, 10 Mar 2021 06:30:29 +0200"
HeaderArray$(1) = "To: "+ #TO
HeaderArray$(2) = "From: " + #FROM + " (Example User)"
HeaderArray$(3) = "Message-ID: <dcd7cb36-11db-487a-9f3a-e652a9458efd@rfcpedant.example.org>"
HeaderArray$(4) = "Subject: example sending a MIME-formatted message"

inline_text$ = "This is the inline text message of the e-mail." + #CRLF$
inline_text$ + #CRLF$
inline_text$ + "It could be a lot of lines that would be displayed in an e-mail" + #CRLF$
inline_text$ + "viewer that is not able to handle HTML." + #CRLF$

inline_html$ = "<html>" + #CRLF$
inline_html$ + " <body>" + #CRLF$
inline_html$ + "  <p>This is the inline <b>HTML</b> message of the e-mail.</p>" + #CRLF$
inline_html$ + "  <br />" + #CRLF$
inline_html$ + "  <p>It could be a lot of HTML data that would be displayed by e-mail viewers able To handle HTML.</p>" + #CRLF$
inline_html$ + " </body>" + #CRLF$
inline_html$ + "</html>" + #CRLF$

curl = curl_easy_init()
If curl
  
  If #SMTP_User <> ""
    ; Set username And password
    curl_easy_setopt_str(curl, #CURLOPT_USERNAME, #SMTP_User)
    curl_easy_setopt_str(curl, #CURLOPT_PASSWORD, #SMTP_Password)
  EndIf
  
  
  If Left(#MailServer, 5) = "smtps"
    ; If you want To connect To a site who isn't using a certificate that is
    ; signed by one of the certs in the CA bundle you have, you can skip the
    ; verification of the server's certificate. This makes the connection
    ; A LOT LESS SECURE.
    ;
    ; If you have a CA cert For the server stored someplace Else than in the
    ; Default bundle, then the CURLOPT_CAPATH option might come handy For
    ; you.
    CompilerIf Defined(SKIP_PEER_VERIFICATION, #PB_Constant)
      CompilerIf #SKIP_PEER_VERIFICATION
        curl_easy_setopt(curl, #CURLOPT_SSL_VERIFYPEER, 0)
      CompilerEndIf
    CompilerEndIf
    
    ; If the site you're connecting to uses a different host name that what
    ; they have mentioned in their server certificate's commonName (or
    ; subjectAltName) fields, libcurl will refuse To connect. You can skip
    ; this check, but this will make the connection less secure. */
    CompilerIf Defined(SKIP_HOSTNAME_VERIFICATION, #PB_Constant)
      CompilerIf #SKIP_HOSTNAME_VERIFICATION
        curl_easy_setopt(curl, #CURLOPT_SSL_VERIFYHOST, 0)
      CompilerEndIf
    CompilerEndIf
  EndIf
  
  
  ; This is the URL for your mailserver
  curl_easy_setopt_str(curl, #CURLOPT_URL, #MailServer)
  
  
  curl_easy_setopt_str(curl, #CURLOPT_MAIL_FROM, #FROM)
  
  *recipients = curl_slist_append(*recipients, #To)
  curl_easy_setopt(curl, #CURLOPT_MAIL_RCPT, *recipients)
  
  ; Build and set the message header list.
  For i = 0 To ArraySize(HeaderArray$()) - 1
    *headers = curl_slist_append(*headers, HeaderArray$(i))
  Next i
  curl_easy_setopt(curl, #CURLOPT_HTTPHEADER, *headers)
  
  ; Build the mime message.
  *mime = curl_mime_init(curl)
  
  ; The inline part is an alternative proposing the html and the text versions of the e-mail.
  *alt = curl_mime_init(curl)
  
  ; HTML message.
  *part = curl_mime_addpart(*alt)
  curl_mime_data(*part, inline_html$, #CURL_ZERO_TERMINATED)
  curl_mime_type(*part, "text/html")
  
  ; Text message.
  *part = curl_mime_addpart(*alt)
  curl_mime_data(*part, inline_text$, #CURL_ZERO_TERMINATED)
  
  ; Create the inline part.
  *part = curl_mime_addpart(*mime)
  curl_mime_subparts(*part, *alt)
  curl_mime_type(*part, "multipart/alternative")
  *slist = curl_slist_append(#Null, "Content-Disposition: inline")
  curl_mime_headers(*part, *slist, 1)
  
  ; Add the current source program As an attachment.
;   *part = curl_mime_addpart(*mime)
;   curl_mime_filedata(*part, "EMailWithHTML.pb")
  
  curl_easy_setopt(curl, #CURLOPT_MIMEPOST, *mime)
  
  ; Send the message
  res = curl_easy_perform(curl)
  ; Check For errors
  If res <> #CURLE_OK
    Debug "curl_easy_perform() failed: " + curl_easy_strerror(res)
  EndIf
  
  ; Free multipart message.
  curl_mime_free(*mime)
  
  ; Free lists.
  curl_slist_free_all(*headers)
  curl_slist_free_all(*recipients)
  
  curl_easy_cleanup(curl)
EndIf

Of course you have to adust the server and user stuff.

Johanson · Post by **Johanson** » Wed Mar 10, 2021 4:20 pm

infratec wrote:I added the mime stuff in my libcurl.pbi

https://www.von-der-salierburg.de/downl ... urldll.zip

This code works:

Code: Select all

;
; LibCurl e-mail with html body
;

EnableExplicit

IncludeFile "libcurl.pbi"

#MailServer = "smtp://mail.example.com"

#FROM = "<sender@example.org>"
#To = "<addressee@example.net>"

#SMTP_User = ""
#SMTP_Password = ""

;#SKIP_PEER_VERIFICATION = #True
;#SKIP_HOSTNAME_VERIFICATION = #True

Define.i curl, i, res
Define.curl_slist *recipients, *headers, *slist
Define.curl_mime *mime, *alt
Define *part
Define inline_text$, inline_html$

Dim HeaderArray$(5)

HeaderArray$(0) = "Date: Wed, 10 Mar 2021 06:30:29 +0200"
HeaderArray$(1) = "To: "+ #TO
HeaderArray$(2) = "From: " + #FROM + " (Example User)"
HeaderArray$(3) = "Message-ID: <dcd7cb36-11db-487a-9f3a-e652a9458efd@rfcpedant.example.org>"
HeaderArray$(4) = "Subject: example sending a MIME-formatted message"

inline_text$ = "This is the inline text message of the e-mail." + #CRLF$
inline_text$ + #CRLF$
inline_text$ + "It could be a lot of lines that would be displayed in an e-mail" + #CRLF$
inline_text$ + "viewer that is not able to handle HTML." + #CRLF$

inline_html$ = "<html>" + #CRLF$
inline_html$ + " <body>" + #CRLF$
inline_html$ + "  <p>This is the inline <b>HTML</b> message of the e-mail.</p>" + #CRLF$
inline_html$ + "  <br />" + #CRLF$
inline_html$ + "  <p>It could be a lot of HTML data that would be displayed by e-mail viewers able To handle HTML.</p>" + #CRLF$
inline_html$ + " </body>" + #CRLF$
inline_html$ + "</html>" + #CRLF$

curl = curl_easy_init()
If curl
  
  If #SMTP_User <> ""
    ; Set username And password
    curl_easy_setopt_str(curl, #CURLOPT_USERNAME, #SMTP_User)
    curl_easy_setopt_str(curl, #CURLOPT_PASSWORD, #SMTP_Password)
  EndIf
  
  
  If Left(#MailServer, 5) = "smtps"
    ; If you want To connect To a site who isn't using a certificate that is
    ; signed by one of the certs in the CA bundle you have, you can skip the
    ; verification of the server's certificate. This makes the connection
    ; A LOT LESS SECURE.
    ;
    ; If you have a CA cert For the server stored someplace Else than in the
    ; Default bundle, then the CURLOPT_CAPATH option might come handy For
    ; you.
    CompilerIf Defined(SKIP_PEER_VERIFICATION, #PB_Constant)
      CompilerIf #SKIP_PEER_VERIFICATION
        curl_easy_setopt(curl, #CURLOPT_SSL_VERIFYPEER, 0)
      CompilerEndIf
    CompilerEndIf
    
    ; If the site you're connecting to uses a different host name that what
    ; they have mentioned in their server certificate's commonName (or
    ; subjectAltName) fields, libcurl will refuse To connect. You can skip
    ; this check, but this will make the connection less secure. */
    CompilerIf Defined(SKIP_HOSTNAME_VERIFICATION, #PB_Constant)
      CompilerIf #SKIP_HOSTNAME_VERIFICATION
        curl_easy_setopt(curl, #CURLOPT_SSL_VERIFYHOST, 0)
      CompilerEndIf
    CompilerEndIf
  EndIf
  
  
  ; This is the URL for your mailserver
  curl_easy_setopt_str(curl, #CURLOPT_URL, #MailServer)
  
  
  curl_easy_setopt_str(curl, #CURLOPT_MAIL_FROM, #FROM)
  
  *recipients = curl_slist_append(*recipients, #To)
  curl_easy_setopt(curl, #CURLOPT_MAIL_RCPT, *recipients)
  
  ; Build and set the message header list.
  For i = 0 To ArraySize(HeaderArray$()) - 1
    *headers = curl_slist_append(*headers, HeaderArray$(i))
  Next i
  curl_easy_setopt(curl, #CURLOPT_HTTPHEADER, *headers)
  
  ; Build the mime message.
  *mime = curl_mime_init(curl)
  
  ; The inline part is an alternative proposing the html and the text versions of the e-mail.
  *alt = curl_mime_init(curl)
  
  ; HTML message.
  *part = curl_mime_addpart(*alt)
  curl_mime_data(*part, inline_html$, #CURL_ZERO_TERMINATED)
  curl_mime_type(*part, "text/html")
  
  ; Text message.
  *part = curl_mime_addpart(*alt)
  curl_mime_data(*part, inline_text$, #CURL_ZERO_TERMINATED)
  
  ; Create the inline part.
  *part = curl_mime_addpart(*mime)
  curl_mime_subparts(*part, *alt)
  curl_mime_type(*part, "multipart/alternative")
  *slist = curl_slist_append(#Null, "Content-Disposition: inline")
  curl_mime_headers(*part, *slist, 1)
  
  ; Add the current source program As an attachment.
;   *part = curl_mime_addpart(*mime)
;   curl_mime_filedata(*part, "EMailWithHTML.pb")
  
  curl_easy_setopt(curl, #CURLOPT_MIMEPOST, *mime)
  
  ; Send the message
  res = curl_easy_perform(curl)
  ; Check For errors
  If res <> #CURLE_OK
    Debug "curl_easy_perform() failed: " + curl_easy_strerror(res)
  EndIf
  
  ; Free multipart message.
  curl_mime_free(*mime)
  
  ; Free lists.
  curl_slist_free_all(*headers)
  curl_slist_free_all(*recipients)
  
  curl_easy_cleanup(curl)
EndIf

Of course you have to adust the server and user stuff.

Define.curl_mime *mime, *alt
==> 'Structure not found: curl_mime'

PureBasic Forums - English

How to send an email as html?

How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?

Re: How to send an email as html?