Local x/y mouse pos inside a gadget

[Mistrel]

Here is a really neat trick for finding the local mouse position within a gadget.

This is adapted from a method I found from a code snippet in the forum. I thought it would be useful enough to post here.

Code: Select all

OpenWindow(0,0,0,320,240,"",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
CreateGadgetList(WindowID(0))
gadget=Frame3DGadget(#PB_Any, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20, "", #PB_Frame3D_Flat)
	
Repeat
event=WaitWindowEvent()
If event
	GetCursorPos_(@cp.point)
	GetWindowRect_(GadgetID(gadget),gr.RECT)
	If PtInRect_(@gr, cp\x, cp\y)
		If GetAsyncKeyState_(#VK_LBUTTON)&32768
			Debug Str(cp\x-gr\left)+"\"+Str(cp\y-gr\top)
		EndIf
	EndIf
EndIf

Until event=#PB_Event_CloseWindow

[netmaestro]

The MapWindowPoints_( api is very useful here as an augmentation to this code. It converts the POINT structure where the cursor position is stored from screen coordinates to gadget coordinates, making any further arithmetic unnecessary:

Code: Select all

   If PtInRect_(@gr, cp\x, cp\y) 
      MapWindowPoints_(#Null, GadgetID(gadget), cp, 1) ; cp now contains gadget coords
      If GetAsyncKeyState_(#VK_LBUTTON)&32768 
         Debug Str(cp\x)+"\"+Str(cp\y) 
      EndIf 
   EndIf 

[Mistrel]

That's great. Thank you.

[popstatic]

Hey, very intersting code snippet, actuallly I was wondering if I could you use the

Code: Select all

PtInRect_(@gr, cp\x, cp\y)

thing in a fullscreenned game, (for detecting if the mouse is over a sprite in the game menu actually).

do you think it may work? because my sprites don't have the

Code: Select all

GadgetID(gadget)

needed by the GetWindowRect_ api, itself needed by PtInRect_

thanx in advance....

[netmaestro]

In a fullscreened game you'll be using a sprite for the mouse pointer, so you can use SpriteCollision() to serve this purpose.

[popstatic]

great, thx for your answer, I must say that I'm a begginer @ fullscreen programming, and and didn't even thought it could be solved that way!

thank you!

[Michael Vogel]

I start to write a simple code for retrieving the column number of a listgadget under the mouse cursor and found this snippet above...
...which seems to have been adapted a little bit to work in PB4.3+:

Code: Select all

OpenWindow(0,0,0,320,240,"",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)

gadget=Frame3DGadget(#PB_Any, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20, "", #PB_Frame3D_Flat)

Repeat
	event=WaitWindowEvent()
	If event
		GetCursorPos_(@cp.point)
		GetWindowRect_(GadgetID(gadget),gr.RECT)
		If PtInRect_(@gr,PeekQ(@cp))
			MapWindowPoints_(#Null, GadgetID(gadget),cp,1) ; cp now contains gadget coords
			;If GetAsyncKeyState_(#VK_LBUTTON)&32768
			Debug Str(cp\x)+"\"+Str(cp\y)
		EndIf
		;EndIf
	EndIf

ForEver

[STARGÅTE]

why use API :

Code: Select all

OpenWindow(0,0,0,320,240,"",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)

gadget=Frame3DGadget(#PB_Any, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20, "", #PB_Frame3D_Flat)

Repeat
   event=WaitWindowEvent()
   If event
     x = WindowMouseX(0)-GadgetX(gadget) : y = WindowMouseY(0)-GadgetY(gadget) 
     If x >= 0 And y >= 0 And x < GadgetWidth(gadget) And y < GadgetHeight(gadget)
       Debug Str(x)+"\"+Str(y)
     EndIf
   EndIf

ForEver