PureBoard

Verfasst: **17.02.2017 16:33**

Hallo zusammen,

ich experimentiere gerade mit der Möglichkeit eigene kleine Dialoge in PB zu erstellen.

Irgendwie bekomme ich die richtige Syntax für ButtonImage in der XML-Struktur nicht hin.
Einfache Buttons mit Text sind kein Problem.

Kann mir bitte mal jemand ein kleines Beispiel posten, denn aus dem Handbuch bzw. der Hilfe werde ich nicht so richtig schlau.

Danke.

Verfasst: **17.02.2017 17:06**

büddeschööön:

Code: Alles auswählen

EnableExplicit

UsePNGImageDecoder()

Runtime Enumeration
  #myButtonImage
EndEnumeration

Enumeration
  #XML
  #Dialog
EndEnumeration

Define sXML.s
Define myImage

sXML = "<window id='#PB_Any' name='test' text='...' minwidth='100' minheight='100' flags='#PB_Window_SystemMenu | #PB_Window_ScreenCentered '>" +
       "  <hbox>" +
       "    <buttonimage id='#myButtonImage' />" +
       "  </hbox>" +
       "</window>"

If ParseXML(#XML, sXML) And XMLStatus(#XML) = #PB_XML_Success
  
  If CreateDialog(#Dialog)
    
    If OpenXMLDialog(#Dialog, #Xml, "test", 100, 100)
      
      myImage = LoadImage(#PB_Any, #PB_Compiler_Home + "\Examples\Sources\Data\world.png")
      
      If myImage
        SetGadgetAttribute(#myButtonImage, #PB_Button_Image, ImageID(myImage))
      EndIf
      
      Repeat
      Until WaitWindowEvent() = #PB_Event_CloseWindow
      
    Else
      Debug "Dialog creation error: " + DialogError(#Dialog)
    EndIf
    
  EndIf
  
Else
  Debug "XML error on line " + XMLErrorLine(#Xml) + ": " + XMLError(#Xml)
EndIf

Grüße ... Peter

Verfasst: **17.02.2017 17:16**

merci!

Kann man die Tags zu den Gadgets irgendwo nachlesen? Ich hab sie im Handbuch nicht gefunden....

Verfasst: **17.02.2017 17:45**

fabulouspaul hat geschrieben:Kann man die Tags zu den Gadgets irgendwo nachlesen?

unter OpenXmlDialog() wirst Du fündig.

Grüße ... Peter

PureBoard

CreateDialog & ButtonImage

CreateDialog & ButtonImage

Re: CreateDialog & ButtonImage

Re: CreateDialog & ButtonImage

Re: CreateDialog & ButtonImage