PureBoard

Code: Alles auswählen

System:
  Kernel: 6.8.0-85-generic arch: x86_64 bits: 64 compiler: gcc v: 13.3.0 clocksource: tsc
  Desktop: Cinnamon v: 6.4.8 tk: GTK v: 3.24.41 wm: Muffin v: 6.4.1 vt: 7 dm: LightDM v: 1.30.0
    Distro: Linux Mint 22.2 Zara base: Ubuntu 24.04 noble
    
Zuerst - wie in der Anleitung im Home-Ordner das Verzeichnis Apps erstellt.
Hierher den entpackten Ordner hineinkopiert.
Dieser heisst bei mir "purebasic".

Installation (Install) via Terminal das zweite mal abgearbeitet. Bedeutet, das einige Dinge bereits installiert wurden.
Erste Aktion:

sudo apt-get install build-essential gcc g++

Ausgabe im Terminal, das gcc und g++ bereits in der neusten Version vorhanden sind. Soweit alles gut.
Dann: 

sudo apt-get install libxxf86vm-dev libxine2-dev unixodbc-dev libsdl1.2-dev libsdl2-dev libssl-dev libvlc-dev libgtk2.0-dev libgtk-3-dev

Auch hier ist alles installiert und auf dem neusten Stand.

Jetzt die nächste Zeile

sudo apt-get install libwebkit2gtk-4.1-dev

Alles OK. Ist die neuste Version installiert.

Jetzt sind die developer Librarys dran und hier kommt der erste Fehler:

sudo apt-get install libgl1-mesa-dev libgl1-mesa-glx

Ausgabe im Terminal:
Paket libgl1-mesa-glx ist nicht verfügbar, wird aber von einem anderen Paket
referenziert. Das kann heißen, dass das Paket fehlt, dass es abgelöst
wurde oder nur aus einer anderen Quelle verfügbar ist.

E: Für Paket »libgl1-mesa-glx« existiert kein Installationskandidat.

Auch das Subsystem QT gibt einen ähnlichen Fehler aus:

sudo apt-get install qt5-default qtbase5-dev qttools5-dev qtmultimedia5-dev qtdeclarative5-dev libqt5svg5-dev libqt5webkit5-dev libqt5multimedia5-plugins

Ausgabe:
Paket qt5-default ist nicht verfügbar, wird aber von einem anderen Paket
referenziert. Das kann heißen, dass das Paket fehlt, dass es abgelöst
wurde oder nur aus einer anderen Quelle verfügbar ist.

E: Für Paket »qt5-default« existiert kein Installationskandidat.

Weiter mit Canberra for PB-IDE:

sudo apt install libcanberra-gtk-module

Hier wieder alles OK. Ist die neuste Version drauf.

Weiter mit gtk2:

sudo apt-get install libgtk2.0

Hier installiert er einen Rattenschwanz an Dateien ohne jede Fehlermeldung. Ist dann wohl alles klar.
Weiter mit gtk3:

sudo apt-get install libwebkitgtk-3.0

Hier ist auch alles auf dem neusten Stand.

Jetzt kommt qt:

sudo apt install qt5-default

Ausgabe:
Paket qt5-default ist nicht verfügbar, wird aber von einem anderen Paket
referenziert. Das kann heißen, dass das Paket fehlt, dass es abgelöst
wurde oder nur aus einer anderen Quelle verfügbar ist.

E: Für Paket »qt5-default« existiert kein Installationskandidat.

Zum Schluß hab ich dann noch versucht, das Desktopicon, wie angegeben zu erstellen.
Habe dazu mit dem GEdit die Datei purebasic.desktop auf dem Desktop erstellt und registriert.
Inhalt der Datei:

#!/usr/bin/env xdg-open
[Desktop Entry]
    Type=Application
    Icon=/home/username/Apps/purebasic/logo.png
    Name=Purebasic
    Comment=Developer Utility
    Exec=/home/thommes/Apps/purebasic/compilers/purebasic
    Path=/home/thommes/Apps/purebasic/compilers
    StartupNotify=false
    Terminal=false 

Code: Alles auswählen

;-TOP

#ProgramTitle = "Create PureBasic Desktop File"
#ProgramVersion = "v1.01.2 by mk-soft"

Enumeration Windows
  #Main
EndEnumeration

Enumeration MenuBar
  #MainMenu
EndEnumeration

Enumeration MenuItems
  #MainMenuAbout
  #MainMenuExit
EndEnumeration

Enumeration Gadgets
  #MainList
  #MainButtonSave
EndEnumeration

Enumeration StatusBar
  #MainStatusBar
EndEnumeration

