PureBoard

Verfasst: **06.09.2020 12:34**

Zurzeit versuche ich, von VB auf Pure-Basic umzusteigen. Hierbei versuche ich, mit dem Date-Gadget ein Datum zu erfassen.

Mit SetGadgetText kann ich das Datum im Eingabefeld des Gadgets auch setzen. Wenn ich danach den Kalender aufklappe und da ein anderes Datum anklicke, aktualisiert sich das Eingabefeld leider nicht und ich finde auch keine Funktion, mit der ich das hinkriege.

Für Profis wahrscheinlich eine Kleinigkeit.

Verfasst: **06.09.2020 13:32**

Das ist nicht ganz richtig.

Mit SetGadgetText wird nicht das Datum gesetzt, sondern das Format der Ausgabe.
Das Datum wird mit SetGadgetState geändert.

Siehe PB Hilfe.

Code: Alles auswählen

If OpenWindow(0, 0, 0, 300, 250, "DateGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  DateGadget(0, 10, 10, 280, 25, "Datum: %mm/%dd/%yyyy Time: %hh:%ii")
  
  ; Format ändert
  SetGadgetText(0, "%dd.%mm.%yyyy")
  
  ; Datum setzen
  SetGadgetState(0, Date(2020, 12, 24, 0, 0, 0))
  
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        Select EventWindow()
          Case 0
            Break
            
        EndSelect
        
      Case #PB_Event_Menu
        Select EventMenu()
            
        EndSelect
            
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 0
            Select EventType()
              Case #PB_EventType_Change
                Debug "Datum: " + GetGadgetText(0) + " Unix Timestamp: " + Str(GetGadgetState(0))
                
            EndSelect
            
        EndSelect
        
    EndSelect
  ForEver
  
EndIf

Verfasst: **06.09.2020 16:07**

So klappt's
vielen Dank.
Ich muss mich in die Denke von PB noch reinarbeiten.

BüNo

PureBoard

Date Gadget

Date Gadget

Re: Date Gadget

Re: Date Gadget