A DLL can return an array ?? [Resolved]

[Kwai chang caine]

Hello at all

Excuse my very bad english

I make this code :

Code of the DLL_Test :

Code: Select all

ProcedureDLL AttachProcess(instance)
 Global Dim Array.s(5) 
EndProcedure

ProcedureDLL CreateArray() 

 For i = 1 To 5 
  Array(i) = "Line " + Str(i) 
 Next 
  
 ProcedureReturn @Array(1) 

EndProcedure 

Code of the exe :

Code: Select all

Dim Array.s(5) 

If OpenLibrary(0, "dll_test.dll") 
  
 ArrayAdress.l = CallFunction(0, "CreateArray") 
 Array(1) = PeekS(ArrayAdress) 

 For i = 1 To 5 
  Debug  Array(i) 
 Next 

 CloseLibrary(0) 

EndIf 

Why the result return only the first line of the array :roll:

Thank you very much for your help

[Trond]

It's not possible to return an array. You must pass the array as a parameter to the function and fill it in.

[Kwai chang caine]

I'm very disappointed

I believed that pure knew make everything

[Psychophanta]

Try this:

Code: Select all

ProcedureDLL AttachProcess(instance)
 Global Dim Array.s(5)
EndProcedure
ProcedureDLL.l CreateArray()
 For i=1 To 5
  Array(i)="Line "+Str(i)
 Next
 ProcedureReturn @Array()
EndProcedure

and

Code: Select all

Dim Array.s(5) 
If OpenLibrary(0,"dll_test.dll")
  *ArrayAdress.l=CallFunction(0,"CreateArray")
  Array()=*ArrayAdress
  For i=1 To 5
    MessageRequester("hi",Array(i))
  Next
  CloseLibrary(0)
EndIf

[Flype]

'Static Dim' allow such manipulations.

[Trond]

'Static Dim' allow such manipulations.

Global Dim = Static Dim.

But each PB array is 8 bytes, the example above sets only 4 bytes, so something is bound to go wrong sometime unless someone knows exactly how PB's arrays are implemented.

[Kwai chang caine]

Thank you Psychophanta for your best code

It's work's fine

And thanks two at FLYPE for his help
I'm glad to see that PureBasic can make everything

I wish you a good day

[Trond]

It's work's fine

It has a memory leak...

[Flype]

'Static Dim' allow such manipulations.

Global Dim = Static Dim.

But each PB array is 8 bytes, the example above sets only 4 bytes, so something is bound to go wrong sometime unless someone knows exactly how PB's arrays are implemented.

It has a memory leak...

please trond, can you explain a bit more, i really don't understand the problem.

is this legal or not ?

Code: Select all

Array()=*ArrayAdress

if so, what's the problem and how to do what Kwaï chang caïne requested ?

[Psychophanta]

is this legal or not ?

Code: Select all

Array()=*ArrayAdress

It is not legal in fact.
You can not re-assign the address of an already created Dim.

See http://www.purebasic.fr/english/viewtopic.php?p=200183
anyway,
@Kwaï chang, you should use structures with [0] inside, instead of arrays with Dim:
Here is a completely safe example i think:

Code: Select all

;DLL:
ProcedureDLL AttachProcess(instance)
 Global Dim Array.s(5)
EndProcedure
ProcedureDLL.l CreateArray()
  For i=0 To 5
    Array(i)="Line "+Str(i)
  Next
  ProcedureReturn @Array()
EndProcedure

Code: Select all

;EXE:
Structure array
  item.s[0]
EndStructure
If OpenLibrary(0,"dll_test.dll")
  *var.array=CallFunction(0,"CreateArray")
  For i=0 To 5
    MessageRequester("hi",*var.array\item[i])
  Next
  CloseLibrary(0)
EndIf

[Kwai chang caine]

@Psychophanta
Thank you for your help