PureBoard

Code: Alles auswählen

  ; Um auf ein externes Objekt (in einer DLL zum Beispiel) zugreifen zu
  ; können, muss zuerst das Objekt-Interface deklariert werden:
  ;
  Interface MyObject
    Move(x,y)
    MoveF(x.f,y.f)
    Destroy()
  EndInterface
  
  ; CreateObject ist die Funktion, welche das Objekt (aus der DLL) erstellt,
  ; dessen Interface gerade definiert wurde.
  ; Erstelle das erste Objekt...
  ;
  Object1.MyObject = MyCreateObject()
  
  ; Und das zweite.
  ;
  Object2.MyObject = MyCreateObject()
  
  ; Dann können die gerade definierten Funktionen verwendet werden,
  ; um auf das gewünschte Objekt zuzugreifen.
  ;
  Object1\Move(10, 20)
  Object1\Destroy()
  
  Object2\MoveF(10.5, 20.1)
  Object2\Destroy()

Code: Alles auswählen

Object1.MyObject = MyCreateObject()

Code: Alles auswählen

Object1.MyObject = CreateObject()

Code: Alles auswählen

;- Interface

Structure VectorBuffer ; Struktur welche den Methodenpointer und Eigenschaften enthält
	*Methods
	X.f
	Y.f
EndStructure

Interface Vector ; Interface welches später genutzt werden kann
	Set(X.f, Y.f)
	Get.s()
	Length.f()
	Add(*Vector)
	Free()
EndInterface

;- Medoden

Procedure Vector_Set(*This.VectorBuffer, X.f, Y.f)
	*This\X = X
	*This\Y = Y
	ProcedureReturn *This
EndProcedure

Procedure.f Vector_Length(*This.VectorBuffer)
	ProcedureReturn Sqr(*This\X**This\X+*This\Y**This\Y)
EndProcedure

Procedure.s Vector_Get(*This.VectorBuffer)
	ProcedureReturn StrF(*This\X)+" , "+StrF(*This\Y)
EndProcedure

Procedure.i Vector_Add(*This.VectorBuffer, *Vector.VectorBuffer)
	*This\X + *Vector\X
	*This\Y + *Vector\Y
	ProcedureReturn *This
EndProcedure

Procedure.i Vector_Free(*This.VectorBuffer)
	FreeStructure(*This)
	ProcedureReturn #Null
EndProcedure

Procedure.i NewVector()
	Protected *This.VectorBuffer = AllocateStructure(VectorBuffer) ; Buffer für die Struktur erzeugen und Methodenpointer setzen
	*This\Methods = ?Vector_Methods
	; Ggf. andere Strukturfelder setzen
	ProcedureReturn *This
EndProcedure


;- Beispiel

Define A.Vector = NewVector()
Define B.Vector = NewVector()

A\Set(4, 3)
Debug A\Length()

B\Set(-1, 2)
A\Add(B)
Debug A\Get()


DataSection
	Vector_Methods:
	Data.i @Vector_Set()
	Data.i @Vector_Get()
	Data.i @Vector_Length()
	Data.i @Vector_Add()
	Data.i @Vector_Free()
EndDataSection