p-unicode und NULL

[_JON_]

Ist es möglich ein Null, an einen mit p-unicode oder p-ascii type zu übergeben?

Laut MSDN sollte eine MsgBox, wenn ich Null als Title übergebe den Standardtext "Fehler" setzen.
Aber PB meckert ja wenn ich keinen String benutzte

Code: Alles auswählen

Prototype.l ProtoMessageBoxW(Window.l, Body.p-unicode, Title.p-unicode, Flags.l = 0)

If OpenLibrary(0, "User32.dll")
    MsgBox.ProtoMessageBoxW = GetFunction(0, "MessageBoxW")
    ;MsgBox(0, "Hello", 0)
    ;MsgBox(0, "Hello", #NUL)
    ;MsgBox(0, "Hello", #NUL$) ;keine echte null, leerer string
    ;MsgBox(0, "Hello", #NULL$)  ;keine echte null, leerer string
EndIf

[RSBasic]

Code: Alles auswählen

MessageBox_(0, "Message ohne Titel bzw. mit Error-Titel", 0, 0)

[ts-soft]

Jetzt fehlt aber noch die Beantwortung der Frage:
- Ist es möglich ein Null, an einen mit p-unicode oder p-ascii type zu übergeben?
Nein. Es wird automatisch ein Nullstring übergeben, aber niemals eine Null.

[_JON_]

Danke für die schnellen Antworten.

Schade das es nicht geht, fand die Pseudotypes eigentlich recht praktisch.

[ts-soft]

Schade das es nicht geht, fand die Pseudotypes eigentlich recht praktisch.

Ich finde sie immer noch recht praktisch und das man mit diesen nur Strings übergeben kann, sollte
ja einleuchten. Dafür sind sie ja da
Und das Wort "Fehler" in den Titel von Windows zu setzen lassen, ist wohl etwas wo man drauf
verzichten kann.

[_JON_]

Naja, ob man nun eine kleine Procedere benutzt oder einfach nur den String übergibt ist doch eigentlich egal.

Das mit der MsgBox war doch nur ein Beispiel gewesen. Wird sicherlich auch sinnvollere geben.

[RSBasic]

Du kannst, wenn es nicht anders gehen würde, kannst du auch zweimal deklarieren:

Code: Alles auswählen

Prototype.l ProtoMessageBoxW(Window.l, Body.p-unicode, Title.p-unicode, Flags.l = 0)
Prototype.l ProtoMessageBoxWEx(Window.l, Body.p-unicode, Title, Flags.l = 0)

If OpenLibrary(0, "User32.dll")
    MsgBox.ProtoMessageBoxW = GetFunction(0, "MessageBoxW")
    MsgBoxEx.ProtoMessageBoxWEx = GetFunction(0, "MessageBoxW")
    MsgBox(0, "Hello", "Mein Titel")
    MsgBoxEx(0, "Hello", 0)
EndIf

Du kannst dann selber aussuchen, ob du beispielsweise mit oder ohne Standard-Titel haben möchtest.

[ts-soft]

titel kann man auch ermitteln:

Code: Alles auswählen

Procedure.s GetLocalErrorTitle()
  Protected hInstance, result.s{255}
  hInstance = LoadLibraryEx_("user32", 0, #LOAD_LIBRARY_AS_DATAFILE)
  If hInstance
    LoadString_(hInstance, 2, @result, 255)
    FreeLibrary_(hInstance)
  EndIf
  ProcedureReturn result
EndProcedure

 Prototype.l ProtoMessageBoxW(Window.l, Body.p-unicode, Title.p-unicode, Flags.l = 0)

If OpenLibrary(0, "User32.dll")
    MsgBox.ProtoMessageBoxW = GetFunction(0, "MessageBoxW")
    title.s = GetLocalErrorTitle()
    MsgBox(0, "bla bla", title)
EndIf

[helpy]

Probiert folgendes:

Code: Alles auswählen

Prototype.l ProtoMessageBoxW(Window.l, Body.p-unicode, Title.p-unicode = 0, Flags.l = 0)

Define NullString.s
Debug @NullString

If OpenLibrary(0, "User32.dll")
	MsgBox.ProtoMessageBoxW = GetFunction(0, "MessageBoxW")
	MsgBox(0, "Hello")
	MsgBox(0, "Hello", NullString)
EndIf

String-Variablen, die nicht mit einem String befüllt werden, verweisen auf NULL!

[_JON_]

Probiert folgendes:
String-Variablen, die nicht mit einem String befüllt werden, verweisen auf NULL!

Super, ich wusste doch, das es irgendwie möglich sein muss

Danke