UDP broadcast on linux is not possible

[lolvince]

hello,

I noticed that the sending request UDP broadcast on linux is not possible with PureBasic.
the "SendNetworkData" function allows you to include the "permission" to create the socket which is a requirement under Linux when sending the broadcast.

Here's an example to test the topic:

PureBasic example (not working because no permission):

Code: Select all

OpenConsole()
If InitNetwork() = 0
  PrintN("Error => Can't initialize the network !")
  Goto killsoft
EndIf
ExamineIPAddresses()
Myip = NextIPAddress()
If Not Myip
  Goto killsoft
EndIf
Myipstr$ = IPString(myip)
Broadcast$ =StringField(IPString(Myip),1,".")+"."+StringField(IPString(Myip),2,".")+"."+StringField(IPString(Myip),3,".")+".255"
PrintN("Your IP : "+ Myipstr$)
PrintN("Your Broadcast : "+Broadcast$)
*Header = AllocateMemory(70) 
connection.i = OpenNetworkConnection(Broadcast$, 50000,#PB_Network_UDP)
If connection <> 0
 PrintN("OpenNetworkConnection OK !")
 ret.i = SendNetworkData(connection, *Header,70)
 While ret = -1
   ret = SendNetworkData(connection, *Header,70)
   PrintN("SendNetworkData return -1 ... retry !")
   Delay(1000)
 Wend
  If ret = 70
    PrintN("Header Sent Correct !")
  Else
    PrintN("Header long error (Not 70) !"); => "+ret)
  EndIf
 CloseNetworkConnection(connection)
Else
  PrintN(" --- ERROR --- OpenNetworkConnection Faild!")
EndIf
killsoft :
Input()

Example C (Functional)

#include <stdlib.h>
#include <sys/types.h>
#include <sys/socket.h>
#include <netinet/in.h>
#include <arpa/inet.h>
#include <time.h>
#include <string.h>
#include <stdio.h>
#include <unistd.h>

int main(int argc, char *argv[])
{
char *dstIP = "192.168.0.255"; /manuel Change !/
char *localIP = "192.168.0.250"; /manuel Change !/
int BroadcastPort = 5000;
int sock; /* Socket */
/-------------------------------Permission Broadcast------------------------------------/
struct sockaddr_in broadcastAddr; /* Broadcast address */
int broadcastPermission; /* Socket opt to set permission to broadcast */
unsigned int localIPLen; /* Length of string to broadcast */
/---------------------------------------------------------------------------------------/
/* Create socket for sending/receiving datagrams */
if ((sock = socket(PF_INET, SOCK_DGRAM, IPPROTO_UDP)) < 0)
perror("socket() failed");
/* Set socket to allow broadcast */
broadcastPermission = 1;
if (setsockopt(sock, SOL_SOCKET, SO_BROADCAST, (void *) &broadcastPermission,
sizeof(broadcastPermission)) < 0)
perror("setsockopt() failed");
/* Construct local address structure */
memset(&broadcastAddr, 0, sizeof(broadcastAddr)); /* Zero out structure */
broadcastAddr.sin_family = AF_INET; /* Internet address family */
broadcastAddr.sin_addr.s_addr = inet_addr(dstIP); /* Broadcast IP address */
broadcastAddr.sin_port = htons(BroadcastPort); /* Broadcast port */
localIPLen = strlen(localIP); /* Find length of localIP */
int j;
for (j=0; j<1; j++) //doesnt mean anything so far, not important
{
/* Broadcast localIP in datagram to clients */
if (sendto(sock, localIP, localIPLen, 0, (struct sockaddr *)
&broadcastAddr, sizeof(broadcastAddr)) != localIPLen)
perror("sendto() sent a different number of bytes than expected");
}
}

Another example purebusic (I can not compile under Linux, but it can include the famous permision)

Code: Select all

Procedure.l SendUDPBroadcastL (port, message.s)
  Protected sock,one,bytes,remote.sockaddr_in

  sock = SOCKET_(#AF_INET,#SOCK_DGRAM,#IPPROTO_IP)
  If ( sock = -1) : ProcedureReturn 1 : EndIf
  one = 1
  If (setsockopt_(sock,#SOL_SOCKET,#SO_BROADCAST,@one,SizeOf(one)) = -1)
    ProcedureReturn 1
  EndIf
  remote\sin_family = #AF_INET
  remote\sin_port = htons_(port)
  remote\sin_addr = #INADDR_BROADCAST
  if (sendto_(sock,message,Len(message),0,@remote,SizeOf(remote)) = -1)
    ProcedureReturn 1
  EndIf
  closesocket_(sock)
  ProcedureReturn 0
EndProcedure

[lolvince]

no solution ?

[jpd]

Hi lolvince,

here a Broadcast sample that works on Linux tested on xubuntu 12.04.

have fun.

jpd

Code: Select all

;http://cs.baylor.edu/~donahoo/practical/CSockets/code/BroadcastSender.c
 
 InitNetwork()

#__SOCKADDR_COMMON_SIZE = 2 

CompilerIf #PB_Compiler_OS = #PB_OS_Linux 
  #UDP_NOCHECKSUM=1
  ;#__SOCKADDR_COMMON_SIZE = 2
  #SOCK_DGRAM = 2
  #SOCK_RAW = 3
  #PF_INET = 2
  #AF_INET = #PF_INET
  #IPPROTO_UDP = 17 
  #INADDR_ANY=0 
  #SO_SNDBUF=4097
  #INADDR_BROADCAST=4294967295
  #SOL_SOCKET = 1;65535
  #SO_BROADCAST=6
  #AF_UNIX=1
  #IPPROTO_IP=0
  #SO_BINDTODEVICE = 25
  #SO_DEBUG = 1
  #SO_REUSEADDR = 4
CompilerEndIf

Structure in_addr
  s_addr.l
EndStructure

Structure _sockaddr
  sa_family.w 
  sa_data.b[14]
EndStructure

Structure _sockaddr_in
  sin_family.w 
  sin_port.w
  sin_addr.in_addr 
  sin_zero.b[SizeOf(_sockaddr)-#__SOCKADDR_COMMON_SIZE-SizeOf(word)-SizeOf(in_addr)] ; Pad To size of `struct sockaddr'.  
EndStructure

Structure BroadcastInfo
  dstIP.s
  port.l
  msg.s
  EndStructure



Procedure Broadcast(Array BroadcastInfo.BroadcastInfo(1))
Protected sock.i
;                         /* Socket */
; /-------------------------------Permission Broadcast------------------------------------/
Protected  broadcastAddr._sockaddr_in;struct sockaddr_in broadcastAddr; /* Broadcast address */
Protected broadcastPermission.i;     int broadcastPermission;          /* Socket opt to set permission to broadcast */
Protected localIPLen.l;     unsigned int localIPLen;       /* Length of string to broadcast */
; /---------------------------------------------------------------------------------------/

; /* Create socket For sending/receiving datagrams */
    sock = SOCKET_(#AF_INET, #SOCK_DGRAM, #IPPROTO_UDP)
    If sock < 0
      Debug "socket failed"
      ProcedureReturn 1
    EndIf
    
    ;/* Set socket To allow broadcast */
    broadcastPermission = 1;
    If setsockopt_(sock, #SOL_SOCKET, #SO_BROADCAST, @broadcastPermission, SizeOf(broadcastPermission) )< 0
      Debug "setsockopt() failed";
      ProcedureReturn 1
    EndIf
    
    ;/* Construct local address Structure */
    FillMemory(@broadcastAddr,SizeOf(broadcastAddr),0)
    
    broadcastAddr\sin_family = #AF_INET;                 /* Internet address family */
    broadcastAddr\sin_addr\s_addr = inet_addr_(BroadcastInfo(0)\dstIP);   /* Broadcast IP address */
    broadcastAddr\sin_port = htons_(BroadcastInfo(0)\port);      /* Broadcast port */
    broadcastAddr\sin_zero=0
    
Repeat 
      
    ;     /* Broadcast localIP in datagram To clients */
    ret= sendto_(sock, BroadcastInfo(0)\msg, Len(BroadcastInfo(0)\msg), 0, @broadcastAddr, SizeOf(broadcastAddr)) ;!= localIPLen)
      If ret <> Len(BroadcastInfo(0)\msg)
           Debug "sendto() sent a different number of bytes than expected";
      Else
        
        CompilerIf #PB_Compiler_OS = #PB_OS_Linux 
                  Sleep_(2)
                CompilerElse
                  Sleep_(2000)
                CompilerEndIf
      EndIf
ForEver
     
EndProcedure
  
  Procedure WatchUDP(Port.l = 49999)
  Protected *Buffer = AllocateMemory(1000) 
  
  
  
  If CreateNetworkServer(0, Port, #PB_Network_UDP) 
      Debug "-UDPServer- Server listening on port: "+Str(Port)
      quit = #False
      Repeat 
        SEvent = NetworkServerEvent() 
        If SEvent 
            ClientID = EventClient()
            ClientIP$ = IPString(GetClientIP(ClientID))
            Select SEvent 
              Case 2 
                Debug "UDPServer: ClientIP " +ClientIP$
                ;AddGadgetItem(#ListView, -1, ClientIP$)
                ReceiveNetworkData(ClientID, *Buffer, 1000) 
                Debug "-UDPServer- recieved message: "+PeekS(*Buffer)
                ReAllocateMemory(*Buffer,1000)
                ;quit = #True
                CompilerIf #PB_Compiler_OS = #PB_OS_Linux 
                  Sleep_(1)
                CompilerElse
                  Sleep_(1000)
                CompilerEndIf
                
            EndSelect 
        EndIf 
      Until quit
    Else 
      Debug "-UDPServer-  Can't create server! Port in use?" 
  EndIf
EndProcedure



Procedure InitBroadcast(dummy.l)

  Protected Dim BroadcastInfo.BroadcastInfo(0)

  With BroadcastInfo(0)
    \dstIP="192.168.169.255"
    \port=2068
    \msg ="Hi @all, here is the master of disaster!"
  EndWith

  Broadcast(BroadcastInfo())
  
EndProcedure

mythread=CreateThread (@InitBroadcast(), 0)

If mythread
  WatchUDP(2068)
EndIf