; ----

Macro AddElementValue(List, Value)
  AddElement(List) : List = Value
EndMacro

Global NewList Rows.s()

Procedure CreateDesktopFile()
  Protected Name.s
  
  Name = "PureBasic v" + Str(#PB_Compiler_Version / 100) + "." + LSet(Str(#PB_Compiler_Version % 100), 2, "0")
  
  AddElementValue(Rows(), "[Desktop Entry]")
  AddElementValue(Rows(), "Type=Application")
  AddElementValue(Rows(), "Icon=" + #PB_Compiler_Home + "logo.png")
  AddElementValue(Rows(), "Name=" + Name + " (gtk3)")
  AddElementValue(Rows(), "Comment=Developer Utility")
  AddElementValue(Rows(), "Exec=" + #PB_Compiler_Home + "compilers/purebasic")
  AddElementValue(Rows(), "Path=" + #PB_Compiler_Home + "compilers")
  AddElementValue(Rows(), "StartupNotify=false")
  AddElementValue(Rows(), "Terminal=false")
  AddElementValue(Rows(), "Categories=Development")
  
  ForEach Rows()
    AddGadgetItem(#MainList, -1, Rows())
  Next

EndProcedure

Procedure SaveDesktopFile()
  Protected path.s, filename.s, file.s
  
  path = "/home/" + UserName() + "/.local/share/applications/"
  If FileSize(path) <> -2
    r1 = MessageRequester("Warning", "Path not exists. Create Path ?" + #LF$ + path, #PB_MessageRequester_Warning | #PB_MessageRequester_YesNo)
    If r1 <> #PB_MessageRequester_Yes
      ProcedureReturn 0
    EndIf
    If Not CreateDirectory(RTrim(path, "/"))
      r1 = MessageRequester("Error", "Create Path " + path, #PB_MessageRequester_Warning | #PB_MessageRequester_YesNo)
      ProcedureReturn 0
    EndIf
  EndIf
  filename = path + "purebasic-v" + LSet(Str(#PB_Compiler_Version), 3, "0") + ".desktop"
  
  file = SaveFileRequester("Save Desktop File", filename, "", 0)
  If file
    If CreateFile(0, file)
      ForEach Rows()
        WriteStringN(0, Rows())
      Next
      CloseFile(0)
    Else
      MessageRequester("Error", "File Not Saved!", #PB_MessageRequester_Error)
    EndIf
  EndIf
EndProcedure

; ----

Procedure UpdateWindow()
  Protected dx, dy
  dx = WindowWidth(#Main)
  dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
  ; Resize gadgets
  ResizeGadget(#MainList, 5, 5, dx - 10, dy - 45)
  ResizeGadget(#MainButtonSave, dx - 130, dy - 35, 120, 30)
EndProcedure

Procedure Main()
  Protected dx, dy
  
  #MainStyle = #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
  
  If OpenWindow(#Main, #PB_Ignore, #PB_Ignore, 800, 600, #ProgramTitle , #MainStyle)
    ; Menu
    CreateMenu(#MainMenu, WindowID(#Main))
    MenuTitle("&File")
    MenuItem(#MainMenuAbout, "About")
    MenuBar()
    MenuItem(#MainMenuExit, "E&xit")
    
    ; StatusBar
    CreateStatusBar(#MainStatusBar, WindowID(#Main))
    AddStatusBarField(#PB_Ignore)
    
    ; Gadgets
    dx = WindowWidth(#Main)
    dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
    ListViewGadget(#MainList, 5, 5, dx -10, dy - 45)
    ButtonGadget(#MainButtonSave, dx - 130, dy - 35, 120, 30, "Save")
    
    ; Bind Events
    BindEvent(#PB_Event_SizeWindow, @UpdateWindow(), #Main)
    
    CreateDesktopFile()
    
    ; Event Loop
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Select EventWindow()
            Case #Main
              Break
              
          EndSelect
          
        Case #PB_Event_Menu
          Select EventMenu()
            Case #MainMenuAbout
              MessageRequester("About", #ProgramTitle + #LF$ + #ProgramVersion, #PB_MessageRequester_Info)
                
            Case #MainMenuExit
              PostEvent(#PB_Event_CloseWindow, #Main, #Null)
              
          EndSelect
          
        Case #PB_Event_Gadget
          Select EventGadget()
            Case #MainList
              Select EventType()
                Case #PB_EventType_Change
                  ;
                  
              EndSelect
              
            Case #MainButtonSave
              SaveDesktopFile()
              
          EndSelect
          
      EndSelect
    ForEver
    
  EndIf
  
EndProcedure : Main()