PureBoard

Verfasst: **30.12.2023 07:43**

Morning,

ich habe ResizeImage schon so oft benutzt aber irgendwie will das nicht funktionieren da ich
nicht mehr so ganz im Bilde zu sein scheine

Kurzer Code der doch eigentlich ausreichen sollte?

Code: Alles auswählen

 
ContainerGadget(#Cnt_GameCover, WindowWidth(#Main) -310, 30, 300, 300, #PB_Container_BorderLess)
;Ich catche das Bild:
       ImageGadget(#Img_GameCover, 0, 0, 300, 300, CatchImage(#Img_CanvasGameCover, ?Img_CanvasGameCover))
;es soll verkleinert werden, und dann später immer mittig im Container:
      ResizeImage(#Img_CanvasGameCover, 200, 200, #PB_Image_Smooth)
CloseGadgetList()

Das Bild zeigt es nicht an. Nur wenn ich bei Resize auch 300x300 angebe.

Verfasst: **30.12.2023 12:29**

Steht in der ResizeImage()-Hilfe

Diese Funktion verändert das Handle des benutzten Bildes. Es muss deshalb z.B. einem ImageGadget() mittels SetGadgetState() neu zugewiesen werden.

Verfasst: **31.12.2023 11:32**

Hoi,

danke Dir. Ich habe es dank deines Denkanstoßes wieder gebacken bekommen.

Allgemein:

warum reicht es nicht anzugeben:

- lade aus Memory das Bild in ein Gadget, zb: #Bild
und rufe einfach nur auf:
- ResizeImage(#Bild, 200,200)
?

Warum ist dieser einfache Weg nicht möglich als das ich angeben muss:

Code: Alles auswählen

SetGadgetState(#Img_GameCover,ResizeImage(#Img_CanvasGameCover, 300, 300, #PB_Image_Smooth))

Das könnte man doch stark vereinfachen?

Programmiere ich zB. in C für die PlayStation 1 und möchte eine Grafik in ihrer Größe verändern gebe ich nur an:

tSprite->scalex = tSprite->scaley = ONE; --> fertig

oder kleinere Wert / größerer Wert

Grüße und danke noch mal,

Guten Rutsch an Alle... Feiert schön

Verfasst: **31.12.2023 14:48**

Du kannst dir so eine Funktion ratzfatz selbst zusammenklampfen.

Verfasst: **31.12.2023 15:19**

Bei mehrfach Größenänderung sollte man immer eine Kopie vom Image nehmen.

Code: Alles auswählen

;-TOP

#ProgramTitle = "Main Window"
#ProgramVersion = "v1.01.2"

Enumeration Windows
  #Main
EndEnumeration

Enumeration MenuBar
  #MainMenu
EndEnumeration

Enumeration MenuItems
  #MainMenuAbout
  #MainMenuExit
EndEnumeration

Enumeration Gadgets
  #MainImage
EndEnumeration

Enumeration StatusBar
  #MainStatusBar
EndEnumeration

UsePNGImageDecoder()
UseJPEGImageDecoder()

Procedure UpdateImageGadget(Gadget, Image)
  Protected last_image, dx, dy
  last_image = GetGadgetData(gadget)
  If last_image
    FreeImage(last_image)
  EndIf
  last_image = CopyImage(Image, #PB_Any)
  dx = GadgetWidth(Gadget)
  dy = GadgetHeight(Gadget)
  ResizeImage(last_image, dx, dy)
  SetGadgetState(Gadget, ImageID(last_image))
  SetGadgetData(Gadget, last_image)
EndProcedure

Procedure UpdateWindow()
  Protected dx, dy
  dx = WindowWidth(#Main)
  dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
  ; Resize gadgets
  ResizeGadget(#MainImage, 0, 0, dx, dy)
  UpdateImageGadget(#MainImage, 0)
EndProcedure

Procedure Main()
  Protected dx, dy, imagefile.s
  
  imagefile.s = OpenFileRequester("Image", "", "", 0)
  If imagefile
    If Not LoadImage(0, imagefile)
      Debug "Error load image " + imagefile
      End
    EndIf
  Else
    End
  EndIf
  
  #MainStyle = #PB_Window_SystemMenu | #PB_Window_SizeGadget | #PB_Window_MaximizeGadget | #PB_Window_MinimizeGadget
  
  If OpenWindow(#Main, #PB_Ignore, #PB_Ignore, 800, 600, #ProgramTitle , #MainStyle)
    ; Menu
    CreateMenu(#MainMenu, WindowID(#Main))
    MenuTitle("&File")
    CompilerIf #PB_Compiler_OS = #PB_OS_MacOS
      MenuItem(#PB_Menu_About, "")
    CompilerElse
      MenuItem(#MainMenuAbout, "About")
    CompilerEndIf
    ; Menu File Items
    
    CompilerIf Not #PB_Compiler_OS = #PB_OS_MacOS
      MenuBar()
      MenuItem(#MainMenuExit, "E&xit")
    CompilerEndIf
    
    ; StatusBar
    CreateStatusBar(#MainStatusBar, WindowID(#Main))
    AddStatusBarField(#PB_Ignore)
    
    ; Gadgets
    dx = WindowWidth(#Main)
    dy = WindowHeight(#Main) - StatusBarHeight(#MainStatusBar) - MenuHeight()
    ImageGadget(#MainImage, 0, 0, dx, dy, 0)
    UpdateImageGadget(#MainImage, 0)
    
    ; Bind Events
    BindEvent(#PB_Event_SizeWindow, @UpdateWindow(), #Main)
    
    ; Event Loop
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_CloseWindow
          Select EventWindow()
            Case #Main
              Break
              
          EndSelect
          
        Case #PB_Event_Menu
          Select EventMenu()
            CompilerIf #PB_Compiler_OS = #PB_OS_MacOS   
              Case #PB_Menu_About
                PostEvent(#PB_Event_Menu, #Main, #MainMenuAbout)
                
              Case #PB_Menu_Preferences
                
              Case #PB_Menu_Quit
                PostEvent(#PB_Event_CloseWindow, #Main, #Null)
                
            CompilerEndIf
            
          Case #MainMenuAbout
            MessageRequester("About", #ProgramTitle + #LF$ + #ProgramVersion, #PB_MessageRequester_Info)
              
          Case #MainMenuExit
            PostEvent(#PB_Event_CloseWindow, #Main, #Null)
            
          EndSelect
          
        Case #PB_Event_Gadget
          Select EventGadget()
              
          EndSelect
          
      EndSelect
    ForEver
    
  EndIf
  
  ; Free resources
  If GetGadgetData(0)
    FreeImage(GetGadgetData(0))
  EndIf
  
EndProcedure : Main()

PureBoard

ResizeImage Frage

ResizeImage Frage

Re: ResizeImage Frage

Re: ResizeImage Frage

Re: ResizeImage Frage

Re: ResizeImage Frage