PureBoard

Verfasst: **07.02.2015 23:00**

Ich habe ein Problem und weiss nich wie ich es lösen könnte. Bitte dieses mal keine API

Ich habe folgenden Code:

Define Event

If OpenWindow(0, 300, 250, 300, 250, "", #PB_Window_SystemMenu)
  StringGadget(0, 5, 5, 290, 25, "", 0)
  EditorGadget(1, 5, 35, 290, 75, 0)
  
  AddKeyboardShortcut(0, #PB_Shortcut_Return, 1)
  
  Repeat
    Event = WaitWindowEvent()
    If Event = #PB_Event_Menu
      Select EventMenu()
        Case 1
          If GetActiveGadget() = 0
            Debug "enter"
          EndIf
      EndSelect
    EndIf
  Until Event = #PB_Event_CloseWindow
EndIf

Ich kann in Stringgadget meine Enter Taste abfragen und darauf reagieren aber dafür
funktioniert Enter in Editorgadget nicht. Ich will aber das man Enter drücken kann. Ich
habe extra mit GetActiveGadget abgefragt ob es auch das Gadget is das ich mit Enter
abfragen möchte aber schein bar überschreibt AddKeyboardShortcut auch bei anderen
Gadgets. Mist geht das auch anders und habt ihr eine Lösung für den Tommy?

Verfasst: **07.02.2015 23:13**

Code: Alles auswählen

Define Event

If OpenWindow(0, 300, 250, 300, 250, "", #PB_Window_SystemMenu)
  StringGadget(0, 5, 5, 290, 25, "", 0)
  EditorGadget(1, 5, 35, 290, 75, 0)

  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow : Break
      Case #PB_Event_Gadget
        Select EventGadget()
          Case 0
            Select EventType()
              Case #PB_EventType_Focus
                AddKeyboardShortcut(0, #PB_Shortcut_Return, 1)
              Case #PB_EventType_LostFocus
                RemoveKeyboardShortcut(0, #PB_Shortcut_Return)
            EndSelect
        EndSelect
      Case #PB_Event_Menu
        Select EventMenu()
          Case 1
            Debug "Return"
        EndSelect
    EndSelect
  ForEver
EndIf

Verfasst: **07.02.2015 23:22**

Großes großes Dankeschön ts-soft

PureBoard

Taste für bestimmtes Gadget abfrage

Taste für bestimmtes Gadget abfrage

Re: Taste für bestimmtes Gadget abfrage

Re: Taste für bestimmtes Gadget abfrage