What is the fastest way of cheking if a file exists?

[Joakim Christiansen]

What is the fastest way of cheking if a file exists?
I currently use this: If FileSize(File) > 0

[travismcgee]

Here's a line from one of my programs, dunno if you'll like it or not:

Code: Select all

If ExamineDirectory(0,GetCurrentDirectory(),"Sqlite3.dll") = 0
  ; it isn't there, handle condition
Else
  ; it is there, handle condition
Endif

I have no idea how fast it is.

[Phoenix]

What is the fastest way of cheking if a file exists?
I currently use this: If FileSize(File) > 0

Better check for >-1 because a file can be a size of 0 bytes........

[travismcgee]

Yes, the way you're already doing it is probably better than what I got. And as the docs say that a return value of -1 means file not found, it seems like the best approach (with phoenix's note applied).

[gnozal]

Windows only but fast.

Code: Select all

Procedure FileExists(FileName.s) 
  Protected Result.l, Find.WIN32_FIND_DATA 
  Result = FindFirstFile_(@FileName, Find) 
  FindClose_(Result) 
  If Result <> #INVALID_HANDLE_VALUE 
    ProcedureReturn #True 
  EndIf 
  ProcedureReturn #False 
EndProcedure

[Fred]

FileSize() does exactly that so it should be the fastest way.

[bingo]

Code: Select all

Import "ntdll.lib"
RtlDoesFileExists_U(file.p-unicode)
EndImport

Debug RtlDoesFileExists_U("c:\your.file")

... the fastest way (xp/vista)

[Rescator]

Yeah, but that one is not documented in the PSDK and not guaranteed to exist in the future at all or OS variants. Use with caution.

[Fluid Byte]

Actually it's not documented anywhere. Only found 591 sites on Google wich is very rare and the over the half is in related to ReactOS and Wine.

[Rescator]

http://en.wikipedia.org/wiki/Heavy_wizardry

[PB]

Maybe this is fastest?

Code: Select all

Debug PathFileExists_("c:\program files\internet explorer\iexplore.exe")
Debug PathFileExists_("c:\program files\internet explorer\iexplore.exee")

[Shardik]

Yeah, but that one is not documented in the PSDK and not guaranteed to exist in the future at all or OS variants. Use with caution.

That's correct. Nevertheless bingo's code even works with WinNT4 SP6...

[RichardL]

I wrote and have used this for many years and it has never thrown a wobbly... Windoze only.

Code: Select all

Procedure.l Exist(File$)                               ;- Check a drive + file exists, without system requesters etc.
  ; Check if a drive or drive+file exists
  ; Return -1 if exists, else 0
  ; *** Never *** displays a system error even if device is missing
  ; such as a multi card interface with no cards plugged in.
  
  Protected EFlag.l, OldErrorMode.l, Junk.l
  
  OldErrorMode = SetErrorMode_(1)   ; Turn off screen error messages
  If GetFileAttributes_(@File$)=-1  ; Get file butes. -1 = fail
    Junk.l=GetLastError_()          ; Get last error, to flush system
    SetLastError_(0)                ; Set error to zero
    EFlag.l = 0                     ; Return value to flag FAIL
  Else
    EFlag.l = -1                    ; Return value to flag a PASS
  EndIf
  SetErrorMode_(OldErrorMode)       ; Reset the error flags
  ProcedureReturn EFlag
EndProcedure