Code structure problem with Modules

[Barbarossa]

Hi all,

I am trying to restructure my code into modules. But I am struggling with the "global" structures.

Let's consider the following code:

Code: Select all

DeclareModule Mod1
	
	Structure CommonStructure
		Number.i
		String.s
	EndStructure
	
	Declare Mod1_Function(*par.CommonStructure)

EndDeclareModule

Module Mod1
	
	Procedure Mod1_Function(*par.CommonStructure)
		Debug *par\Number
	EndProcedure
	
EndModule

DeclareModule Mod2
	
	Structure CommonStructure
		Number.i
		String.s
	EndStructure
	
	Declare Mod2_Function(*par.CommonStructure)

EndDeclareModule

Module Mod2
	
	Procedure Mod2_Function(*par.CommonStructure)
		Debug *par\String
	EndProcedure
	
EndModule

; Main Scope

Structure CommonStructure
	Number.i
	String.s
EndStructure

NewList Test.CommonStructure()	
AddElement(Test())
Test()\Number=1
Test()\String="Test"

UseModule Mod1   ; this raises an error because the compiler inserts Commonstructure 
UseModule Mod2	; into the main scope in which it already exists

Mod1_Function(@Test())
Mod2_Function(@Test())

End

My question is, how can I best solve this?

I can think of two solutions. Both kinda defeat the purpose of using modules. They are:
1. Give every structure an unique name:
- Main_CommonStructure
- Mod1_CommonStructure
- Mod2_CommonStructure
Not really what you would want. Difficult to update the structures too.
2. Don't use UseModule and use prefix Mod1::Mod1_Function() instead
Now you lose the autocomplete and it gives you also longer commands,

Maybe there is a better way. Any input is appreciated!

John

[Little John]

2. Don't use UseModule and use prefix Mod1::Mod1_Function() instead

That's what I always do.
AFAIK it's the only safe way to avoid the naming conflicts which you mentioned.

BTW: Writing something like Mod1_ is not necessary then. It's sufficient to use the respective module prefixes:

Code: Select all

Mod1::MyFunction()
Mod2::MyFunction()
Mod3::MyFunction()

[mk-soft]

I use it a global module

Code: Select all

DeclareModule ModCommon
  Structure CommonStructure
    Number.i
    String.s
  EndStructure
EndDeclareModule

Module ModCommon
  ; Global functions
EndModule

DeclareModule Mod1
  
  Declare Mod1_Function(*par)
  
EndDeclareModule

Module Mod1
  
  Structure CommonStructure
    Number.i
    String.s
  EndStructure

  Procedure Mod1_Function(*par.CommonStructure)
    Debug *par\Number
  EndProcedure
  
EndModule

DeclareModule Mod2
  
  Declare Mod2_Function(*par)
  
EndDeclareModule

Module Mod2
  
  Structure CommonStructure
    Number.i
    String.s
  EndStructure

  Procedure Mod2_Function(*par.CommonStructure)
    Debug *par\String
  EndProcedure
  
EndModule

; Main Scope

UseModule ModCommon
NewList Test.CommonStructure()   
AddElement(Test())
Test()\Number=1
Test()\String="Test"

UseModule Mod1   ; this raises an error because the compiler inserts Commonstructure 
UseModule Mod2   ; into the main scope in which it already exists

Mod1_Function(@Test())
Mod2_Function(@Test())

End

[Barbarossa]

Thanks for the answers. I think I'll go with LittleJohns Solution for now.
MK-softs solution doesn't really work and gives me the same problems as before.

I really think the modules need some more improvement for them to work like they should in theory.

John

[Fred]

IMHO, your should use a global module, and import it in your submodule, so you will actually share the structure:

Code: Select all

DeclareModule ModCommon
  Structure CommonStructure
    Number.i
    String.s
  EndStructure
EndDeclareModule

Module ModCommon
  ; Global functions
EndModule


DeclareModule Mod1
  Declare Function(*par)
EndDeclareModule

Module Mod1
  UseModule ModCommon

  Procedure Function(*par.CommonStructure)
    Debug *par\Number
  EndProcedure
 
EndModule


DeclareModule Mod2
  Declare Function(*par)
EndDeclareModule

Module Mod2
  UseModule ModCommon

  Procedure Function(*par.CommonStructure)
    Debug *par\String
  EndProcedure
EndModule

; Main Scope

UseModule ModCommon

NewList Test.CommonStructure()   
AddElement(Test())
Test()\Number=1
Test()\String="Test"

Mod1::Function(@Test())
Mod2::Function(@Test())

End

[mk-soft]

On this idea I did not come

[Blue]

@Fred

(1) What would be the best place to insert EnableExplicit so that it governs the entirerity of the example you provided above ?
(2) As a general rule, should EnableExplicit appear in the Module part or the DeclareModule part ?

[Fred]

At the top of the file and inside each DeclareModule

[Blue]

Oh la la !! Rapide le monsieur que je pensais trop occupé à pourchasser les bogues pour s'occuper du vrai monde...

Thank you Fred