PureBoard

Das deutsche PureBasic-Forum
https://www.purebasic.fr/german/

Dateierkennung ohne Dateikennung?

https://www.purebasic.fr/german/viewtopic.php?t=32876

Seite 1 von 1

Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 08:15
von Micro
Moin :)

wie kann man eigendlich herausfinden, um welchen Dateityp es sich handelt?

Bsp:
Anstatt des kompletten Dateinahmen "Bsp vom 03.01.2023.pdf" heißt die Datei "Bsp vom 03.01.2023".
Hier ist die Dateiendung ".pdf" einfach nicht mehr vorhanden, die neue Dateiendung ist also ".2023".

Bei PDF-Dateien würde das ja einfach sein, aber wie würde das JPG-Dateien funktionieren?

Hier mal das, was ich mir überlegt hatte:

Code: Alles auswählen

Global nummer.l = 1
If ExamineDirectory(0, "C:\Temp\", "")  
  While NextDirectoryEntry(0)
    If DirectoryEntryType(0) = #PB_DirectoryEntry_File
      Debug "x - " + DirectoryEntryName(0)
      If ReadFile(0,  DirectoryEntryName(0))
        *MemoryID = AllocateMemory(1000)
        If *MemoryID
          bytes = ReadData(0, *MemoryID, 1000)  ; einlesen 1000 Zeichen der Datei
                                               ; Debug DirectoryEntryName(0) + " --- " + PeekS(*MemoryID, -1, #PB_Ascii)
          If FindString(PeekS(*MemoryID, -1, #PB_Ascii), "%PDF")
            Debug Str(nummer.l) + " PDF - " + DirectoryEntryName(0)
          nummer.l = nummer.l + 1
          EndIf
          
          If FindString(PeekS(*MemoryID, -1, #PB_Ascii), "ÿØÿà")
            Debug Str(nummer.l) + " JPG - " + DirectoryEntryName(0)
          nummer.l = nummer.l + 1
          EndIf
                              
          ; Debug "xxx - " + DirectoryEntryName(0)
          
        EndIf
        
        CloseFile(0)
        FreeMemory(*MemoryID)
      EndIf
    EndIf
  Wend
  FinishDirectory(0)
  Debug "-----------------------"
  
EndIf
Keine Ahnung, ob das der richtige Ansatz ist...

Hab da auch noch eine Frage zu PeekS:
In der Hilfe steht bei der Länge was von einen abschließendes Null-Zeichen. Was ist damit gemeint?

Gruß Frank

Re: Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 08:30
von jacdelad
Bei einem JPEG könntest du prüfen, ob es sich laden lässt. Dann findet aber keine Unterscheidung zwischen JPEG und anderen, unterstützten Bildformaten statt. Wenn es genau JPEG sein soll, dann musst du mal einen Blick in die offizielle Dokumentation werfen, dort findest du auch die magische Zahl.

Außerdem gab es mal so eine DLL, die zig Formate erkennen konnte. War aber nur 32 Bit und ich kann mich weder an den Namen erinnern, noch ob sie noch weiterentwickelt wird (vermutlich nicht). Google könnte dir da helfen.

Zu PeekS: PeekS sucht einen String in einem Speicherbereich. Strings werden in PureBasic immer durch ein 0-Zeichen abgeschlossen (also nicht "0" sondern Chr(0)). Deshalb erwartet PeekS am Ende des zu lesenden Strings eben jenes Chr(0).
Das ist übrigens auch der Grund, weshalb sich Strings nur für die Speicherung von Strings eignen und Verschlüsselungen immer in Speicherbereichen stattfinden sollten (es sei denn, es kommen wieder reine Strings raus).

Re: Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 08:46
von NicTheQuick
Schau dir mal das hier an: https://www.ibm.com/docs/en/zos/2.2.0?t ... magic-file
Oder das: http://www.fibel.org/linux/lfo-0.6.0/node76.html
Damit erkennt zum Beispiel Linux um welchen Dateityp es sich handelt. Linux schert sich allgemein nicht um Dateiendungen.

Re: Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 09:55
von tft
Moin.

Als es noch keine Datei Endungen gab. Wurden meistens die ersten 4 Byte einer Datei zur Erkennung des Datei Type verwendet.
Ich dachte eigentlich das sich das nicht geändert hat. Und der Suffix im Dateiname ist nur zum Komfort eingeführt worden. Um
von aussen zu sehen um was es sich für eine Datei handelt. Wenn ich mich irre ... sorry

Gruss TFT

Re: Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 10:00
von NicTheQuick
tft hat geschrieben: 03.01.2023 09:55 Als es noch keine Datei Endungen gab. Wurden meistens die ersten 4 Byte einer Datei zur Erkennung des Datei Type verwendet.
Ich dachte eigentlich das sich das nicht geändert hat. Und der Suffix im Dateiname ist nur zum Komfort eingeführt worden. Um
Das klappt so immer noch mit vielen Dateitypen, aber lange nicht mehr mit allen. Ich glaube das fängt schon bei MP3s an. Die sind besonders doof konstruiert um sie erkennen zu können und damit bestimmt auch nicht die einzigen.

Re: Dateierkennung ohne Dateikennung?

Verfasst: 03.01.2023 17:46
von Axolotl
Das Problem ist ja schon bei einfachen Textdateien gegeben...
Ich habe mal ein Versuch anhand der ersten Bytes einer Datei die Extension zu erkennen gebastelt.
Einfach eine oder mehrere Dateien aus dem Explorer auf das ListiconGadget droppen.
Die Extensions die das Progrämmchen erkennt stehen in der Enumeration....

Code: Alles auswählen

; License   : Free, unrestricted, no warranty whatsoever - Use at your own risk 
;           : Copyright (c) 2023 by A.H. (Axolotl)  
EnableExplicit 

Enumeration EFileExtention  
  #FileExtention_NONE  ; Unknown file extention 
  #FileExtention_BMP   
  #FileExtention_JPEG  
  #FileExtention_PDF   
  #FileExtention_ZIP   
  #FileExtention_7z   
  #FileExtention_WAV  
  #FileExtention_EXE 
EndEnumeration 

Structure TExtension 
  Marker.i  
  Name$ 
  EnumValue.i 
EndStructure 

; --- Constants --------------------------------------------------------------- 

#MARKER_MASK                   = $FFFFFFFF 
#ExtensionTableMaxEntry        = 6  ; set to the number of entries 

Global Dim ExtensionTable.TExtension(#ExtensionTableMaxEntry)  

; -----------------------------------------------------------------------------

Macro SetExtensionTableEntry(_Name_, _Marker_, _Value_) 
  ExtensionTable(Index)\Name$ = _Name_ 
  ExtensionTable(Index)\Marker = _Marker_
  ExtensionTable(Index)\EnumValue = _Value_
EndMacro 

; -----------------------------------------------------------------------------

Procedure InitExtensionTable() 
  Protected Index 
  
  SetExtensionTableEntry("BMP",  $E10364D42,        #FileExtention_BMP)  : Index + 1 
  SetExtensionTableEntry("JPEG", $464A1000E0FFD8FF, #FileExtention_JPEG) : Index + 1 
  SetExtensionTableEntry("PDF",  $362E312D46445025, #FileExtention_PDF)  : Index + 1 
  SetExtensionTableEntry("ZIP",  $2001404034B50,    #FileExtention_ZIP)  : Index + 1 
  SetExtensionTableEntry("7z",   $2001C27AFBC7A37,  #FileExtention_7z)   : Index + 1 
  SetExtensionTableEntry("WAV",  $6EE8446464952,    #FileExtention_WAV)  : Index + 1 
  SetExtensionTableEntry("EXE",  $300905A4D,        #FileExtention_EXE)  : Index + 1 

; ReDim ExtensionTable(Index - 1) 
; Debug "INTERNAL INFO: ReDim Table to " + Str(Index - 1) 
EndProcedure 

InitExtensionTable() 
UndefineMacro SetExtensionTableEntry 

; -----------------------------------------------------------------------------

Procedure.i CheckOnFile(Gadget, FileName$)  ; 
  Protected FILE, marker, index, count 

  FILE = ReadFile(#PB_Any, FileName$) ; read with no flags 
  If FILE 
    marker = ReadInteger(FILE) 
    CloseFile(FILE) 
  EndIf 

  If marker <> 0  ; found something valid 
    Debug "Marker == $" + Hex(marker, #PB_Quad)  ; <= need this for new identified extentions 
    AddGadgetItem(Gadget, -1, FileName$ + #LF$ + #LF$ + "$" + Hex(marker, #PB_Quad)) 

    Count = ArraySize(ExtensionTable()) 
    For index = 0 To Count 
      If (marker & #MARKER_MASK) = (ExtensionTable(index)\Marker & #MARKER_MASK) 
        SetGadgetItemText(Gadget, CountGadgetItems(Gadget)-1, ExtensionTable(index)\Name$, 1) 
        ProcedureReturn ExtensionTable(index)\EnumValue 
      EndIf 
    Next index 
  EndIf 
  ProcedureReturn #FileExtention_NONE 
EndProcedure 

; -----------------------------------------------------------------------------

Procedure main() 
  Protected files$, ii, cnt  

  If OpenWindow(0, 0, 0, 640, 480, "File Extention Detection Example...", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) 
    StickyWindow(0, 1) 
    ListIconGadget(1, 4, 4, 632, 472, "Filename", 432) 
    AddGadgetColumn(1, 1, "Ext", 64) 
    AddGadgetColumn(1, 2, "Marker", 128) 
    EnableGadgetDrop(1, #PB_Drop_Files, #PB_Drag_Copy) 

    Repeat
      Select WaitWindowEvent() 
        Case #PB_Event_CloseWindow
          Break ; say good bye  
     
        Case #PB_Event_GadgetDrop 
          If EventDropType() = #PB_Drop_Files 
            files$ = EventDropFiles() 
            If files$ 
              cnt = CountString(files$, #LF$) + 1 
              For ii = 1 To cnt 
                CheckOnFile(1, StringField(files$, ii, #LF$)) 
              Next ii 
            EndIf 
          EndIf 
      EndSelect
    ForEver 
  EndIf 
  ProcedureReturn 0 
EndProcedure 

End main()

Re: Dateierkennung ohne Dateikennung?

Verfasst: 05.01.2023 00:20
von SMaag
https://en.wikipedia.org/wiki/List_of_file_signatures

https://www.garykessler.net/library/file_sigs.html
Alle Zeiten sind UTC+02:00
Seite 1 von 1

Powered by phpBB® Forum Software © phpBB Limited

Deutsche Übersetzung durch phpBB.de