PureBoard

Verfasst: **16.08.2013 12:27**

Hi,

bin gerade am Rumspielen mit den neuen Funktionalitäten. Zum Beispiel:

DeclareModule MTest
  
EndDeclareModule
Module MTest
  
  Procedure EventHandler()
    
        Debug "OK"
    
  EndProcedure
  BindEvent(#PB_Event_Gadget, @EventHandler(), #PB_All, 0, #PB_EventType_Change)
EndModule
OpenWindow(0,0,0,140,200,"Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
ListIconGadget(0,0,0,120,180,"Name",85)

For i = 0 To 9
  AddGadgetItem(0, -1, "name " + Str(i))
Next

Repeat
  Event = WaitWindowEvent()
Until Event = #PB_Event_CloseWindow

Warum haut es mir denn da immer zwei Events beim Changen um die Ohren?

Gruß
Justin

Verfasst: **16.08.2013 12:59**

BindEvent kannst du nicht in dieser Form verwenden.
Siehe hier: PB 5.20 - BindEvent() doesn't work with #PB_All

Nutze hier bitte BindGadgetEvent().

Zu dem eigentlichen Problem: Da dieses Event im WaitWindowEvent()-Block nicht doppelt kommt, ist es wohl ein Bug.

Verfasst: **16.08.2013 13:11**

Alles klar. Das Problem tritt aber auch ganz unabhängig vom #PB_All auf, denn wenn ich das durch die entsprechenden Nummern ersetze ist es das selbe.

Code: Alles auswählen

BindEvent(#PB_Event_Gadget, @EventHandler(), 0, 0, #PB_EventType_Change)

Gibt das jemand ans englische Forum weiter?

Gruß
Justin

Verfasst: **16.08.2013 13:12**

Da wird bei einem Klick anscheinend erst einmal das aktuelle Element auf -1 gesetzt,
und dann erst auf den jeweiligen Eintrag. Also zwei Events.

Wenn man allerdings in der Mainloop des Fensters das Event abfragt wird nur eines gefeuert...

Beim WindowEvent() hat PB die Events ja mehr oder weniger gefiltert, und bei BindEvent ist
man ja sozusagen ungefiltert, daher behaupte ich mal das in der Filterung von PB das erste Event
unterdrückt wird. Im Callback allerdings ist es nach wie vor vorhanden.

Man kann sich (wenn das alles so zutrifft) sich behelfen mit :

Code: Alles auswählen

  Procedure EventHandler()
    If GetGadgetState(EventGadget()) > -1
      Debug "OK"
    EndIf
  EndProcedure

Womit man dann die "PB Filterung" wieder durchführt.

Anmerkung : Innerhalb eines Modules eine direkte Anweisung zu machen ist schlecht. (BindEvent())
Sollte man nun das Modul ans Ende stellen, was dann ?

Besser wäre also folgendes :

Code: Alles auswählen

DeclareModule MTest
  Declare Set()
EndDeclareModule
Module MTest
  Procedure EventHandler()
    If GetGadgetState(EventGadget()) > -1
      Debug "OK " + Str(GetGadgetState(EventGadget()))
    EndIf
  EndProcedure
  Procedure Set()
    BindEvent(#PB_Event_Gadget, @EventHandler(), #PB_All, 0, #PB_EventType_Change)
  EndProcedure
EndModule

OpenWindow(0,0,0,140,200,"Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
ListIconGadget(0,0,0,120,180,"Name",85)

MTest::Set()

For i = 0 To 9
  AddGadgetItem(0, -1, "name " + Str(i))
Next

Repeat
  Event = WaitWindowEvent()
  If Event = #PB_Event_Gadget
    If EventType() = #PB_EventType_Change 
      Debug "Normal " +Str(GetGadgetState(0))
    EndIf  
  EndIf  
Until Event = #PB_Event_CloseWindow

Verfasst: **16.08.2013 13:25**

Also das gilt bsp. auch für StringGadgets. Da kommen auch mehrere Event bei rüber - bei leftclick oder lostfocus.

Das ist sehr schade, denn eigentlich hatte ich vor, dass Modul so zu gestallten damit es mir in einer List vorliegende Gadgets selbstständig verwaltet, dass ich das in der normalen Loop machen kann weiß ich

Aber die Gadgets in der Liste sind auch variabel, somit kann ich BindGadgetEvent auch nicht verwenden, weil ich dor auf ein bestimmtest Gadget zugreife.

Sehr schade.

Gruß
Justin

Verfasst: **16.08.2013 13:28**

Noch besser wird es, wenn man die Bindung in einer Prozedur des Moduls festlegt. Dann kommen da 12 Ereignisse bei raus...

Gruß
Justin

Verfasst: **16.08.2013 13:34**

Dann probiers doch mal so ...
hier kommt nur wirklich ein "Debug" pro Aktion...

Code: Alles auswählen

DeclareModule MTest
  Declare Set(Gadget)
EndDeclareModule
Module MTest
  Procedure EventHandler()
    Select GadgetType(EventGadget()) 
      Case #PB_GadgetType_ListIcon
        If GetGadgetState(EventGadget()) > -1
          Debug "OK " + Str(GetGadgetState(EventGadget()))
        EndIf
      Case #PB_GadgetType_String
        Debug "Change on String"
    EndSelect
    
  EndProcedure
  Procedure Set(Gadget)
    BindGadgetEvent(Gadget, @EventHandler(), #PB_EventType_Change)
  EndProcedure
EndModule

OpenWindow(0,0,0,140,220,"Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
ListIconGadget(0,0,0,120,180,"Name",85)
StringGadget(1, 0, 185, 120, 20, "H")

For i=0 To 1
MTest::Set(i)
Next i

For i = 0 To 9
  AddGadgetItem(0, -1, "name " + Str(i))
Next

Repeat
  Event = WaitWindowEvent()
 
Until Event = #PB_Event_CloseWindow

Edit: Oder du erstellst dir eigene GadgetKreationen wie hier...

Code: Alles auswählen

DeclareModule MTest
  Declare myListIconGadget(Gadget, x, y, Width, Height, Title$, TitleWidth, Flags = -1)
  Declare myStringGadget(Gadget, x, y, Width, Height, Content$, Flags = -1)
EndDeclareModule
Module MTest
  
  EnableExplicit
  
  Procedure EventHandler()
    Select GadgetType(EventGadget()) 
      Case #PB_GadgetType_ListIcon
        If GetGadgetState(EventGadget()) > -1
          Debug "OK " + Str(GetGadgetState(EventGadget()))
        EndIf
      Case #PB_GadgetType_String
        Debug "Change on String"
    EndSelect
  EndProcedure
  Procedure myListIconGadget(Gadget, x, y, Width, Height, Title$, TitleWidth, Flags = -1)
    
    Protected Result, ID
    
    If Flags = -1
      Result = ListIconGadget(Gadget, x, y, Width, Height, Title$, TitleWidth)
    Else
      Result = ListIconGadget(Gadget, x, y, Width, Height, Title$, TitleWidth, Flags)
    EndIf
    If Gadget = #PB_Any : ID = Result : Else : ID = Gadget : EndIf
    
    If IsGadget(ID)
      BindGadgetEvent(ID, @EventHandler(), #PB_EventType_Change)
    EndIf
    
    ProcedureReturn Result
    
  EndProcedure
  Procedure myStringGadget(Gadget, x, y, Width, Height, Content$, Flags = -1)
    
    Protected Result, ID
    
    If Flags = -1
      Result = StringGadget(Gadget, x, y, Width, Height, Content$)
    Else
      Result = StringGadget(Gadget, x, y, Width, Height, Content$, Flags)
    EndIf
    If Gadget = #PB_Any : ID = Result : Else : ID = Gadget : EndIf
    
    If IsGadget(ID)
      BindGadgetEvent(ID, @EventHandler(), #PB_EventType_Change)
    EndIf
    
    ProcedureReturn Result
    
  EndProcedure
  
EndModule

OpenWindow(0,0,0,140,220,"Test", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

MTest::myListIconGadget(0,0,0,120,180,"Name",85)
MTest::myStringGadget(1, 0, 185, 120, 20, "H")

For i = 0 To 9
  AddGadgetItem(0, -1, "name " + Str(i))
Next

Repeat
  Event = WaitWindowEvent()
Until Event = #PB_Event_CloseWindow

Verfasst: **16.08.2013 15:46**

so,

also wenn ich den GadgetState auf > -1 prüfe, scheint es in der uhrsprünglichen Version zu funktionieren.

Ich danke euch für eure Teilnahme.

Aber vielleicht kann das jemand an entsprechender Stelle melden...

Gruß
Justin

PureBoard

BindEvent in Modulen [PB 5.20 Beta 10]

BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]

Re: BindEvent in Modulen [PB 5.20 Beta 10]