[Résolu] webgadget et ftp sans affichage ...

[kerkael]

Salut,

Je cherche à faire un code qui irait chercher sur un serveur ftp (dont j'ai le login et password) des fichiers dont je n'ai pas la liste.

Précisément :
- mes clients testent leurs connaissances par un test sur une page web.
- la page génère un fichier .txt par jour
- les fichiers suivent la nomenclature : test_produit_1205.txt pour le fichier créé le 12 mai, par exemple
- le fichier du 12 mai contient une ligne par client ayant passé le test
- la page n'est pas interactive - l'utilisateur ne reçoit pas son résultat au test, c'est moi qui le traite et qui génère des stats (donc pas besoin de php)
- je veux automatiser la récupération des .txt une fois de temps en temps.
Mais comme il n'y a pas eu forcément de saisie tel ou tel jour, je ne veux pas traiter de fichiers inexistants.


J'ai bien trouvé sur le forum des codes d'utilisation (et de resize, merci les aminches) de wegbadget. Et l'utilisation d'une URL FTP fonctionne aussi bien qu'une HTTP :

Code : Tout sélectionner

WebGadget(#internet,10,10,620,400,"ftp://user:passwd@serveur.ftp.com/tna")

Cela m'ouvre bien en accès écriture le répertoire contenant tous les test_produit_JJMM.txt que je veux traiter. Ouf.

Question : si je veux récupérer le contenu d'un dossier FTP pour le traiter sans l'afficher, est-ce que je peux utiliser autre chose qu'un webgadget ?

Est-ce qu'un Treegadget peut travailler avec des URL ? J'ai pas réussi à lui fournir ni du http ni du ftp comme chemin, mais est-ce que ma question est absurde ?

Je cherche dans le forum mais je n'ai rien trouvé avec le critère FTP ... rien que ça, ça me parait dingue


Merci de vos suggestions

[kerkael]

Bon ... je vais temporiser ma question, cherchant du côté de Resultat = ReceiveHTTPFile(URL$, NomDeFichier$)

Je vous tiens au courant.

[Ar-S]

Heu mais tu as pas la version finale de PB ??

Resultat = ExamineFTPDirectory(#Ftp)...
NextFTPDirectoryEntry...
ReceiveFTPFile..

ça devrait te donner la solution à ton problème. Si tu brasses des fichiers FTP, aucun besoin d'un webgadget !

Si tu veux récupérer les fichiers ftp de temps en temps, tu joues avec les dates. Toutes les N minutes ou heures (ou jours) openftp etc...

---edit----
j'ai repondu avant ton second topic ^^

[kerkael]

Ah le couillon que je suis !

J'ai la dernière version .. si si ... mais j'ai même pô vu les commandes ftp dans la doc ... désolé Je me concentrais sur les commandes http, alors même que ma question posait sur ftp.

Merci pour ton coup de pouce ... qui me fait trébucher dans le ravin de la honte.

Bon, même pas la peine que je donne du code ici, tout est dans la doc.

[Geo Trouvpatou]

Salut.

Un petit truc que j'ai fait il y a quelques temps.
A toi de décortiquer et d'adapter à tes besoins.

Code : Tout sélectionner

; Geo Trouvpatou 25/02/2009
; Lister Dossiers et Fichiers de son FTP et les trier de A-Z
; OS : Window - Linux

Structure FichierDossierFTP
    Nom$
    Taille.l
EndStructure

NewList NomFichier.FichierDossierFTP()
NewList NomDossier.FichierDossierFTP()


InitNetwork()
If OpenFTP(0, "ftpperso.free.fr", "LOGIN", "MDP") ;------------- A REMPLIR
    
    ; DOSSIERS
    If ExamineFTPDirectory(0)
        
        While NextFTPDirectoryEntry(0)
            
            If FTPDirectoryEntryType(0) = 2
                If FTPDirectoryEntryName(0) <> "."
                    Debug "Dossier :" + FTPDirectoryEntryName(0)
                    ;Debug FTPDirectoryEntryType(0)
                    AddElement(NomDossier())
                    NomDossier()\Nom$ = FTPDirectoryEntryName(0)
                EndIf
            EndIf
            
        Wend
        
    EndIf  
    
    ; FICHIERS
    If ExamineFTPDirectory(0)
        
        While NextFTPDirectoryEntry(0)
            
            If FTPDirectoryEntryType(0) = 1
                Debug "Fichier :" + FTPDirectoryEntryName(0)
                Debug FTPDirectoryEntrySize(0)
                ;Debug FTPDirectoryEntryType(0)
                AddElement(NomFichier())
                NomFichier()\Nom$ = FTPDirectoryEntryName(0)
                NomFichier()\Taille = FTPDirectoryEntrySize(0)
            EndIf
            
        Wend
        
    EndIf  
    
    
    Debug "----------"
    Debug "---------- TRIéS"
    Debug "----------"
    
    SortStructuredList(NomDossier(), #PB_Sort_Ascending, OffsetOf(FichierDossierFTP\Nom$), #PB_Sort_String)
    
    ForEach NomDossier()
        Debug "Dossier : " + NomDossier()\Nom$ 
    Next 
    
    
    SortStructuredList(NomFichier(), #PB_Sort_Ascending, OffsetOf(FichierDossierFTP\Nom$), #PB_Sort_String)
    
    ForEach NomFichier()
        Debug "Fichier : " + NomFichier()\Nom$ + " ----- Taille : " + Str(NomFichier()\Taille) 
    Next    
    
    CloseFTP(0)
    
Else
    MessageRequester("Avertissement", "Connexion impossible")
EndIf

Bye.

[kerkael]

FORMIDABLE !

Exactement ce que je cherchais.

C'est bizarre, quand dans le forum je recherche ftp : pas de résultat.
Si je recherche http, je trouve bien tous les sujets qui en parlent. D'où ma confusion sur l'absence de sujet mentionnant cela.

Un problème dans le moteur de recherche, peut-être ?

Bon, mon problème est résolu grâce à vous deux.

Merci

[Ar-S]

Un problème dans le moteur de recherche, peut-être ?

ba disons que le moteur phpbb a pas mal de lacunes