PureBoard

Code: Alles auswählen

ListIconGadget(#Listview_0, 320, 25, 90, 170,"User",50)
AddGadgetColumn(#Listview_0,1,"Ok?",30) 

AddGadgetItem(#Listview_0,-1,"Sabine"+Chr(10)+"ja")
AddGadgetItem(#Listview_0,-1,"Thomas"+Chr(10)+"nö") 

Code: Alles auswählen

;
; ------------------------------------------------------------
;
;   PureBasic - Gadget example file
;
;    (c) 2002 - Fantaisie Software
;
; ------------------------------------------------------------
;

#WindowWidth  = 450
#WindowHeight = 305

; Load our images.. 
;
LoadImage(0, "Data\Drive.bmp")
LoadImage(1, "Data\File.bmp")
LoadImage(2, "Data\PureBasic.bmp")
LoadImage(3, "Data\CdPlayer.ico")

CreatePopupMenu(0)
  MenuItem(0, "Popup !")

If OpenWindow(0, 100, 120, #WindowWidth, #WindowHeight, #PB_Window_SystemMenu | #PB_Window_MinimizeGadget, "PureBasic - Advanced Gadget Demonstration")

  If CreateGadgetList(WindowID())
    
    ListIconGadget(5, 170, 50, 265, 200, "Column 1", 131)
    AddGadgetColumn(5, 1, "Column 2", 300)
    AddGadgetColumn(5, 2, "Column 3", 80)
    
    TextGadget(4, 10, 16, 180, 24, "Please wait while initializing...")
    
    ProgressBarGadget(3, 10, 260, #WindowWidth-25, 20, 0, 100)
    
    ; Update the ProgressBar, just for fun !
    ;
    For k=0 To 100
      SetGadgetState(3, k)
      Delay(10)
    Next
    
    ImageGadget      (0, 200, 5, 0, 0, UseImage(2))
    ButtonImageGadget(1, 384, 5, 50, 36, UseImage(3))
    
    TreeGadget    (2,  10, 50, 150, 200)
    
  EndIf
  
  SetGadgetText(4, "Initialize Ok... Welcome !")
  
  ; Fill Up the Tree gadget with lot of entries (including the image)
  ;
  
  For k=0 To 10
    AddGadgetItem(2, 0, "General "+Str(k), UseImage(1))
    AddGadgetItem(2, 0, "ScreenMode", UseImage(1))
    OpenTreeGadgetNode()
      AddGadgetItem(2, 0, "640*480", UseImage(1))
      AddGadgetItem(2, 0, "800*600", UseImage(3))
      AddGadgetItem(2, 0, "1024*768", UseImage(1))
      AddGadgetItem(2, 0, "1600*1200", UseImage(1))
    CloseTreeGadgetNode()
    AddGadgetItem(2, 0, "Joystick", UseImage(1))
  Next
    
  ; Fill Up the ListIcon gadget. Notice than the column are separated by Chr(10) (NewLine) character
  ;
  For k=0 To 100
    AddGadgetItem(5, -1, "Element "+Str(k)+Chr(10)+"C 2"+Chr(10)+"Comment 3", UseImage(3))
  Next
  
  SetGadgetState(5, 8)
  
  Repeat
    EventID = WaitWindowEvent()

    If EventID = #PB_EventGadget
      
      Select EventGadgetID()
        Case 1
          MessageRequester("Information", "You did it !", 0)
      
        Case 2
          SetGadgetText(4, "Tree Gadget. Item selected: "+Str(GetGadgetState(2)))
          
          If EventType() = 2
            MessageRequester("Information", "Doubleclick: item"+Str(GetGadgetState(2))+", Text: "+GetGadgetText(2), 0)
          ElseIf EventType() = 1
            DisplayPopupMenu(0, WindowID())
          EndIf
          
        Case 5
          SetGadgetText(4, "ListIcon Gadget. Item selected: "+Str(GetGadgetState(5)))
          
          If EventType() = 2
            MessageRequester("Information", "Doubleclick: item"+Str(GetGadgetState(5))+", Text: "+GetGadgetText(5), 0)
          ElseIf EventType() = 1
            DisplayPopupMenu(0, WindowID())
          EndIf
          
     EndSelect

    EndIf
    
  Until EventID = #PB_EventCloseWindow
EndIf

End