WebGadget - show Properties?

[firace]

I guess I really need a WebGadget/API guru on this one...

I'm trying to create a keyboard shortcut to show the web page Properties dialog (the one you get through the IE right-click menu). Any ideas please?

Code: Select all

OpenWindow(0, 632, 42, 600, 500, "Window_0", #PB_Window_SystemMenu)

WebGadget(0, 10, 10, 580, 450, "http://www.purebasic.com")

AddKeyboardShortcut(0,   #PB_Shortcut_F12, 86)         

Repeat 
  e = WaitWindowEvent()
  Select e
    Case #PB_Event_Menu    
      If EventMenu() =    86 : 
        Debug "Show Page Properties"
        
      EndIf
  EndSelect
  
Until e = #PB_Event_CloseWindow

[pstryk]

Hi,
You can use this:

Code: Select all

Enumeration 1
  #OLECMDID_OPEN
  #OLECMDID_NEW
  #OLECMDID_SAVE
  #OLECMDID_SAVEAS
  #OLECMDID_SAVECOPYAS
  #OLECMDID_PRINT
  #OLECMDID_PRINTPREVIEW
  #OLECMDID_PAGESETUP
  #OLECMDID_SPELL
  #OLECMDID_PROPERTIES
  #OLECMDID_CUT
  #OLECMDID_COPY
  #OLECMDID_PASTE
  #OLECMDID_PASTESPECIAL
  #OLECMDID_UNDO
  #OLECMDID_REDO
  #OLECMDID_SELECTALL
  #OLECMDID_CLEARSELECTION
  #OLECMDID_ZOOM
  #OLECMDID_GETZOOMRANGE
  #OLECMDID_UPDATECOMMANDS
  #OLECMDID_REFRESH
  #OLECMDID_STOP
  #OLECMDID_HIDETOOLBARS
  #OLECMDID_SETPROGRESSMAX
  #OLECMDID_SETPROGRESSPOS
  #OLECMDID_SETPROGRESSTEXT
  #OLECMDID_SETTITLE
  #OLECMDID_SETDOWNLOADSTATE
  #OLECMDID_STOPDOWNLOAD
EndEnumeration

Enumeration 0
  #OLECMDEXECOPT_DODEFAULT
  #OLECMDEXECOPT_PROMPTUSER
  #OLECMDEXECOPT_DONTPROMPTUSER
  #OLECMDEXECOPT_SHOWHELP
EndEnumeration

OpenWindow(0, 632, 42, 600, 500, "Window_0", #PB_Window_SystemMenu)

WebGadget(0, 10, 10, 580, 450, "http://www.purebasic.com")

AddKeyboardShortcut(0,   #PB_Shortcut_F12, 86)         

Repeat 
  e = WaitWindowEvent()
  Select e
    Case #PB_Event_Menu    
      If EventMenu() =    86 : 
        Web.IWebBrowser2 = GetWindowLong_(GadgetID(0), #GWL_USERDATA)
        Web\ExecWB(  #OLECMDID_PROPERTIES, #OLECMDEXECOPT_DONTPROMPTUSER, 0, 0)       
      EndIf
  EndSelect
  
Until e = #PB_Event_CloseWindow

Regards
pstryk

[firace]

Amazing! Thank you so much for this answer.